dev-python/peewee: add 3.17.6

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

dev-python/peewee/Manifest

@@ -1 +1,2 @@
 DIST peewee-3.17.5.gh.tar.gz 927674 BLAKE2B 45d23ebec38363a83441c916def460d76c7fe54175497df53de5a904d57b3d2cdbe077f757028b85f6a5eba0e65f1eab9ee99ceea11a00a9b111fce842ccd010 SHA512 b9878450a0759740f28cb6425ba0f14aa92e037bc4c888c13ae24bc38993787e64bff6342edcdf5364b5aac97c405e1c8e53e1140016e6bdbeba6d57d7f339ec
+DIST peewee-3.17.6.gh.tar.gz 929364 BLAKE2B f7add872316dae1210a4dec4a71cf0b5122010e3da854019887143111cca5ed7f53b48bdf68aaa215097bde8003878e4aae0ddf827fb3fd0ab635345815a0d7a SHA512 7250b931ebaab6f5e1fbc9461cb737e30eef794bbc6a15f6f1ba59e358bd9101c17d31112906d314a12f0a05b4c2112435f90053a866f3b91d0e5a1dc4aba2f8

dev-python/peewee/peewee-3.17.6.ebuild

@@ -0,0 +1,79 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+PYTHON_REQ_USE="sqlite"
+
+inherit distutils-r1
+
+DESCRIPTION="Small Python ORM"
+HOMEPAGE="
+	https://github.com/coleifer/peewee/
+	https://pypi.org/project/peewee/
+"
+SRC_URI="
+	https://github.com/coleifer/peewee/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv ~x86"
+IUSE="examples +native-extensions test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	native-extensions? ( dev-db/sqlite:3= )
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	test? (
+		dev-db/postgresql
+		dev-python/psycopg:0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs \
+	dev-python/sphinx-rtd-theme
+
+src_prepare() {
+	# disable test failing on postgres 16
+	sed -e 's/test_timeout/_&/' -i tests/sqliteq.py || die
+
+	default
+}
+
+src_compile() {
+	if ! use native-extensions; then
+		local -x NO_SQLITE=1
+	fi
+
+	distutils-r1_src_compile
+}
+
+src_test() {
+	initdb -D "${T}"/pgsql || die
+	pg_ctl -w -D "${T}"/pgsql start -o "-h '' -k '${T}'" || die
+	createdb -h "${T}" peewee_test || die
+
+	local -x PEEWEE_PSQL_HOST="${T}"
+	distutils-r1_src_test
+
+	pg_ctl -w -D "${T}"/pgsql stop || die
+}
+
+python_test() {
+	"${EPYTHON}" runtests.py -v 2 || die "tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use examples && DOCS=( examples/ )
+	distutils-r1_python_install_all
+}