app-emulation/buildah: Bump to version 1.11.3

Package-Manager: Portage-2.3.77, Repoman-2.3.17
Signed-off-by: Zac Medico <zmedico@gentoo.org>
This commit is contained in:
Zac Medico
2019-10-17 21:43:42 -07:00
parent 4b75dd06be
commit 1671df0346
2 changed files with 58 additions and 0 deletions
+1
View File
@@ -1 +1,2 @@
DIST buildah-1.11.2.tar.gz 10128075 BLAKE2B ad8f4253b62cd7709bf5ae530d002190c1850da6bbfa7dff2281de0592422eccc67a4ba6e52f7a82d6c1b320b986237a84d0ffaaf9b3b1b93822a54621365250 SHA512 f491d96d5bb4d0aa03981fb58d24f36c2e3928179c8fb79e85f323ce9a65ae6da05b816d86ae43f94a83a1b2445b315f93ca28b531436d9b4e5861e4adef2aac
DIST buildah-1.11.3.tar.gz 10429884 BLAKE2B 2d433a128d115c6b2f3a9d246d41406993905dee357237796cea3295036d026ca93f8c98ca992cfebfa574ab0d5e7b974fd356a146b7cde58986166bc18a5645 SHA512 07fff3f8c044ad01a663bf5470b19f75568ce741b3bb45f656200099ba559622597111ede3e20331dc06139f2e58d962d92bf0fdd00284ca6ed05b5b66500975
@@ -0,0 +1,57 @@
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit bash-completion-r1 golang-vcs-snapshot
KEYWORDS="~amd64"
DESCRIPTION="A tool that facilitates building OCI images"
HOMEPAGE="https://github.com/containers/buildah"
LICENSE="Apache-2.0 BSD BSD-2 CC-BY-SA-4.0 ISC MIT MPL-2.0"
SLOT="0"
IUSE="ostree selinux"
EGO_PN="${HOMEPAGE#*//}"
EGIT_COMMIT="v${PV}"
GIT_COMMIT="0bafbfe"
SRC_URI="https://${EGO_PN}/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
RDEPEND="app-crypt/gpgme:=
app-emulation/skopeo
dev-libs/libgpg-error:=
dev-libs/libassuan:=
sys-fs/lvm2:=
sys-libs/libseccomp:=
selinux? ( sys-libs/libselinux:= )"
DEPEND="${RDEPEND}"
RESTRICT="test"
REQUIRED_USE="!selinux? ( !ostree )"
S="${WORKDIR}/${P}/src/${EGO_PN}"
src_prepare() {
default
sed -e 's|^\(GIT_COMMIT ?= \).*|\1'${GIT_COMMIT}'|' -i Makefile || die
[[ -f ostree_tag.sh ]] || die
use ostree || { echo -e "#!/bin/sh\necho containers_image_ostree_stub" > \
ostree_tag.sh || die; }
[[ -f selinux_tag.sh ]] || die
use selinux || { echo -e "#!/bin/sh\ntrue" > \
selinux_tag.sh || die; }
}
src_compile() {
export -n GOCACHE XDG_CACHE_HOME
GOPATH="${WORKDIR}/${P}" emake all
}
src_install() {
dodoc CHANGELOG.md CONTRIBUTING.md README.md install.md troubleshooting.md
doman docs/*.1
dodoc -r docs/tutorials
dobin ${PN} imgtype
dobashcomp contrib/completions/bash/buildah
}
src_test() {
GOPATH="${WORKDIR}/${P}" emake test-unit
}