mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-08 18:27:07 -08:00
net-fs/samba: Bump to version 4.6.16
Package-Manager: Portage-2.3.46, Repoman-2.3.10
This commit is contained in:
Lars Wendler
@@ -2,6 +2,7 @@ DIST samba-4.2.14.tar.gz 20883281 BLAKE2B 90bff4ef0752b952e2e31b6e86223ae7e78524
|
||||
DIST samba-4.5.11-disable-python-patches.tar.xz 6292 BLAKE2B c2a32a1059a02bc1c87ce5f604cbc5878c654b8f693c8486b5ba63b37513444915a7b6389fe82b7e31ab2f9577dd8462eddba60b4f4f756b4ed1145ce7bd90ae SHA512 f0e3076e3e1ecaae3f06b3ef30efc81719fb3f63a1041dcbdae4b62ca4cf693732f9eb16f047d046d4930136fed82194e82b455ea888e12cf845b3e6a122d57d
|
||||
DIST samba-4.5.16.tar.gz 21024396 BLAKE2B e737559fb748044076608fa233700eb54c7e1c56bc234763f062b6341a179cc78a4a8cdf9f3d6f4d7f3cf8a79f846852ddd5cc753a468c3adb3a0451e1809ed9 SHA512 de8a41013cfb5ef3adcb290efd97a78a5de876d90ad05764d631f14e663a1849bb53e4ac394b46c906f1109be5748fee9316407a659c57007d36851ae8adcd7f
|
||||
DIST samba-4.6.15.tar.gz 21175479 BLAKE2B 40751be51e5ae1368b66d5e0919092935749a749dbb469dd503864acb9d5caf1c26c0894ac3a5294ed8b2c79de31366d80f1b565bffb4f18a7ba659872748feb SHA512 7b55e305c41380ba6dd4df94bdd88aa2d4ebbe27ec258331c04a9610ee820e4c290a3dfdcd04fa89e100b115a674380881699d6cd565f08d753d1b23036c4986
|
||||
DIST samba-4.6.16.tar.gz 21184221 BLAKE2B 93c2a666edadf1cf6277f6ec202f629be6badec6151dff0b4faed7e9541c6b0c20776ea1c2f536ca9ae1056e153929a312f7c8b06aa92adebf0758cca7cebf6b SHA512 e51d34a5a21d40e18b221ac2d150eb5d0a72cf14b3fdbaa11ab621dc173067c8c73764c748148907f6e5633b5afc68b691b673fb6cbffb3b77e1b7281dabebc4
|
||||
DIST samba-4.6.7-disable-python-patches.tar.xz 8896 BLAKE2B 99496f91d015f10d111e2a8738c9e66b3c1f1958c0e0894d8e9d8f3ff141fbedaa25d93699b702ab69130fda770c80c3ed4280de0af1090dedbcfd5784b72222 SHA512 c45e548a49735e17b568bebf07dc7409de3de0f93256d1dcf345d2723a27d22a51d860ed921785354fda691f83be4eca3b9d618d5c332438ebf97518a01983eb
|
||||
DIST samba-4.7.7.tar.gz 16875059 BLAKE2B 05ecf13562e847070498e923df0cc85836b2fb98d4618942f60e4f28d6c5110b382cfe494e6578bbc06e14052c5d87b0f542ada186e4f132375c4360eaa8bb9f SHA512 78f180f602f08ab9e3000ae016f667e44f059a865b606c21e18857efb89af469c2cb2f9c1316e658badf1a1f41826ba87ccb23f38dc31fe82bf9e5b8fb93daad
|
||||
DIST samba-4.7.9.tar.gz 16907301 BLAKE2B c5e1e7422c271893ad6bc8fbaa1c17161e221d2eb9eb7cc370d52cf3d5dd4b54b023419f9dd72476ead8da306b6a530c4fc2529efad8eab26100157ffe23b5a4 SHA512 7e7e3c611e69fef904d13503752cafb7a259dd02b0be9a73d3b31ef82d701006da47e60a68dc19abb5343aa27ee4b210aa5d9bb2c1962932835dcbccba9b4f4a
|
||||
|
||||
@@ -0,0 +1,316 @@
|
||||
# Copyright 1999-2018 Gentoo Foundation
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=6
|
||||
PYTHON_COMPAT=( python2_7 )
|
||||
PYTHON_REQ_USE='threads(+),xml(+)'
|
||||
|
||||
inherit python-single-r1 waf-utils multilib-minimal linux-info systemd eutils
|
||||
|
||||
MY_PV="${PV/_rc/rc}"
|
||||
MY_P="${PN}-${MY_PV}"
|
||||
|
||||
SRC_PATH="stable"
|
||||
[[ ${PV} = *_rc* ]] && SRC_PATH="rc"
|
||||
|
||||
SRC_URI="mirror://samba/${SRC_PATH}/${MY_P}.tar.gz
|
||||
https://dev.gentoo.org/~axs/samba-4.6.7-disable-python-patches.tar.xz"
|
||||
[[ ${PV} = *_rc* ]] || \
|
||||
KEYWORDS="~amd64 ~arm64 ~hppa ~x86"
|
||||
|
||||
DESCRIPTION="Samba Suite Version 4"
|
||||
HOMEPAGE="https://www.samba.org/"
|
||||
LICENSE="GPL-3"
|
||||
|
||||
SLOT="0"
|
||||
|
||||
IUSE="acl addc addns ads ceph client cluster cups debug dmapi fam gnutls gpg iprint ldap pam python
|
||||
quota selinux syslog system-heimdal +system-mitkrb5 systemd test winbind zeroconf"
|
||||
|
||||
MULTILIB_WRAPPED_HEADERS=(
|
||||
/usr/include/samba-4.0/policy.h
|
||||
/usr/include/samba-4.0/dcerpc_server.h
|
||||
/usr/include/samba-4.0/ctdb.h
|
||||
/usr/include/samba-4.0/ctdb_client.h
|
||||
/usr/include/samba-4.0/ctdb_protocol.h
|
||||
/usr/include/samba-4.0/ctdb_private.h
|
||||
/usr/include/samba-4.0/ctdb_typesafe_cb.h
|
||||
/usr/include/samba-4.0/ctdb_version.h
|
||||
)
|
||||
|
||||
# sys-apps/attr is an automagic dependency (see bug #489748)
|
||||
CDEPEND="
|
||||
>=app-arch/libarchive-3.1.2[${MULTILIB_USEDEP}]
|
||||
dev-lang/perl:=
|
||||
dev-libs/libaio[${MULTILIB_USEDEP}]
|
||||
dev-libs/libbsd[${MULTILIB_USEDEP}]
|
||||
dev-libs/iniparser:0
|
||||
dev-libs/popt[${MULTILIB_USEDEP}]
|
||||
dev-python/subunit[${PYTHON_USEDEP},${MULTILIB_USEDEP}]
|
||||
>=dev-util/cmocka-1.0.0[${MULTILIB_USEDEP}]
|
||||
net-libs/libnsl:=[${MULTILIB_USEDEP}]
|
||||
sys-apps/attr[${MULTILIB_USEDEP}]
|
||||
~sys-libs/ldb-1.1.29[ldap(+)?,python(+),${PYTHON_USEDEP},${MULTILIB_USEDEP}]
|
||||
sys-libs/libcap
|
||||
sys-libs/ncurses:0=[${MULTILIB_USEDEP}]
|
||||
sys-libs/readline:0=
|
||||
>=sys-libs/talloc-2.1.9[python?,${PYTHON_USEDEP},${MULTILIB_USEDEP}]
|
||||
>=sys-libs/tdb-1.3.12[python?,${PYTHON_USEDEP},${MULTILIB_USEDEP}]
|
||||
>=sys-libs/tevent-0.9.34[python?,${PYTHON_USEDEP},${MULTILIB_USEDEP}]
|
||||
sys-libs/zlib[${MULTILIB_USEDEP}]
|
||||
virtual/libiconv
|
||||
pam? ( virtual/pam )
|
||||
acl? ( virtual/acl )
|
||||
addns? (
|
||||
net-dns/bind-tools[gssapi]
|
||||
dev-python/dnspython:=[${PYTHON_USEDEP}]
|
||||
)
|
||||
ceph? ( sys-cluster/ceph )
|
||||
cluster? (
|
||||
net-libs/rpcsvc-proto
|
||||
!dev-db/ctdb
|
||||
)
|
||||
cups? ( net-print/cups )
|
||||
debug? ( dev-util/lttng-ust )
|
||||
dmapi? ( sys-apps/dmapi )
|
||||
fam? ( virtual/fam )
|
||||
gnutls? (
|
||||
dev-libs/libgcrypt:0
|
||||
>=net-libs/gnutls-1.4.0
|
||||
)
|
||||
gpg? ( app-crypt/gpgme )
|
||||
ldap? ( net-nds/openldap[${MULTILIB_USEDEP}] )
|
||||
system-heimdal? ( >=app-crypt/heimdal-1.5[-ssl,${MULTILIB_USEDEP}] )
|
||||
system-mitkrb5? ( app-crypt/mit-krb5[${MULTILIB_USEDEP}] )
|
||||
systemd? ( sys-apps/systemd:0= )"
|
||||
DEPEND="${CDEPEND}
|
||||
${PYTHON_DEPS}
|
||||
app-text/docbook-xsl-stylesheets
|
||||
dev-libs/libxslt
|
||||
virtual/pkgconfig
|
||||
test? (
|
||||
!system-mitkrb5? (
|
||||
>=sys-libs/nss_wrapper-1.1.3
|
||||
>=net-dns/resolv_wrapper-1.1.4
|
||||
>=net-libs/socket_wrapper-1.1.7
|
||||
>=sys-libs/uid_wrapper-1.2.1
|
||||
)
|
||||
)"
|
||||
RDEPEND="${CDEPEND}
|
||||
python? ( ${PYTHON_DEPS} )
|
||||
client? ( net-fs/cifs-utils[ads?] )
|
||||
selinux? ( sec-policy/selinux-samba )
|
||||
!dev-perl/Parse-Yapp
|
||||
"
|
||||
|
||||
REQUIRED_USE="
|
||||
addc? ( python gnutls !system-mitkrb5 )
|
||||
addns? ( python )
|
||||
ads? ( acl gnutls ldap )
|
||||
cluster? ( ads )
|
||||
gpg? ( addc )
|
||||
test? ( python )
|
||||
?? ( system-heimdal system-mitkrb5 )
|
||||
${PYTHON_REQUIRED_USE}
|
||||
"
|
||||
|
||||
# the test suite is messed, it uses system-installed samba
|
||||
# bits instead of what was built, tests things disabled via use
|
||||
# flags, and generally just fails to work in a way ebuilds could
|
||||
# rely on in its current state
|
||||
RESTRICT="test"
|
||||
|
||||
S="${WORKDIR}/${MY_P}"
|
||||
|
||||
PATCHES=(
|
||||
"${FILESDIR}/${PN}-4.4.0-pam.patch"
|
||||
"${FILESDIR}/${PN}-4.5.1-compile_et_fix.patch"
|
||||
"${FILESDIR}/${PN}-glibc-2.26-no_rpc.patch" #637320
|
||||
"${FILESDIR}/${PN}-4.6-no_ads.patch"
|
||||
)
|
||||
|
||||
#CONFDIR="${FILESDIR}/$(get_version_component_range 1-2)"
|
||||
CONFDIR="${FILESDIR}/4.4"
|
||||
|
||||
WAF_BINARY="${S}/buildtools/bin/waf"
|
||||
|
||||
SHAREDMODS=""
|
||||
|
||||
pkg_setup() {
|
||||
python-single-r1_pkg_setup
|
||||
if use cluster ; then
|
||||
SHAREDMODS="idmap_rid,idmap_tdb2,idmap_ad"
|
||||
elif use ads ; then
|
||||
SHAREDMODS="idmap_ad"
|
||||
fi
|
||||
}
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
|
||||
# install the patches from tarball(s)
|
||||
eapply "${WORKDIR}/patches"
|
||||
|
||||
# un-bundle dnspython
|
||||
sed -i -e '/"dns.resolver":/d' "${S}"/third_party/wscript || die
|
||||
|
||||
# unbundle iso8601 unless tests are enabled
|
||||
use test || sed -i -e '/"iso8601":/d' "${S}"/third_party/wscript || die
|
||||
|
||||
# ugly hackaround for bug #592502
|
||||
cp /usr/include/tevent_internal.h "${S}"/lib/tevent/ || die
|
||||
|
||||
sed -e 's:<gpgme\.h>:<gpgme/gpgme.h>:' \
|
||||
-i source4/dsdb/samdb/ldb_modules/password_hash.c \
|
||||
|| die
|
||||
|
||||
# Friggin' WAF shit
|
||||
multilib_copy_sources
|
||||
}
|
||||
|
||||
multilib_src_configure() {
|
||||
# when specifying libs for samba build you must append NONE to the end to
|
||||
# stop it automatically including things
|
||||
local bundled_libs="NONE"
|
||||
if ! use system-heimdal && ! use system-mitkrb5 ; then
|
||||
bundled_libs="heimbase,heimntlm,hdb,kdc,krb5,wind,gssapi,hcrypto,hx509,roken,asn1,com_err,NONE"
|
||||
fi
|
||||
|
||||
local myconf=()
|
||||
myconf=(
|
||||
--enable-fhs
|
||||
--sysconfdir="${EPREFIX}/etc"
|
||||
--localstatedir="${EPREFIX}/var"
|
||||
--with-modulesdir="${EPREFIX}/usr/$(get_libdir)/samba"
|
||||
--with-piddir="${EPREFIX}/run/${PN}"
|
||||
--bundled-libraries="${bundled_libs}"
|
||||
--builtin-libraries=NONE
|
||||
--disable-rpath
|
||||
--disable-rpath-install
|
||||
--nopyc
|
||||
--nopyo
|
||||
)
|
||||
if multilib_is_native_abi ; then
|
||||
myconf+=(
|
||||
$(use_with acl acl-support)
|
||||
$(usex addc '' '--without-ad-dc')
|
||||
$(use_with addns dnsupdate)
|
||||
$(use_with ads)
|
||||
$(use_enable ceph cephfs)
|
||||
$(use_with cluster cluster-support)
|
||||
$(use_enable cups)
|
||||
$(use_with debug lttng)
|
||||
$(use_with dmapi)
|
||||
$(use_with fam)
|
||||
$(use_enable gnutls)
|
||||
$(use_with gpg gpgme)
|
||||
$(use_enable iprint)
|
||||
$(use_with ldap)
|
||||
$(use_with pam)
|
||||
$(usex pam "--with-pammodulesdir=${EPREFIX}/$(get_libdir)/security" '')
|
||||
$(use_with quota quotas)
|
||||
$(use_with syslog)
|
||||
$(use_with systemd)
|
||||
$(usex system-mitkrb5 '--with-system-mitkrb5' '')
|
||||
$(use_with winbind)
|
||||
$(usex python '' '--disable-python')
|
||||
$(usex test '--enable-selftest' '')
|
||||
$(use_enable zeroconf avahi)
|
||||
--with-shared-modules=${SHAREDMODS}
|
||||
)
|
||||
else
|
||||
myconf+=(
|
||||
--without-acl-support
|
||||
--without-ad-dc
|
||||
--without-dnsupdate
|
||||
--without-ads
|
||||
--disable-avahi
|
||||
--disable-cephfs
|
||||
--without-cluster-support
|
||||
--disable-cups
|
||||
--without-dmapi
|
||||
--without-fam
|
||||
--disable-gnutls
|
||||
--without-gpgme
|
||||
--disable-iprint
|
||||
$(use_with ldap)
|
||||
$(use_with debug lttng)
|
||||
--without-pam
|
||||
--without-quotas
|
||||
--without-syslog
|
||||
--without-systemd
|
||||
$(usex system-mitkrb5 '--with-system-mitkrb5' '')
|
||||
--without-winbind
|
||||
--disable-python
|
||||
)
|
||||
fi
|
||||
|
||||
CPPFLAGS="-I${SYSROOT}${EPREFIX}/usr/include/et ${CPPFLAGS}" \
|
||||
waf-utils_src_configure ${myconf[@]}
|
||||
}
|
||||
|
||||
multilib_src_compile() {
|
||||
waf-utils_src_compile
|
||||
}
|
||||
|
||||
multilib_src_install() {
|
||||
waf-utils_src_install
|
||||
|
||||
# Make all .so files executable
|
||||
find "${D}" -type f -name "*.so" -exec chmod +x {} +
|
||||
|
||||
if multilib_is_native_abi; then
|
||||
# install ldap schema for server (bug #491002)
|
||||
if use ldap ; then
|
||||
insinto /etc/openldap/schema
|
||||
doins examples/LDAP/samba.schema
|
||||
fi
|
||||
|
||||
# create symlink for cups (bug #552310)
|
||||
if use cups ; then
|
||||
dosym ../../../bin/smbspool /usr/libexec/cups/backend/smb
|
||||
fi
|
||||
|
||||
# install example config file
|
||||
insinto /etc/samba
|
||||
doins examples/smb.conf.default
|
||||
|
||||
# Fix paths in example file (#603964)
|
||||
sed \
|
||||
-e '/log file =/s@/usr/local/samba/var/@/var/log/samba/@' \
|
||||
-e '/include =/s@/usr/local/samba/lib/@/etc/samba/@' \
|
||||
-e '/path =/s@/usr/local/samba/lib/@/var/lib/samba/@' \
|
||||
-e '/path =/s@/usr/local/samba/@/var/lib/samba/@' \
|
||||
-e '/path =/s@/usr/spool/samba@/var/spool/samba@' \
|
||||
-i "${ED%/}"/etc/samba/smb.conf.default || die
|
||||
|
||||
# Install init script and conf.d file
|
||||
newinitd "${CONFDIR}/samba4.initd-r1" samba
|
||||
newconfd "${CONFDIR}/samba4.confd" samba
|
||||
|
||||
systemd_dotmpfilesd "${FILESDIR}"/samba.conf
|
||||
systemd_dounit "${FILESDIR}"/nmbd.service
|
||||
systemd_dounit "${FILESDIR}"/smbd.{service,socket}
|
||||
systemd_newunit "${FILESDIR}"/smbd_at.service 'smbd@.service'
|
||||
systemd_dounit "${FILESDIR}"/winbindd.service
|
||||
systemd_dounit "${FILESDIR}"/samba.service
|
||||
fi
|
||||
}
|
||||
|
||||
multilib_src_test() {
|
||||
if multilib_is_native_abi ; then
|
||||
"${WAF_BINARY}" test || die "test failed"
|
||||
fi
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
ewarn "Be aware the this release contains the best of all of Samba's"
|
||||
ewarn "technology parts, both a file server (that you can reasonably expect"
|
||||
ewarn "to upgrade existing Samba 3.x releases to) and the AD domain"
|
||||
ewarn "controller work previously known as 'samba4'."
|
||||
|
||||
elog "For further information and migration steps make sure to read "
|
||||
elog "https://samba.org/samba/history/${P}.html "
|
||||
elog "https://samba.org/samba/history/${PN}-4.5.0.html and"
|
||||
elog "https://wiki.samba.org/index.php/Samba4/HOWTO "
|
||||
}
|
||||
Reference in New Issue
Block a user