mail-filter/pyzor: add 1.0.0_p20211223

Signed-off-by: Sam James <sam@gentoo.org>

mail-filter/pyzor/Manifest

@@ -1 +1,2 @@
 DIST pyzor-1.0.0_p20200523.tar.gz 138077 BLAKE2B 13ad30f06ce32a24a42dd5aaa21ad2a6700df1bac3dc54a86532748688b094ee0f56a8e28e34336298388c6e0b95868e95d040866c9afa561d867069496608fe SHA512 afe3b14794aea68b1a7d72840257976c7c9f755a6f6dcaaf6ebacab465c176fe2aa84f3fe176006cdbe26ef0b07ed949f75f6ef729f65c604fadf6ce8472da8f
+DIST pyzor-1.0.0_p20211223.tar.gz 138500 BLAKE2B 242a7b2df3451f659d820771454e685868792bd2275b6d69d4c4adfd6044c781abe2d72fe1500a6074851faf8e88e95d6578c546d4d95fda03e11609d1a0b436 SHA512 218bea40515a21b1e08b2bad5b7ba339ba84fff2da425dc58df72a967730ebe10e319944e1604ff56bb37f6a8ae7bc0cd974b54b18a4878ba103131b8ea47b67

mail-filter/pyzor/pyzor-1.0.0_p20211223.ebuild

@@ -0,0 +1,59 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+inherit distutils-r1
+
+MY_COMMIT="2dbe627c1ec245db206cdc73bf1f9d785f1512d8"
+DESCRIPTION="A distributed, collaborative spam detection and filtering network"
+HOMEPAGE="https://github.com/SpamExperts/pyzor"
+SRC_URI="https://github.com/SpamExperts/pyzor/archive/${MY_COMMIT}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}-${MY_COMMIT}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc gdbm gevent mysql pyzord redis test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	pyzord? (
+		gdbm? ( $(python_gen_impl_dep 'gdbm') )
+		gevent? ( dev-python/gevent[${PYTHON_USEDEP}] )
+		mysql? ( dev-python/mysqlclient[${PYTHON_USEDEP}] )
+		redis? ( dev-python/redis-py[${PYTHON_USEDEP}] )
+	)"
+DEPEND="
+	test? (
+		gdbm? ( $(python_gen_impl_dep 'gdbm') )
+		redis? ( dev-python/redis-py[${PYTHON_USEDEP}] )
+	)
+"
+
+# TODO: maybe upstream would support skipping tests for which the
+# dependencies are missing?
+REQUIRED_USE="
+	pyzord? ( || ( gdbm redis ) )
+	test? ( gdbm redis )
+"
+
+distutils_enable_sphinx docs
+
+python_test() {
+	pytest -vv tests/unit || die "Tests fail with ${EPYTHON}"
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	if use pyzord; then
+		dodir /usr/sbin
+		mv "${ED}"/usr/bin/pyzord* "${ED}/usr/sbin" \
+		   || die "failed to relocate pyzord"
+	else
+		rm "${ED}"/usr/bin/pyzord* || die "failed to remove pyzord"
+	fi
+}