dev-python/rapidfuzz: Bump to 3.9.7

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/rapidfuzz/Manifest

@@ -1 +1,2 @@
 DIST rapidfuzz-3.9.6.tar.gz 1596107 BLAKE2B e108320e05ad3ad194b1ffa05d5fddc5bb6080e73ecb031117a0552d5685734870af4a87503022fceadf3fd38b31e71f85c05483b4aaaf4a9d7358d4566699b4 SHA512 015b947dcfd12ee48c7592ac2fc204833d8aa8e43110dab12dff7650e9f309a9a2017d2faf89b3c154cead23d9dc7fc1658f0ff5d2f8b5b3c73b2c97f021c7d9
+DIST rapidfuzz-3.9.7.tar.gz 1596228 BLAKE2B ba3188748dc408cbe91718e890fd67e9ee47feacfe2b307038d7bfc6ffdb7aebb016b2276b591a1fd3a5c59df29a1b55a9555505f938638907d11deec9575f98 SHA512 b1a50f3ff0af044e0aa57a053bcefb3227dce2ed17b94ed82afe72203c6e858221c5ca955e4f190a0cb7adaeada11fab7fa5958e1c439deec60d96899207269d

dev-python/rapidfuzz/rapidfuzz-3.9.7.ebuild

@@ -0,0 +1,67 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+# custom wrapper over setuptools
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( pypy3 python3_{10..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Rapid fuzzy string matching in Python using various string metrics"
+HOMEPAGE="
+	https://github.com/rapidfuzz/RapidFuzz/
+	https://pypi.org/project/rapidfuzz/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+# all these are header-only libraries
+DEPEND="
+	>=dev-cpp/taskflow-3.0.0
+	>=dev-cpp/rapidfuzz-cpp-3.0.5
+	dev-python/numpy[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/cython-3[${PYTHON_USEDEP}]
+	>=dev-python/scikit-build-0.16.2[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	# sterilize build flags
+	sed -i -e '/CMAKE_INTERPROCEDURAL_OPTIMIZATION/d' CMakeLists.txt || die
+	# remove bundled libraries
+	rm -r extern || die
+	# force recythonization
+	find src -name '*.cxx' -delete || die
+	# do not require exact taskflow version
+	sed -i -e '/Taskflow/s:3\.7\.0::' CMakeLists.txt || die
+
+	distutils-r1_src_prepare
+
+	export RAPIDFUZZ_BUILD_EXTENSION=1
+}
+
+python_compile() {
+	distutils-r1_python_compile
+
+	# scikit-build is broken and reuses the same build
+	# https://github.com/scikit-build/scikit-build/issues/633
+	rm -r _skbuild || die
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}