dev-python/alembic: Bump to 1.16.5

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/alembic/Manifest

@@ -1 +1,2 @@
 DIST alembic-1.16.4.tar.gz 1968161 BLAKE2B 417279257dd1ee69039b5dea23ca8313ad3a6c67e51e94ad4eb7206e9c9384421b370f14f8b8fba342b214623c06da1c55598ed3e71362f93f8999e1be087d96 SHA512 7cd6ddd8ebb7c4f9b941ff611226c5a7a498e097dcd15ff1b7c4e6e584f1e2f3c6f0f66d34089708f84275c6b6cc0510580a39acf1e90393119ea4ed925c4d8a
+DIST alembic-1.16.5.tar.gz 1969868 BLAKE2B 9798e371ac26b5f6042bfc057e3b308d026d1b58446d70c23408ce0bd64c2115773af73868cdda5aa1fb303ec54eba65687d515b06b5cd774ed551c33f093e10 SHA512 871aa27c955c0b3ea8aed4c1f3ca5595d21e8b52b09eef9c225f5acba1c8011b6ff1a3c1081583cfefe49265739f9f3a358cf33aea4bb442636a3a9469cb4130

dev-python/alembic/alembic-1.16.5.ebuild

@@ -0,0 +1,57 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3_11 python3_{11..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Database migrations tool, written by the author of SQLAlchemy"
+HOMEPAGE="
+	https://github.com/sqlalchemy/alembic/
+	https://pypi.org/project/alembic/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+IUSE="doc"
+
+RDEPEND="
+	>=dev-python/sqlalchemy-1.4.0[${PYTHON_USEDEP}]
+	dev-python/mako[${PYTHON_USEDEP}]
+	>=dev-python/typing-extensions-4.12[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		sys-libs/timezone-data
+	)
+"
+
+EPYTEST_PLUGINS=()
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=()
+
+	if ! has_version "dev-python/black[${PYTHON_USEDEP}]"; then
+		EPYTEST_DESELECT+=(
+			tests/test_post_write.py::RunHookTest::test_module
+			tests/test_post_write.py::RunHookTest::test_module_black_with_cwd
+			tests/test_post_write.py::RunHookTest::test_module_filename_interpolation
+			tests/test_post_write.py::RunHookTest::test_module_path_in_config
+		)
+	fi
+
+	# setup.cfg contains -p no:warnings in addopts which triggers
+	# datetime.utcfromtimestamp() deprecation warning as an error in py3.12
+	epytest -o addopts=
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/. )
+	distutils-r1_python_install_all
+}