gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-08-06 00:48:18 -07:00
Code Issues Projects Releases Wiki Activity

dev-python/hypothesis: Bump to 5.41.2

Browse Source 
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2020-11-08 22:41:54 +01:00
parent 9c92d70084
commit 1c245c7aae
2 changed files with 64 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/hypothesis/Manifest
View File

@@ -4,3 +4,4 @@ DIST hypothesis-python-5.36.2.tar.gz 9088227 BLAKE2B 578c28d045f3b3f288d43765d55
DIST hypothesis-python-5.37.5.tar.gz 9092380 BLAKE2B b5bf9f5c5bb1002154ea6041c38b727e926ae65641a05ddd2bfe919fdb7b6457963ddcc5bf1d57a929c57a3912b15a13c52b4568708348f4f308146cf64caa61 SHA512 ddf2db9d8f9318b0b3ae872fdfebbc4ac8376a86816e7c9a0350738a68a4e3adbe41aaf19a8f54471f551542f3252172cc34f5bc140483989ef8c04c5735f044
DIST hypothesis-python-5.41.0.tar.gz 9094817 BLAKE2B 3025caf9a0ccba19abfd12273edefe1db825a40615a378fb076e8d3ba96bfecc64ec23be6ef72b6fcd89d7d6b5c94bbf12abf3212e4a521a21def892b0d95a56 SHA512 76a0147d36179368d62a3d9e6f9f27effa903476fa0cccdba4574937c470bbfd020daccf9b3df73f457b543b6a94ce0858fe4d9abdfe9c16a8c49858c8bc0e92
DIST hypothesis-python-5.41.1.tar.gz 9095771 BLAKE2B 29c5c091f4b827d1f1e6276d0401c1a673077304b3ee8b0252536c3eeda066a4cfa764856edb222ba6cbaebb424b08aebc8d8ec00c5e0d445774b1c62ed98593 SHA512 b1f02e32e6c5bdb6ca0a338901715508a03d2734898c673c5b3a5b25dee34922d7fbfcc2534b0c658d003d5de3e97abecb5a9b4f00ada0cc85c457b4b870a873
DIST hypothesis-python-5.41.2.tar.gz 9095799 BLAKE2B c1743f2e9872cefdd82dd79b60f78ae02bb975be2156bf7c05054627ca8386092588721450dfe14954129e46ea3556b78f7784102640d84368bdc98af2980b04 SHA512 712a6b3a007e4b354e9ed2137b7dd53652abbbf0b324467ce540ca886fb956eae5d00f83cbc1c9b1799a4a3abc64f4d26d9aed85d5fb689e904e1125b87b88eb

63
dev-python/hypothesis/hypothesis-5.41.2.ebuild Normal file
View File

@@ -0,0 +1,63 @@
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
DISTUTILS_USE_SETUPTOOLS=rdepend
PYTHON_COMPAT=( python3_{6,7,8,9} pypy3 )
PYTHON_REQ_USE="threads(+),sqlite"
inherit distutils-r1 eutils multiprocessing optfeature
DESCRIPTION="A library for property based testing"
HOMEPAGE="https://github.com/HypothesisWorks/hypothesis https://pypi.org/project/hypothesis/"
SRC_URI="https://github.com/HypothesisWorks/${PN}/archive/${PN}-python-${PV}.tar.gz"
S="${WORKDIR}/${PN}-${PN}-python-${PV}/${PN}-python"
LICENSE="MPL-2.0"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
IUSE="cli test"
RESTRICT="!test? ( test )"
RDEPEND="
>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
>=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
cli? (
$(python_gen_cond_dep '
dev-python/black[${PYTHON_USEDEP}]
dev-python/click[${PYTHON_USEDEP}]
' python3_{6..9})
)
"
BDEPEND="
test? (
${RDEPEND}
dev-python/mock[${PYTHON_USEDEP}]
dev-python/pexpect[${PYTHON_USEDEP}]
>=dev-python/pytest-5.3.5[${PYTHON_USEDEP}]
dev-python/pytest-xdist[${PYTHON_USEDEP}]
!!<dev-python/typing-3.7.4.1
)
"
python_prepare() {
if ! use cli || [[ ${EPYTHON} != python* ]]; then
sed -i -e '/console_scripts/d' setup.py || die
fi
}
python_test() {
pytest -vv tests/cover tests/pytest tests/quality \
-n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")" ||
die "Tests fail with ${EPYTHON}"
}
pkg_postinst() {
optfeature "datetime support" dev-python/pytz
optfeature "dateutil support" dev-python/python-dateutil
optfeature "numpy support" dev-python/numpy
optfeature "django support" dev-python/django dev-python/pytz
optfeature "pandas support" dev-python/pandas
optfeature "pytest support" dev-python/pytest
}