xfce-base/libxfce4windowing: Revert "Remove old"

Restore 4.20.5 due to
https://gitlab.xfce.org/xfce/libxfce4windowing/-/work_items/64.

Reverts: 72aaa61327
Signed-off-by: Michał Górny <mgorny@gentoo.org>

xfce-base/libxfce4windowing/Manifest

@@ -1 +1,2 @@
+DIST libxfce4windowing-4.20.5.tar.bz2 622438 BLAKE2B fb69e4c70a1d34b01324f8aa778f5e2b70d1aaa210087935a25edf1570d230b52df1093a71ef92be8fa600fc22f9ecab84789984238ee04d09ce27eb0360b0d8 SHA512 357afc89d2ed146d65afaa7376c3aada78adae291ecfe602f0cb061d115b132024ee8a78eedc0ed77b91fc6bdaa8d3c3b107c1e21503053eda1e05bc81b15d9f
 DIST libxfce4windowing-4.20.6.tar.bz2 595011 BLAKE2B c149adba12fca29088d4a86ff5c79b3419dc779fcb7510ce3b6315be054b1f30067dc69a042f606601b67156c3ba4bb75c517bee2bcc001b17384720398f0c57 SHA512 94d1c199aeac99d584453dc782c1fed39311b922ac2bbeafec4e099347f1eeaff72a853497e1e328325d73513fd0cbcc13b5533309b37e484057315343b3244a

xfce-base/libxfce4windowing/libxfce4windowing-4.20.5-r1.ebuild

@@ -0,0 +1,67 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit meson vala
+
+DESCRIPTION="Unified widget and session management libs for Xfce"
+HOMEPAGE="https://gitlab.xfce.org/xfce/libxfce4windowing/"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="LGPL-2.1+"
+SLOT="0/4.19.6"
+KEYWORDS="amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv ~sparc x86"
+IUSE="+introspection wayland X vala"
+REQUIRED_USE="
+	|| ( wayland X )
+	vala? ( introspection )
+"
+
+RDEPEND="
+	>=dev-libs/glib-2.72.0
+	>=x11-libs/gtk+-3.24.10:3[X?,introspection?,wayland?]
+	>=x11-libs/gdk-pixbuf-2.42.8[introspection?]
+	wayland? (
+		>=dev-libs/wayland-1.20
+	)
+	X? (
+		>=media-libs/libdisplay-info-0.1.1:=
+		>=x11-libs/libX11-1.6.7
+		>=x11-libs/libXrandr-1.5.0
+		>=x11-libs/libwnck-3.14:3
+	)
+"
+DEPEND="
+	${RDEPEND}
+	wayland? (
+		>=dev-libs/wayland-protocols-1.39
+	)
+"
+BDEPEND="
+	>=dev-build/xfce4-dev-tools-4.19.2
+	dev-lang/perl
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+	wayland? (
+		>=dev-util/wayland-scanner-1.15
+	)
+"
+
+src_prepare() {
+	default
+	use vala && vala_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use introspection)
+		$(meson_feature vala)
+		$(meson_feature wayland)
+		$(meson_feature X x11)
+		-Dtests=false
+	)
+
+	meson_src_configure
+}