dev-util/bitrise: new ebuild, version 1.16.1

Bitrise is a Continuous Integration and Delivery (CI/CD) Platform
as a Service (PaaS) with a main focus on mobile app development (iOS,
Android, Xamarin, ...).

Closes: https://bugs.gentoo.org/655770
Closes: https://github.com/gentoo/gentoo/pull/8412

dev-util/bitrise/Manifest

@@ -0,0 +1 @@
+DIST bitrise-1.16.1.tar.gz 3986520 BLAKE2B 2a38eb72abc2aee69b9494abe03434014531a5081e8d71e7883418d686dffd1de8d61b2dda8761a1d074392a4f84699a4cff36be4f6be8abf52ba705434b8283 SHA512 37d87a27f2d3c17df7c61eebb8ab50887c7f723901125af08a5833bd053c5706cf1a2d3310fa30a6ade3bec8292b30bc4ddfb3143ece8129c606fcbe5103ddd6

dev-util/bitrise/bitrise-1.16.1.ebuild

@@ -0,0 +1,42 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit golang-build
+
+EGO_ON="github.com/bitrise-io"
+EGO_PN="${EGO_ON}/${PN}"
+
+DESCRIPTION="Run your Bitrise.io automations on any Mac or Linux machine"
+HOMEPAGE="https://www.bitrise.io/cli"
+SRC_URI="https://${EGO_PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="doc"
+
+S="${WORKDIR}/src/${EGO_ON}/${PN}"
+
+src_unpack() {
+	unpack ${A}
+	mkdir -p "${WORKDIR}/src/${EGO_ON}" || die "Couldn't create project dir in GOPATH"
+	mv "${WORKDIR}/${P}" "${WORKDIR}/src/${EGO_ON}/bitrise" || die "Couldn't move sources to GOPATH"
+}
+
+src_compile() {
+	GOPATH="${WORKDIR}" go build -v -o bin/bitrise || die "Couldn't compile bitrise"
+}
+
+src_test() {
+	export PULL_REQUEST_ID=""
+	export INTEGRATION_TEST_BINARY_PATH="${S}/bin/bitrise"
+	GOPATH="${WORKDIR}" go test -v ./_tests/integration/... || die "Integration tests failed"
+}
+
+src_install() {
+	dobin bin/bitrise
+	dodoc README.md
+	use doc && dodoc -r _docs
+}

dev-util/bitrise/metadata.xml

@@ -0,0 +1,19 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>karol.wrotniak@droidsonroids.pl</email>
+		<name>Karol Wrótniak</name>
+	</maintainer>
+	<maintainer type="project">
+		<email>proxy-maint@gentoo.org</email>
+		<name>Proxy Maintainers</name>
+	</maintainer>
+	<longdescription>Run your Bitrise automations with this CLI tool on any Mac or Linux machine, and use the same configuration on bitrise.io (automation service, with a mobile app focus). Part of the Bitrise Continuous Integration, Delivery and Automations Stack, with stepman and envman. For a nice &amp; quick intro you should check: https://www.bitrise.io/cli</longdescription>
+	<upstream>
+		<bugs-to>https://github.com/bitrise-io/bitrise/issues</bugs-to>
+		<changelog>https://github.com/bitrise-io/bitrise/blob/master/CHANGELOG.md</changelog>
+		<doc>https://github.com/bitrise-io/bitrise/blob/master/README.md</doc>
+		<remote-id type="github">bitriseio/bitrise</remote-id>
+	</upstream>
+</pkgmetadata>