dev-python/eventlet: Bump to 0.33.1

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/eventlet/Manifest

@@ -1 +1,2 @@
 DIST eventlet-0.33.0.tar.gz 414929 BLAKE2B cfb2500d25ed56f5eb7b81968286b1d7d0286511e1658dca8ab4fcf07029390168aea1f95092b5f1b486bd6fb34a96b762c2087cd19f903d232f1da183508888 SHA512 52ef5c6997d0c8a3b55d5f6e969320e06950503984c90440b484020ba346d622ba99abf2bd389b962534849b0c70d80b06f110b2586417f27fb6dde725bfaef4
+DIST eventlet-0.33.1.tar.gz 415294 BLAKE2B 25efb9b9848a6e0db2040d111288447aa07ceb70d2cbd9b3d189a2ca58aadad6b6d64054f76f3329ff7ca832efccbabb780c839c4db6d95a5b623d80079b7da3 SHA512 c8ece6a26039631b13ecc188f480f348a42551267fb6135551899dec7a23d0cfd032c14728e114901e4d256bf580203bfbdb1795881abdd71e49a53f8ed58964

dev-python/eventlet/eventlet-0.33.1.ebuild

@@ -0,0 +1,63 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..9} )
+
+inherit distutils-r1
+
+DESCRIPTION="Highly concurrent networking library"
+HOMEPAGE="
+	https://pypi.org/project/eventlet/
+	https://github.com/eventlet/eventlet/
+"
+SRC_URI="mirror://pypi/${PN::1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="examples"
+
+RDEPEND="
+	>=dev-python/dnspython-1.15.0[${PYTHON_USEDEP}]
+	>=dev-python/six-1.10.0[${PYTHON_USEDEP}]
+	virtual/python-greenlet[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/pyopenssl[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/eventlet-0.25.1-tests.patch"
+	"${FILESDIR}/eventlet-0.30.0-tests-socket.patch"
+	"${FILESDIR}/eventlet-0.30.2-test-timeout.patch"
+)
+
+distutils_enable_tests nose
+
+src_prepare() {
+	# increase timeout - #791748
+	sed -e '/eventlet.sleep/s/0.1/5.0/' -i tests/isolated/patcher_fork_after_monkey_patch.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	unset PYTHONPATH
+	export TMPDIR="${T}"
+	nosetests -v -x || die
+}
+
+python_install_all() {
+	if use examples; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		docinto examples
+		dodoc -r examples/.
+	fi
+
+	distutils-r1_python_install_all
+}