sys-apps/cpu-x: add 5.1.3

Signed-off-by: Ben Kohler <bkohler@gentoo.org>

sys-apps/cpu-x/Manifest

@@ -4,3 +4,4 @@ DIST cpu-x-5.0.4.tar.gz 1995465 BLAKE2B 6e3982040400a2bbdb7fba0cac24f1b183792693
 DIST cpu-x-5.1.0.tar.gz 2705947 BLAKE2B 8f5989170ebba7b943bc4bf5d3550ff2a7f9d527305d2ee4ad9ffa39cebcf089098b6ed0340c001d0926d0a093fd559273b3b61b404cc21ece3aea937097c1f5 SHA512 7f0ce6123cdd957663aa1012194cee12a09cdd3a44b0bcdfecad36315a3b1c1e5e6461ffa0d9613c0ff275332d4aae0499f8687d1acbcd921703971508819ed6
 DIST cpu-x-5.1.1.tar.gz 2721238 BLAKE2B bfd0f1e919e3ca3663b54b41f50dadc6c0ebc2329bad58253ef26f5af0c1f5b3ce713f7309be25c16990d056df415aa5ce76e5fb9bcb975675568a856290c45c SHA512 8601946feaed567e144350c69761a46a7f5ff1aa47c1d550afca11d6b3eb7546b125c56ecd4f266a33d5ee8a6ef09eba01f7c6570dde25c4f1989971eb6dbb27
 DIST cpu-x-5.1.2.tar.gz 2727723 BLAKE2B 570762bd7c58ebb6b168b7dab78b9a58a55b5619c69e0ac0b30d51600b5bf5c4962be8c353f51b0a3f330f536af99dbfae8b08ee17f43b12cc6c30f76bb018a5 SHA512 3c07efbebc44b3a085daea161ce0144a786b76ac46b80141ede985e07a79837b6f40d2af3203b3d6f1dad6c6ff6dff99fbb553e705a9471b55b041f42db2111e
+DIST cpu-x-5.1.3.tar.gz 2732630 BLAKE2B 86f7dff5ab93f98e54154104f75a221bc0bf966014f3f89176f0049b89cd03aa01c19c6eec9d91a8204137117df2e69624904d3d1b1aea5deecf83905838cc33 SHA512 2823c313d2d940443eee174c5cbfa83c3dd003a3b669c3d7dcb85f14f80571e7a232675c380ab8e4eea977f3c4b6c6d5d4d3bd5c6a1215f14252defc16cd9375

sys-apps/cpu-x/cpu-x-5.1.3.ebuild

@@ -0,0 +1,83 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN="CPU-X"
+
+inherit cmake gnome2-utils xdg
+
+DESCRIPTION="A Free software that gathers information on CPU, motherboard and more"
+HOMEPAGE="https://thetumultuousunicornofdarkness.github.io/CPU-X/"
+SRC_URI="https://github.com/TheTumultuousUnicornOfDarkness/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="-* ~amd64"
+IUSE="+cpu force-libstatgrab +gpu gui +ncurses +nls opencl +pci test vulkan"
+RESTRICT="!test? ( test )"
+
+COMMON_DEPEND="
+	dev-libs/glib:2
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/pango
+	force-libstatgrab? ( sys-libs/libstatgrab )
+	!force-libstatgrab? ( sys-process/procps:= )
+	gui? ( dev-cpp/gtkmm:3.0
+		>=x11-libs/gtk+-3.12:3 )
+	cpu? ( >=dev-libs/libcpuid-0.7.0:= )
+	gpu? ( >=media-libs/glfw-3.3
+		media-libs/libglvnd )
+	pci? ( sys-apps/pciutils )
+	ncurses? ( sys-libs/ncurses:=[tinfo] )
+	opencl? ( virtual/opencl )
+	vulkan? ( media-libs/vulkan-loader
+		>=dev-util/vulkan-headers-1.3.151 )
+"
+
+DEPEND="
+	test? (
+		sys-apps/grep[pcre]
+		sys-apps/mawk
+		sys-apps/nawk
+	)
+
+	${COMMON_DEPEND}
+"
+
+BDEPEND="
+	dev-lang/nasm
+	nls? ( sys-devel/gettext )
+"
+
+RDEPEND="${COMMON_DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DFORCE_LIBSTATGRAB=$(usex force-libstatgrab)
+		-DWITH_GETTEXT=$(usex nls)
+		-DWITH_GTK=$(usex gui)
+		-DWITH_LIBCPUID=$(usex cpu)
+		-DWITH_LIBGLFW=$(usex gpu)
+		-DWITH_LIBPCI=$(usex pci)
+		-DWITH_LIBSTATGRAB=OFF
+		-DWITH_NCURSES=$(usex ncurses)
+		-DWITH_OPENCL=$(usex opencl)
+		-DWITH_VULKAN=$(usex vulkan)
+	)
+	use gui && mycmakeargs+=( -DGSETTINGS_COMPILE=OFF )
+
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}