net-analyzer/wireshark: add 4.6.10

Bug: https://bugs.gentoo.org/986785
Signed-off-by: Holger Hoffstätte <holger@applied-asynchrony.com>
Part-of: https://codeberg.org/gentoo/gentoo/pulls/2453
Signed-off-by: Sam James <sam@gentoo.org>
This commit is contained in:
Holger Hoffstätte
2026-11-19 18:31:39 +00:00
committed by Sam James
parent 5c78d7245e
commit 193d2e4bd4
2 changed files with 336 additions and 0 deletions
+2
View File
@@ -1,3 +1,5 @@
DIST wireshark-4.6.10-signatures.txt 2524 BLAKE2B 81e9e2c6f66797586da6b402fd97e769c554e692210dac3d1ce055bbf0b64b69080eb8e1bc49fb599182b35650ad64b8bd3ba809222817f81bfa9ce9d0d08b86 SHA512 c6ad8e7b75001e826f0264cdbc476447216f62ab0c551122d833eca436f2edc94322df8c1751ab51ff8e8736e0a6cc958c5b7efe2f3484806f016ba90dd1c866
DIST wireshark-4.6.10.tar.xz 56704568 BLAKE2B 82be7df587d5a39362896772258167c8ce735e0c9b7a04fb250df91e2cb8dc842c6ba9d0953a4530067078a1897432f9530a6d4d8c42051cf45e3cd97a4cf7f0 SHA512 fd52c764635188bc9ab52ea549537af1b470cf48658221d478ee5ad7fb698bdb0c10008f4c51f2b862e680e8d06c0de62642c3cda98705c6ed40e273ee776190
DIST wireshark-4.6.8-signatures.txt 2507 BLAKE2B 818d0dd0804dd681552786bf2902ff36e1c42d59515c25e1a1ccd3410ff2d8333becab956cf9363a161e0c73fe7b5352f6b919dd4ab589b02a987ae6c8008f67 SHA512 598caa682ac71899465fb82a37445f7141287bbabee964dfd33aedbb4c4c6e0ed9b206d458b9eb2d9a083f9c6db9f8b50d8dcaf11e26dc33bb8baee83ae3f6fa
DIST wireshark-4.6.8.tar.xz 56464692 BLAKE2B 6a7c2407780b7aae8d7091465ecc724e7a042eb38ee1595e0bf038a6a0426b8f072fd09cfc95f6283236ae1e7e2fdac8e77d4509a28e83a2a5e6b5bad01bb59a SHA512 4692bd15bebd67475502b6afe106e3be85b90add16f932d7e58c4426fd62b5886e96daa522aafd9ee4a8300bf3e091a738b5b1fa20e3e0721d0d0f3be216f3c8
DIST wireshark-4.6.9-signatures.txt 2507 BLAKE2B 06f06e31d60ded6642cc8f8bfb0386c17ab48354b54e6abe55d27d9e0d16b441b1af0ca25734bff571119a5a39042e3caa1de3adb3435485f93d4e8d2fe70c2e SHA512 64ef89e8ff57ce9bccf6580e50545186079bd5444f906f4a4cf585a6e3d9f509239e8ae719e0775c07d6718cab1ce433c864d87799121ca6c46799fa3b3addcd
@@ -0,0 +1,334 @@
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
LUA_COMPAT=( lua5-{3..4} )
PYTHON_COMPAT=( python3_{12..14} )
inherit fcaps lua-single python-any-r1 qt-utils toolchain-funcs xdg cmake
DESCRIPTION="Network protocol analyzer (sniffer)"
HOMEPAGE="https://www.wireshark.org/"
if [[ ${PV} == *9999* ]] ; then
EGIT_REPO_URI="https://gitlab.com/wireshark/wireshark.git"
inherit git-r3
else
VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/wireshark.asc
inherit verify-sig
SRC_URI="https://www.wireshark.org/download/src/all-versions/${P/_/}.tar.xz"
SRC_URI+=" verify-sig? ( https://www.wireshark.org/download/SIGNATURES-${PV/_/}.txt -> ${P}-signatures.txt )"
S="${WORKDIR}/${P/_/}"
if [[ ${PV} != *_rc* ]] ; then
KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~ppc64 ~riscv ~x86"
fi
fi
LICENSE="GPL-2"
SLOT="0/${PV}"
IUSE="androiddump bcg729 brotli +capinfos +captype ciscodump +dftest doc dpauxmon"
IUSE+=" +dumpcap +editcap +gui http2 http3 ilbc kerberos lua lz4 maxminddb"
IUSE+=" +mergecap +minizip +netlink opus pkcs11 +plugins +pcap +randpkt"
IUSE+=" +randpktdump +reordercap sbc selinux +sharkd smi snappy spandsp sshdump ssl"
IUSE+=" sdjournal test +text2pcap +tshark +udpdump wifi xxhash zlib +zstd"
REQUIRED_USE="
lua? ( ${LUA_REQUIRED_USE} )
"
RESTRICT="!test? ( test )"
# bug #753062 for speexdsp
RDEPEND="
acct-group/pcap
>=dev-libs/glib-2.50.0:2
dev-libs/libpcre2:=
dev-libs/libxml2:=
>=net-dns/c-ares-1.13.0:=
>=dev-libs/libgcrypt-1.8.0:=
media-libs/speexdsp
bcg729? ( media-libs/bcg729 )
brotli? ( app-arch/brotli:= )
ciscodump? ( >=net-libs/libssh-0.6:= )
filecaps? ( sys-libs/libcap )
http2? ( >=net-libs/nghttp2-1.11.0:= )
http3? ( net-libs/nghttp3 )
ilbc? ( media-libs/libilbc:= )
kerberos? ( virtual/krb5 )
lua? ( ${LUA_DEPS} )
lz4? ( app-arch/lz4:= )
maxminddb? ( dev-libs/libmaxminddb:= )
minizip? ( virtual/minizip:= )
netlink? ( dev-libs/libnl:3 )
opus? ( media-libs/opus )
pcap? ( net-libs/libpcap )
gui? (
dev-qt/qtbase:6[concurrent,gui,widgets]
dev-qt/qt5compat:6
dev-qt/qtmultimedia:6
x11-misc/xdg-utils
)
sbc? ( media-libs/sbc )
sdjournal? ( sys-apps/systemd:= )
smi? ( net-libs/libsmi )
snappy? ( app-arch/snappy:= )
spandsp? ( media-libs/spandsp:= )
sshdump? ( >=net-libs/libssh-0.6:= )
ssl? ( >=net-libs/gnutls-3.5.8:=[pkcs11?] )
wifi? ( >=net-libs/libssh-0.6:= )
xxhash? ( dev-libs/xxhash )
zlib? ( virtual/zlib:= )
zstd? ( app-arch/zstd:= )
"
DEPEND="
${RDEPEND}
"
BDEPEND="
${PYTHON_DEPS}
dev-lang/perl
app-alternatives/lex
sys-devel/gettext
virtual/pkgconfig
doc? (
app-text/doxygen
dev-ruby/asciidoctor
dev-libs/libxslt
)
gui? (
dev-qt/qttools:6[linguist]
)
test? (
$(python_gen_any_dep '
dev-python/pytest[${PYTHON_USEDEP}]
dev-python/pytest-xdist[${PYTHON_USEDEP}]
')
)
"
RDEPEND="
${RDEPEND}
gui? ( virtual/freedesktop-icon-theme )
selinux? ( sec-policy/selinux-wireshark )
"
if [[ ${PV} != *9999* ]] ; then
BDEPEND+=" verify-sig? ( sec-keys/openpgp-keys-wireshark )"
fi
PATCHES=(
"${FILESDIR}/4.4.6-lto.patch"
"${FILESDIR}/4.6.2-gnutls-pkcs11.patch"
)
python_check_deps() {
use test || return 0
python_has_version -b "dev-python/pytest[${PYTHON_USEDEP}]" &&
python_has_version -b "dev-python/pytest-xdist[${PYTHON_USEDEP}]"
}
pkg_setup() {
use lua && lua-single_pkg_setup
python-any-r1_pkg_setup
}
src_unpack() {
if [[ ${PV} == *9999* ]] ; then
git-r3_src_unpack
else
if use verify-sig ; then
cd "${DISTDIR}" || die
verify-sig_verify_signed_checksums \
${P}-signatures.txt \
openssl-dgst \
${P}.tar.xz
cd "${WORKDIR}" || die
fi
default
fi
}
src_prepare() {
# since 4.6.5 the Lua version is found "automatically" and can no longer
# be passed in via LUA_FIND_VERSIONS, so we override the search list.
if use lua; then
sed -i "s/set(LUA_VERSIONS5 5.5 5.4 5.3 5.2 5.1 5.0)/set(LUA_VERSIONS5 ${ELUA#lua})/g" \
cmake/modules/FindLua.cmake || die
fi
cmake_src_prepare
}
src_configure() {
local mycmakeargs
python_setup
mycmakeargs+=(
-DPython3_EXECUTABLE="${PYTHON}"
-DCMAKE_DISABLE_FIND_PACKAGE_{Asciidoctor,DOXYGEN}=$(usex !doc)
# Force bundled lemon (bug 933119)
-DLEMON_EXECUTABLE=
-DRPMBUILD_EXECUTABLE=
-DGIT_EXECUTABLE=
-DENABLE_CCACHE=OFF
$(use androiddump && use pcap && echo -DEXTCAP_ANDROIDDUMP_LIBPCAP=yes)
-DBUILD_androiddump=$(usex androiddump)
-DBUILD_capinfos=$(usex capinfos)
-DBUILD_captype=$(usex captype)
-DBUILD_ciscodump=$(usex ciscodump)
-DBUILD_dftest=$(usex dftest)
-DBUILD_dpauxmon=$(usex dpauxmon)
-DBUILD_dumpcap=$(usex dumpcap)
-DBUILD_editcap=$(usex editcap)
-DBUILD_mergecap=$(usex mergecap)
-DBUILD_mmdbresolve=$(usex maxminddb)
-DBUILD_randpkt=$(usex randpkt)
-DBUILD_randpktdump=$(usex randpktdump)
-DBUILD_reordercap=$(usex reordercap)
-DBUILD_sdjournal=$(usex sdjournal)
-DBUILD_sharkd=$(usex sharkd)
-DBUILD_sshdump=$(usex sshdump)
-DBUILD_text2pcap=$(usex text2pcap)
-DBUILD_tfshark=OFF
-DBUILD_tshark=$(usex tshark)
-DBUILD_udpdump=$(usex udpdump)
-DBUILD_wireshark=$(usex gui)
-DUSE_qt6=$(usex gui)
-DENABLE_WERROR=OFF
-DENABLE_BCG729=$(usex bcg729)
-DENABLE_BROTLI=$(usex brotli)
-DENABLE_CAP=$(usex filecaps caps)
-DENABLE_GNUTLS=$(usex ssl)
-DENABLE_PKCS11=$(usex pkcs11)
-DENABLE_ILBC=$(usex ilbc)
-DENABLE_KERBEROS=$(usex kerberos)
-DENABLE_LUA=$(usex lua)
-DENABLE_LZ4=$(usex lz4)
-DENABLE_MINIZIP=$(usex minizip)
-DENABLE_MINIZIPNG=OFF
-DENABLE_NETLINK=$(usex netlink)
-DENABLE_NGHTTP2=$(usex http2)
-DENABLE_NGHTTP3=$(usex http3)
-DENABLE_OPUS=$(usex opus)
-DENABLE_PCAP=$(usex pcap)
-DENABLE_PLUGINS=$(usex plugins)
-DENABLE_PLUGIN_IFDEMO=OFF
-DENABLE_SBC=$(usex sbc)
-DENABLE_SMI=$(usex smi)
-DENABLE_SNAPPY=$(usex snappy)
-DENABLE_SPANDSP=$(usex spandsp)
-DBUILD_wifidump=$(usex wifi)
-DENABLE_XXHASH=$(usex xxhash)
-DENABLE_ZLIB=$(usex zlib)
-DENABLE_ZLIBNG=OFF
-DENABLE_ZSTD=$(usex zstd)
)
tc-is-lto && mycmakeargs+=( -DENABLE_LTO=ON )
cmake_src_configure
}
src_test() {
cmake_build test-programs
# https://www.wireshark.org/docs/wsdg_html_chunked/ChTestsRunPytest.html
epytest \
--disable-capture \
--skip-missing-programs=all \
--program-path "${BUILD_DIR}"/run
}
src_install() {
# bug #928577
# https://gitlab.com/wireshark/wireshark/-/commit/fe7bfdf6caac9204ab5f34eeba7b0f4a0314d3cd
cmake_src_install install-headers
if ! use doc; then
# prepare Relase Notes redirector (bug #939195)
local relnotes="doc/Wireshark Release Notes.html"
# by default create a link for our specific version
local relversion="wireshark-${PV}.html"
# for 9999 we link to the release notes index page
if [[ ${PV} == *_rc* ]] || [[ ${PV} == *9999* ]] ; then
relversion=""
fi
# patch version into redirector & install it
sed -e "s/#VERSION#/${relversion}/g" < "${FILESDIR}/release-notes.html" > "${relnotes}" || die
dodoc "${relnotes}"
fi
# FAQ is not required as is installed from help/faq.txt
dodoc AUTHORS ChangeLog README* doc/randpkt.txt doc/README*
# install headers
insinto /usr/include/wireshark
doins "${BUILD_DIR}"/config.h
# If trying to remove this, try build e.g. libvirt first!
# At last check, Fedora is still doing this too.
local dir dirs=(
epan
epan/crypt
epan/dfilter
epan/dissectors
epan/ftypes
wiretap
wsutil
wsutil/wmem
)
for dir in "${dirs[@]}" ; do
insinto /usr/include/wireshark/${dir}
doins ${dir}/*.h
done
if use gui ; then
local s
for s in 16 32 48 64 128 256 512 1024 ; do
insinto /usr/share/icons/hicolor/${s}x${s}/apps
newins resources/icons/wsicon${s}.png wireshark.png
done
for s in 16 24 32 48 64 128 256 ; do
insinto /usr/share/icons/hicolor/${s}x${s}/mimetypes
newins resources/icons/WiresharkDoc-${s}.png application-vnd.tcpdump.pcap.png
done
fi
if [[ -d "${ED}"/usr/share/appdata ]] ; then
rm -r "${ED}"/usr/share/appdata || die
fi
}
pkg_postinst() {
xdg_pkg_postinst
# Add group for users allowed to sniff.
chgrp pcap "${EROOT}"/usr/bin/dumpcap
if use dumpcap && use pcap ; then
fcaps -o 0 -g pcap -m 4710 -M 0710 \
cap_dac_read_search,cap_net_raw,cap_net_admin \
"${EROOT}"/usr/bin/dumpcap
fi
ewarn "NOTE: To capture traffic with wireshark as normal user you have to"
ewarn "add yourself to the pcap group. This security measure ensures"
ewarn "that only trusted users are allowed to sniff your traffic."
}