dev-python/translate-toolkit: add 3.5.1

Signed-off-by: Sam James <sam@gentoo.org>

dev-python/translate-toolkit/Manifest

@@ -1 +1,2 @@
 DIST translate-3.4.1.gh.tar.gz 1147673 BLAKE2B 3a29b06f944752e9edb30c9b3efd681d7cd7f75fc9a320a3a8d9e74d497e43f1a1a4e18649174e4b28f1a3b2223d735ba411d32736b1fea36237ba95f8021217 SHA512 e2ff9b2c5de58c15ef7b11f1339be7b36ffda3368b91aa647585c9dc0f4c9f1c1ffac9165e0e963cb3c10fdf6ce037ed99d82b6156e7c104b4216c8d46dd709e
+DIST translate-3.5.1.gh.tar.gz 1147898 BLAKE2B f9fc96065727e0016e61fd581690dafc3021471de9ccc9012b223c24778669b984e0bf0ab5f83a910af0e543b0e4793afa110c5b2ced890a257f72512bcaf58d SHA512 2125e3ab019a6b721327d6979482562d5984df28b04aaa69d11e44b6a7396ee387f79d8242a20a84157f9b62457839b52599eb0fe13abac33c9a312a84d55d30

dev-python/translate-toolkit/translate-toolkit-3.5.1.ebuild

@@ -0,0 +1,100 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE="sqlite"
+
+inherit distutils-r1
+
+MY_P=translate-${PV}
+DESCRIPTION="Toolkit to convert between many translation formats"
+HOMEPAGE="https://github.com/translate/translate"
+SRC_URI="
+	https://github.com/translate/translate/archive/refs/tags/${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="+html +ical +ini +subtitles +yaml"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+BDEPEND=">=dev-python/six-1.11.0[${PYTHON_USEDEP}]"
+RDEPEND="${BDEPEND}
+	!dev-python/pydiff
+	app-text/iso-codes
+	>=dev-python/chardet-3.0.4[${PYTHON_USEDEP}]
+	dev-python/cheroot[${PYTHON_USEDEP}]
+	>=dev-python/lxml-4.3.1[${PYTHON_USEDEP}]
+	>=dev-python/pycountry-19.8.18[${PYTHON_USEDEP}]
+	>=dev-python/python-levenshtein-0.12.0[${PYTHON_USEDEP}]
+	>=dev-python/pyparsing-3[${PYTHON_USEDEP}]
+	dev-python/ruamel-yaml[${PYTHON_USEDEP}]
+	sys-devel/gettext
+	html? ( dev-python/utidylib[${PYTHON_USEDEP}] )
+	ical? ( dev-python/vobject[${PYTHON_USEDEP}] )
+	ini? ( >=dev-python/iniparse-0.5[${PYTHON_USEDEP}] )
+	subtitles? ( media-video/gaupol[${PYTHON_USEDEP}] )
+	yaml? ( dev-python/pyyaml[${PYTHON_USEDEP}] )
+"
+BDEPEND+="
+	test? ( dev-python/phply[${PYTHON_USEDEP}] )"
+
+distutils_enable_sphinx docs \
+	dev-python/sphinx-bootstrap-theme
+distutils_enable_tests pytest
+
+PATCHES=(
+	"${FILESDIR}"/translate-toolkit-3.3.0-no-install-docs.patch
+)
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Fails with network-sandbox (and even with it off but w/ softer fail)
+		'tests/xliff_conformance/test_xliff_conformance.py::test_open_office_to_xliff'
+		'tests/xliff_conformance/test_xliff_conformance.py::test_po_to_xliff'
+	)
+	local EPYTEST_IGNORE=(
+		# unpackaged fluent.*
+		translate/storage/test_fluent.py
+	)
+
+	if ! use ini; then
+		EPYTEST_IGNORE+=(
+			translate/convert/test_ini2po.py
+			translate/convert/test_po2ini.py
+		)
+	fi
+
+	if ! use subtitles; then
+		EPYTEST_IGNORE+=(
+			translate/storage/test_subtitles.py
+		)
+	fi
+
+	# translate/storage/test_mo.py needs 'pocompile'
+	distutils_install_for_testing
+	epytest
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if ! use html; then
+		rm "${ED}"/usr/bin/{html2po,po2html} || die
+	fi
+	if ! use ical; then
+		rm "${ED}"/usr/bin/{ical2po,po2ical} || die
+	fi
+	if ! use ini; then
+		rm "${ED}"/usr/bin/{ini2po,po2ini} || die
+	fi
+	if ! use subtitles; then
+		rm "${ED}"/usr/bin/{sub2po,po2sub} || die
+	fi
+
+	python_optimize
+}