media-gfx/opentoonz: version bump to 1.4.0

Signed-off-by: Tact Yoshida <otakuto.gentoo@gmail.com>
Package-Manager: Portage-2.3.84, Repoman-2.3.20
Closes: https://github.com/gentoo/gentoo/pull/14523
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

media-gfx/opentoonz/Manifest

@@ -1,3 +1,4 @@
 DIST opentoonz-1.1.2.tar.gz 36777909 BLAKE2B d822218c5ea1843a50da8d799bd9edf6998bd424ec2b65600371a0ae9f69aaea0d1c45aa53c3a0287c67459b8101a82bc0c339510859f4fbac3a116c9671df08 SHA512 800a741cb40e7dede79ef92705fc8fe3a23524c8a4397c30f80a81a7513c98606fb1bb5574188969ba08cfe8995d679f9fc5ecb696a6ac14c48aa2646a2c871e
 DIST opentoonz-1.2.1.tar.gz 39843446 BLAKE2B f9035bab5c6fa1d86459b401ca94acbffe8e38a2f5ec2bc97f303c7e829b9f6695480e7ab7a7560909f6ce45109ca1704d5020ff774964b5ed72b1b01588e93b SHA512 3eaf5983b5ec7424338e25975228b9bf6e9da61b2699c52377528966ecf07971868426bda0a64c780c2876cc1f0e4adb63c46767e8099fbfe32a8d1586c13f44
 DIST opentoonz-1.3.0.tar.gz 39920932 BLAKE2B 292e01c078a4cf461fff0814a60e4ab6aea9a74a63f23e854815632432e07e65d5c01dce9d3aab36595f94ca06dd83b078e52858532d8dadb2e7518514c08b08 SHA512 5df272c943f2c222a457545c99388266579d88c702d6c7e71dfe0c924a0189e30323cf9e369c96755c507ee5347620da0140215b2647555f0b3bdae41c615c71
+DIST opentoonz-1.4.0.tar.gz 53531141 BLAKE2B adb7a85fb0581d92119b5f6b75dc320428ea0763955f8c883072cba78045acdeea75a5cea82065a29d2c59f53b4843d8ff92690c9a47c01605b4702fd36d6c13 SHA512 777f5d59ec8076e1e53a81347e15bef198bea77449073f1e9d5fdd371a61e20fd6dc8b26c6656c783959782bd71008fbb63c05742aaa50c92bd317aded7d0649

media-gfx/opentoonz/opentoonz-1.4.0.ebuild

@@ -0,0 +1,86 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils xdg-utils
+
+DESCRIPTION="An open-source full-featured 2D animation creation software"
+HOMEPAGE="https://github.com/opentoonz/opentoonz"
+SRC_URI="https://github.com/opentoonz/opentoonz/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD libtiff"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+	virtual/pkgconfig
+"
+RDEPEND="
+	app-arch/lz4:=
+	>=dev-libs/boost-1.55.0:=
+	dev-libs/lzo:2
+	>=dev-qt/qtcore-5.9:5
+	>=dev-qt/qtgui-5.9:5
+	>=dev-qt/qtmultimedia-5.9:5[widgets]
+	>=dev-qt/qtnetwork-5.9:5
+	>=dev-qt/qtopengl-5.9:5
+	>=dev-qt/qtprintsupport-5.9:5
+	>=dev-qt/qtscript-5.9:5
+	>=dev-qt/qtsvg-5.9:5
+	>=dev-qt/qtwidgets-5.9:5
+	>=dev-qt/qtxml-5.9:5
+	media-libs/freeglut
+	media-libs/freetype:2
+	media-libs/glew:=
+	media-libs/libjpeg-turbo
+	>=media-libs/libmypaint-1.3.0:=
+	media-libs/libpng:=
+	>=sci-libs/superlu-4.1:=
+	sys-libs/zlib
+	virtual/cblas
+	virtual/libusb:1
+	virtual/opengl
+"
+DEPEND="
+	${RDEPEND}
+"
+
+CMAKE_USE_DIR="${S}"/toonz/sources
+CMAKE_MAKEFILE_GENERATOR=emake
+
+src_configure() {
+	local mycmakeargs=(
+		-DTIFF_LIBRARY="${S}/thirdparty/tiff-4.0.3/libtiff/.libs/libtiff.a"
+		-DSUPERLU_INCLUDE_DIR="${EPREFIX}/usr/include/superlu"
+		-DLZO_INCLUDE_DIR="${EPREFIX}/usr/include/lzo"
+		-DCMAKE_SKIP_RPATH=ON
+	)
+
+	# The upstream uses their own modified libtiff
+	# See: https://github.com/opentoonz/opentoonz/blob/master/doc/how_to_build_linux.md#building-libtiff
+	cd thirdparty/tiff-4.0.3 || die
+	econf \
+		--with-pic \
+		--disable-jbig \
+		--enable-static \
+		--disable-shared
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cd "${S}"/thirdparty/tiff-4.0.3 || die
+	emake
+
+	cmake-utils_src_compile
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}