gui-libs/libhandy: add 1.8.3

Signed-off-by: Mart Raudsepp <leio@gentoo.org>

gui-libs/libhandy/Manifest

@@ -1 +1,2 @@
 DIST libhandy-1.8.2.tar.xz 1778096 BLAKE2B 83b8316b22e7bd37436d5fdad0bd270dd5d64862bca97d358b0c2a1c6b7b0e18e0f472ce453719dfde982a427fd7c0c523b042d7721415602d3e7b9c57399509 SHA512 ec48c66a95b1e9158d3e072e1cfab6d538a9235966c790f1e4d4f2ec40a251c8818f505d031285a53ce855da92b7919d3a26aca4160d93241925da1e8cf4b748
+DIST libhandy-1.8.3.tar.xz 1791428 BLAKE2B 4e90929e62a197b3dbc8a2565198486d5acd231768afeece617b95c7bf8f689afba01c8bd90312cb41a1c388627b64a31286a706b8422485012754a955925957 SHA512 1e0ae363d2a4993c9667243715256b27cb0ecb898fa8f4ea1a914fbeb36c0a9c26447f8f13f92f5a855e45ada49f732adeb30b88d81f3ee5f984bca48db3ae65

gui-libs/libhandy/libhandy-1.8.3.ebuild

@@ -0,0 +1,61 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org meson xdg vala virtualx
+
+DESCRIPTION="Building blocks for modern adaptive GNOME apps"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/libhandy/"
+
+LICENSE="LGPL-2.1+"
+SLOT="1"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+IUSE="examples glade gtk-doc +introspection test +vala"
+REQUIRED_USE="
+	gtk-doc? ( introspection )
+	vala? ( introspection )
+"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/glib-2.44:2
+	>=x11-libs/gtk+-3.24.1:3[introspection?]
+	glade? ( dev-util/glade:3.10= )
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+"
+DEPEND="${RDEPEND}
+	x11-base/xorg-proto"
+BDEPEND="
+	dev-libs/libxml2:2
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	gtk-doc? ( >=dev-util/gi-docgen-2021.1
+		app-text/docbook-xml-dtd:4.3 )
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	default
+	use vala && vala_setup
+	xdg_environment_reset
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dprofiling=false # -pg passing
+		$(meson_feature introspection)
+		$(meson_use vala vapi)
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use test tests)
+		$(meson_use examples)
+		$(meson_feature glade glade_catalog)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}