sys-apps/polychromatic: bump to 0.9.4

Signed-off-by: Maciej Barć <xgqt@gentoo.org>

sys-apps/polychromatic/Manifest

@@ -1 +1,2 @@
 DIST polychromatic-0.9.3.tar.gz 1809140 BLAKE2B 8b3397a234e45a4e72635207bf2ce8d8fc3454e62494cd84128908fffe1d3155255d74ea41d17584cb1dbfd2e68e8b6cb629e8dedab43e22eba3ff8204f271b0 SHA512 a1805bce9986915164fdf61b5fd194ebd16cd7f1528febe0dcf7c09ecde5edf6ed7b404c97a3ea27427727d0134d9e26b71d8a810b5649e659febc403146bc4a
+DIST polychromatic-0.9.4.tar.gz 1805903 BLAKE2B cf751113a10582eb98588937278ec42fcfd6fe911f01eb5875ecba557da66e7fafdbe48042faf455a3009ff9190cbd11bed0b087f38833d7054d0eccde44ab61 SHA512 776a6d44c31bbbf6d88f09bb9d75b2d6982029538ce00512c6a6d36f7f196a62ba6a95a87841009759cb2d0d15265d1b01891f2ab463466d0b59f1a66f739f1e

sys-apps/polychromatic/polychromatic-0.9.4.ebuild

@@ -0,0 +1,76 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit meson python-single-r1 readme.gentoo-r1 xdg
+
+DESCRIPTION="RGB lighting management software for GNU/Linux powered by OpenRazer"
+HOMEPAGE="https://polychromatic.app/
+	https://github.com/polychromatic/polychromatic/"
+
+if [[ "${PV}" == *9999* ]] ; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/${PN}/${PN}.git"
+else
+	SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.tar.gz"
+
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	>=x11-libs/gtk+-3.20:3[introspection]
+	$(python_gen_cond_dep '
+		dev-python/pyqt6-webengine[${PYTHON_USEDEP}]
+		dev-python/pyqt6[svg,${PYTHON_USEDEP}]
+		dev-python/colorama[${PYTHON_USEDEP}]
+		dev-python/colour[${PYTHON_USEDEP}]
+		dev-python/distro[${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/setproctitle[${PYTHON_USEDEP}]
+		sys-apps/openrazer[client,${PYTHON_USEDEP}]
+	')
+"
+BDEPEND="
+	${RDEPEND}
+	dev-util/intltool
+"
+
+DOC_CONTENTS="To automatically start up Polychromatic on session login copy
+/usr/share/polychromatic/polychromatic-autostart.desktop file into Your user's
+~/.config/autostart/ directory."
+
+src_test() {
+	rm -rf "locale" || die
+	ln -svf "${BUILD_DIR}/locale" "locale" || die
+	PYTHONPATH="tests:${PYTHONPATH}" "${EPYTHON}" "tests/runner.py" || die
+}
+
+src_install() {
+	meson_src_install
+	python_optimize
+	readme.gentoo_create_doc
+
+	python_doscript "${S}"/polychromatic-{cli,controller,helper,tray-applet}
+
+	# Do not force polychromatic to autostart on session login.
+	# Move it into /usr/share/polychromatic and treat it as an example file
+	# that could be installed into user's ~/.config/autostart/ directory.
+	mv "${ED}/etc/xdg/autostart/${PN}-autostart.desktop" \
+	   "${ED}/usr/share/${PN}/${PN}-autostart.desktop" || die
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	readme.gentoo_print_elog
+}