dev-python/hishel: Bump to 0.1.3

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/hishel/Manifest

@@ -1 +1,2 @@
 DIST hishel-0.1.2.gh.tar.gz 876933 BLAKE2B e301071b563071b0b3f33d7ab9913dd363732f6cd9a5e93f33ca3ea7cf86d14fb400ee10627dd9448df3ba3879c3dd0c490b3d435d2012d5176b42b3d6cdf92a SHA512 11b5eed0d5bbae099306c7274c50d677ce831f42f35b17beb09ae5f71abb947969ebb8a7dd1e983ac6a067e6ca0e59648a7c8bb52eb7b0b61dc20573c940a7c2
+DIST hishel-0.1.3.gh.tar.gz 877174 BLAKE2B 296337921b1b7091b3fd8c4ec45203c7dc6138659d4affcd26a84cedf408cd39c835bf24acee5766deb59c4589d81fb4a9b7fc2f38ae5e328175f2a886617502 SHA512 5807cb1ddd819e3903f038b330cde7abb12101a46782c5117cc97b4cd53e752d8ed0e69ac9d0142fe1314b2ce56f1173aac23989f96e78596bbc3b6696a4f713

dev-python/hishel/hishel-0.1.3.ebuild

@@ -0,0 +1,76 @@
+# Copyright 2024-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1
+
+DESCRIPTION="An elegant HTTP Cache implementation for HTTPX and HTTP Core"
+HOMEPAGE="
+	https://github.com/karpetrosyan/hishel
+	https://pypi.org/project/hishel/
+"
+SRC_URI="
+	https://github.com/karpetrosyan/${PN}/archive/refs/tags/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+RDEPEND="
+	>=dev-python/httpx-0.28[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	${RDEPEND}
+	dev-python/hatch-fancy-pypi-readme[${PYTHON_USEDEP}]
+	test? (
+		dev-db/redis
+		dev-python/boto3[${PYTHON_USEDEP}]
+		dev-python/redis[${PYTHON_USEDEP}]
+		dev-python/trio[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=( anyio )
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	sed -e 's:mock_s3:mock_aws:g' \
+		-e '/import anysqlite/ d' \
+		-i tests/_async/test_storages.py \
+		tests/_sync/test_storages.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+src_test() {
+	local EPYTEST_DESELECT=(
+		# tests that need anysqlite
+		tests/_async/test_storages.py::test_sqlitestorage
+		tests/_async/test_storages.py::test_sqlite_expired
+		tests/_async/test_storages.py::test_sqlite_ttl_after_hits
+	)
+
+	local redis_pid="${T}"/redis.pid
+	local redis_port=6379
+
+	einfo "Starting Redis"
+	"${EPREFIX}"/usr/sbin/redis-server - <<- EOF
+		daemonize yes
+		pidfile ${redis_pid}
+		port ${redis_port}
+		bind 127.0.0.1 ::1
+	EOF
+
+	# Run the tests
+	distutils-r1_src_test
+
+	# Clean up afterwards
+	kill "$(<"${redis_pid}")" || die
+}