gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-08-05 12:38:09 -07:00
Code Issues Projects Releases Wiki Activity

games-rpg/manaplus: Bump to version 1.6.11.5

Browse Source 
Package-Manager: portage-2.3.2
This commit is contained in:
Lars Wendler
2016-11-17 18:44:36 +01:00
parent 40ef3f47ef
commit 1926bc8758
2 changed files with 100 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
games-rpg/manaplus/Manifest
View File

@@ -1,2 +1,3 @@
DIST manaplus-1.6.10.22.tar.xz 11749908 SHA256 dde06c2cf3c7f7d132f3d5ff74f2eafeb17f987115f3625fa2a4dc3d83428b50 SHA512 f335a57ef643a0bd61681182e1d9bf2c6b16d3766b629c8a45904b7e118e6b435d47abacc0804fba03a65ee0a335535d37b589eb78d22bef2e7477d9df7321de WHIRLPOOL 055ccc4a80d21bddd7824d6c122dcb7587eab9eb806c7c47efb4612517ae8b556a6ea3afe57692292959f504804c3015e30a51ae2213648655310a3de6b1f4b6
DIST manaplus-1.6.11.5.tar.xz 11744332 SHA256 cb5ac8a8df93b9a6698a53048a64e6b6f1d431e8da0c0a3b55b01e5a58dea3c5 SHA512 3b934ec9403a2eefd637d3193f16069d208635eea484ebcbf5780bd0dd42eba1eb179467bc2f616e4c432ae61289f6ed96926c985707885190066c2b17c3b348 WHIRLPOOL e12d69aa4f469b5e66a43feecf62910c742ff957a4a1767f060870fdec098e81743f1166e68cdc6b035fa0b461154e6de5622bb30d3c5e467ae26df4f5755805
DIST manaplus-1.6.3.26.tar.xz 9721160 SHA256 87aee4fdaec09337fe711ee85e515470374ea9387e45622caa712a6414f5b253 SHA512 f84718c40799c619a2a320e5589dffa05f52ebd7e4710c640947f4083c59146bb2b7c10a429f68f9963086f1a07c92b8a049c0a0092659108cf52c767d834566 WHIRLPOOL 4887d9699378e3fad95f48268234c1279bbfed66138cdbd9875227e9ebc8c598ac6aa530230537cfc79d1d100216f4b3049e5c4b55ae34545ea09c5fdec284dc

99
games-rpg/manaplus/manaplus-1.6.11.5.ebuild Normal file
View File

@@ -0,0 +1,99 @@
# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=6
[[ ${PV} == 9999 ]] && inherit autotools git-r3
DESCRIPTION="OpenSource 2D MMORPG client for Evol Online and The Mana World"
HOMEPAGE="http://manaplus.evolonline.org"
if [[ ${PV} == 9999 ]] ; then
EGIT_REPO_URI="https://github.com/ManaPlus/ManaPlus.git"
else
SRC_URI="http://download.evolonline.org/manaplus/download/${PV}/${P}.tar.xz"
KEYWORDS="~amd64 ~x86"
fi
LICENSE="GPL-2+"
SLOT="0"
IUSE="mumble nls opengl pugixml +sdl2 test"
RDEPEND="
>=dev-games/physfs-1.0.0
media-fonts/dejavu
media-fonts/liberation-fonts
media-fonts/mplus-outline-fonts
media-fonts/wqy-microhei
media-libs/libpng:0=
net-misc/curl
sys-libs/zlib
x11-apps/xmessage
x11-libs/libX11
x11-misc/xdg-utils
mumble? ( media-sound/mumble )
nls? ( virtual/libintl )
opengl? ( virtual/opengl )
pugixml? ( dev-libs/pugixml )
!pugixml? ( dev-libs/libxml2 )
sdl2? (
media-libs/libsdl2[X,opengl?,video]
media-libs/sdl2-gfx
media-libs/sdl2-image[png]
media-libs/sdl2-mixer[vorbis]
media-libs/sdl2-net
media-libs/sdl2-ttf
)
!sdl2? (
media-libs/libsdl[X,opengl?,video]
media-libs/sdl-gfx
media-libs/sdl-image[png]
media-libs/sdl-mixer[vorbis]
media-libs/sdl-net
media-libs/sdl-ttf
)"
DEPEND="${RDEPEND}
virtual/pkgconfig
nls? ( sys-devel/gettext )"
src_prepare() {
default
if [[ ${PV} == 9999 ]] ; then
eautoreconf
fi
}
src_configure() {
CONFIG_SHELL=/bin/bash \
econf \
--localedir=/usr/share/locale \
--without-internalsdlgfx \
$(use_with mumble) \
$(use_enable nls) \
$(use_with opengl) \
--enable-libxml=$(usex pugixml pugixml libxml) \
$(use_with sdl2) \
$(use_enable test unittests)
}
src_install() {
default
local destpath="/usr/share/${PN}"
dosym /usr/share/fonts/dejavu/DejaVuSans-Bold.ttf "${destpath}"/data/fonts/dejavusans-bold.ttf
dosym /usr/share/fonts/dejavu/DejaVuSans.ttf "${destpath}"/data/fonts/dejavusans.ttf
dosym /usr/share/fonts/dejavu/DejaVuSansMono-Bold.ttf "${destpath}"/data/fonts/dejavusansmono-bold.ttf
dosym /usr/share/fonts/dejavu/DejaVuSansMono.ttf "${destpath}"/data/fonts/dejavusansmono.ttf
dosym /usr/share/fonts/dejavu/DejaVuSerifCondensed-Bold.ttf "${destpath}"/data/fonts/dejavuserifcondensed-bold.ttf
dosym /usr/share/fonts/dejavu/DejaVuSerifCondensed.ttf "${destpath}"/data/fonts/dejavuserifcondensed.ttf
dosym /usr/share/fonts/liberation-fonts/LiberationMono-Bold.ttf "${destpath}"/data/fonts/liberationsansmono-bold.ttf
dosym /usr/share/fonts/liberation-fonts/LiberationMono-Regular.ttf "${destpath}"/data/fonts/liberationsansmono.ttf
dosym /usr/share/fonts/liberation-fonts/LiberationSans-Bold.ttf "${destpath}"/data/fonts/liberationsans-bold.ttf
dosym /usr/share/fonts/liberation-fonts/LiberationSans-Regular.ttf "${destpath}"/data/fonts/liberationsans.ttf
dosym /usr/share/fonts/mplus-outline-fonts/mplus-1p-bold.ttf "${destpath}"/data/fonts/mplus-1p-bold.ttf
dosym /usr/share/fonts/mplus-outline-fonts/mplus-1p-regular.ttf "${destpath}"/data/fonts/mplus-1p-regular.ttf
dosym /usr/share/fonts/wqy-microhei/wqy-microhei.ttc "${destpath}"/data/fonts/wqy-microhei.ttf
}
src_test() {
make check
}