app-admin/eselect: Version bump.

Package-Manager: Portage-2.3.40, Repoman-2.3.9

app-admin/eselect/Manifest

@@ -1 +1,2 @@
 DIST eselect-1.4.12.tar.xz 177520 BLAKE2B 0938fe9bd8785fe711edc1af63a9c318a4a5fe9141c61d7f1c4da0352242322f1e18e4f68f7e219a1aa2beae5b25ddac58d7c47d4272408fd8fe5207324ef7c7 SHA512 2ea182364dfb2333112e9eebe691e1963e95a4c9ab40945eb2e5bc8c81da76105c1ae6aa3d153b78dea6c1e0cadb9b0237f7556b8ceb9d48e0fba67a642d6081
+DIST eselect-1.4.13.tar.xz 177848 BLAKE2B 70e5a793759e16119f5233b2c974e0fcc8d213b2033e2b3b76e0a047797b1a0f2feb21ad3beda72f644b498725b4d8ff5c221dcd0870adf5197eaf81c6f3c895 SHA512 5ce10bd288268bc5b52031703f8ac8f3cf07bb22039339bb00c92583ed226162ea8865788f5c1ff4e058d38f0bf25e3557273fb1e839e0391c1fafb9f702bc11

app-admin/eselect/eselect-1.4.13.ebuild

@@ -0,0 +1,61 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit bash-completion-r1
+
+DESCRIPTION="Gentoo's multi-purpose configuration and management tool"
+HOMEPAGE="https://wiki.gentoo.org/wiki/Project:Eselect"
+SRC_URI="https://dev.gentoo.org/~ulm/eselect/${P}.tar.xz"
+
+LICENSE="GPL-2+ || ( GPL-2+ CC-BY-SA-3.0 )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~x64-cygwin ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="doc emacs vim-syntax"
+
+RDEPEND="sys-apps/sed
+	|| (
+		sys-apps/coreutils
+		sys-freebsd/freebsd-bin
+		app-misc/realpath
+	)"
+DEPEND="${RDEPEND}
+	doc? ( dev-python/docutils )"
+RDEPEND="${RDEPEND}
+	sys-apps/file
+	sys-libs/ncurses:0"
+
+PDEPEND="emacs? ( app-emacs/eselect-mode )
+	vim-syntax? ( app-vim/eselect-syntax )"
+
+src_compile() {
+	emake
+	use doc && emake html
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	newbashcomp misc/${PN}.bashcomp ${PN}
+	dodoc AUTHORS ChangeLog NEWS README TODO doc/*.txt
+	if use doc; then
+		docinto html
+		dodoc *.html doc/*.html doc/*.css
+	fi
+
+	# needed by news module
+	keepdir /var/lib/gentoo/news
+	if ! use prefix; then
+		fowners root:portage /var/lib/gentoo/news
+		fperms g+w /var/lib/gentoo/news
+	fi
+}
+
+pkg_postinst() {
+	# fowners in src_install doesn't work for the portage group:
+	# merging changes the group back to root
+	if ! use prefix; then
+		chgrp portage "${EROOT}/var/lib/gentoo/news" \
+			&& chmod g+w "${EROOT}/var/lib/gentoo/news"
+	fi
+}