x11-misc/qterm: version bump to 0.7.1

Package-Manager: Portage-2.3.3, Repoman-2.3.1

x11-misc/qterm/Manifest

@@ -1 +1,2 @@
 DIST qterm-0.5.12.tar.bz2 749254 SHA256 bd31051a6c117b05fef3ea163480143837c57632a84eab43e8e142860bcab22a SHA512 43f302f28edfb7fe4332d054390011e3eba37863be57191a13cedf2fa76d7b5db53d32947b7acd5e7585f2b0c8afe9b4b43334d86040f1f9249e9e767dd715e8 WHIRLPOOL 77b3fb09ea28901a151f8e0707a107677260a52d38a24427155dfa4e36d208bfc08be4016205d4c4f0c7fd374b967ccfed46271644e6dca2aa6e27ac637a991a
+DIST qterm-0.7.1.tar.gz 901169 SHA256 7e760dc18afa8c6e20c7d5f0148c41b9a9273667c6ee7716f7cc87ee5eaa0d63 SHA512 94f4c3f7974572c29eabf98c45e962b9232a4b0fbd6710c7725e0d23e6ecc91456f52a8c112779cd3b4732cb2e4302629419f7365b2d359ccbf39578e6e67cdd WHIRLPOOL fd9cd74ec010e4d63b7e7ef6c3f756f7e67db58f96a932ef426136fbee1565199ed13c27d27586ef7f81fb89d79b7cde7a2d090903bc3c3e64fecf30e0188d52

x11-misc/qterm/qterm-0.7.1.ebuild

@@ -0,0 +1,70 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit cmake-utils gnome2-utils xdg-utils
+
+DESCRIPTION="A BBS client for Linux"
+HOMEPAGE="https://github.com/qterm/qterm"
+SRC_URI="https://github.com/qterm/qterm/archive/0.7.1.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="libressl"
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtmultimedia:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtscript:5[scripttools]
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	x11-libs/libX11
+	!libressl? ( dev-libs/openssl:0= )
+	libressl? ( dev-libs/libressl:= )
+"
+DEPEND="${RDEPEND}
+	dev-qt/linguist-tools:5
+	dev-qt/qthelp:5
+	x11-proto/xproto
+"
+
+DOCS=( README.rst RELEASE_NOTES TODO )
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	sed -i -e "s/Exec=qterm/Exec=QTerm/" src/${PN}.desktop || die
+}
+
+src_configure() {
+	xdg_environment_reset
+
+	local mycmakeargs=(
+		-DQT5=ON
+	)
+
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+	mv "${D}"/usr/bin/qterm "${D}"/usr/bin/QTerm || die
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}