www-client/opera-developer: Version 71.0.3763.0

Package-Manager: Portage-3.0.0, Repoman-2.3.23
Signed-off-by: Jeroen Roovers <jer@gentoo.org>

www-client/opera-developer/Manifest

@@ -2,3 +2,4 @@ DIST opera-developer_71.0.3735.0_amd64.deb 67521252 BLAKE2B 0e5df62a5e6a81647593
 DIST opera-developer_71.0.3742.0_amd64.deb 67574880 BLAKE2B 3b878ba41696858c0600534b89840bfe11443a4e859931434f888a37d1c9e846cf7dd5f43f8c84ea6b1064be7bb53049254935a87418f87f9fdf43bebb6149ae SHA512 b93c0fff4cf3ff8f21685392137a5d1b9a147dd16d0e44874572e3cf1835a858ac4b9dad472661dc1a583cd7e6a1c4b07fb94657187220a24bae9e3cd2b201c5
 DIST opera-developer_71.0.3749.0_amd64.deb 67691960 BLAKE2B 7f9a5a0a14d2dbc36d3771b101633b5b26b10e48c480ecc03c591e0e92d88772e6e27941183aba14a4e770367fccab8867099ea8473ca3efe3331adabddfde43 SHA512 ec4240f969018dc599f212a191587eeefa730f789eafda61c734a0ecd623d5899887fcfb844c35492fa3bb93e7aa88406d9b45e243e43aaf23bd2c14653fc4ac
 DIST opera-developer_71.0.3756.0_amd64.deb 67772036 BLAKE2B 367035f5046ff03d87ded6eb0be40ee5398fb149229b4f9584e912c0485979b03ffb6865c27b8ee8b45c04d58f6eff8cb2f730e68ac878394a2542ebc25248fa SHA512 dc9f409bf6104548ed9754e1c1506d8c9cbc48c3a628f0ebf5453a429af210d801ee586afa8f558e2d702ac28b71fe1253408ad97323b964a6a5fc19aee84609
+DIST opera-developer_71.0.3763.0_amd64.deb 67783224 BLAKE2B 95f28d165f2b52d3dbdd52ce3f312952f1cfb483d96defd38f4b6e51b54f02b5ef45133d97b11b56dd4c6da1b1b9eb3a66cf5dcb84d8f7f661a0169fbb98a069 SHA512 04bd8afb6fd5af08b85197f4c2346e5e42b8699019a8772c9e377107a9c66d4f487b6d2a1895120693f36574a9bab01e882f07da9f1991674529e5344efe5f4e

www-client/opera-developer/opera-developer-71.0.3763.0.ebuild

@@ -0,0 +1,115 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+CHROMIUM_LANGS="
+	be bg bn ca cs da de el en-GB es es-419 fi fil fr fr-CA hi hr hu id it
+	ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+	zh-CN zh-TW
+"
+inherit chromium-2 multilib unpacker xdg-utils
+
+DESCRIPTION="A fast and secure web browser"
+HOMEPAGE="https://www.opera.com/"
+LICENSE="OPERA-2014"
+SLOT="0"
+SRC_URI_BASE="
+	https://download1.operacdn.com/pub/
+	https://download2.operacdn.com/pub/
+	https://download3.operacdn.com/pub/
+	https://download4.operacdn.com/pub/
+"
+SRC_URI="amd64? ("
+for uri in ${SRC_URI_BASE}; do
+SRC_URI+="
+	"${uri}${PN}/${PV}/linux/${PN}_${PV}_amd64.deb"
+"
+done
+SRC_URI+=")"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	gnome-base/gconf:2
+	media-libs/alsa-lib
+	media-libs/fontconfig
+	media-libs/freetype
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libX11
+	x11-libs/libXScrnSaver
+	x11-libs/libXcomposite
+	x11-libs/libXcursor
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXi
+	x11-libs/libXrandr
+	x11-libs/libXrender
+	x11-libs/libXtst
+	x11-libs/libnotify
+	x11-libs/pango[X]
+"
+
+QA_PREBUILT="*"
+S=${WORKDIR}
+
+src_unpack() {
+	unpack_deb ${A}
+}
+
+pkg_setup() {
+	OPERA_HOME="usr/$(get_libdir)/${PN}"
+}
+
+src_prepare() {
+	default
+
+	case ${ARCH} in
+		amd64)
+			mv usr/lib/x86_64-linux-gnu usr/$(get_libdir) || die
+			rm -r usr/lib || die
+			;;
+		x86)
+			mv usr/lib/i386-linux-gnu/${PN} usr/$(get_libdir)/ || die
+			;;
+	esac
+
+	mv usr/share/doc/${PN} usr/share/doc/${PF} || die
+	gunzip usr/share/doc/${PF}/changelog.gz || die
+
+	rm usr/bin/${PN} || die
+
+	pushd "${OPERA_HOME}/localization" > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	sed -i \
+		-e 's|^TargetEnvironment|X-&|g' \
+		usr/share/applications/${PN}.desktop || die
+}
+
+src_install() {
+	mv * "${D}" || die
+	dosym ../$(get_libdir)/${PN}/${PN} /usr/bin/${PN}
+	fperms 4711 /usr/$(get_libdir)/${PN}/opera_sandbox
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}