dev-libs/libgpiod: add 2.2.2

Signed-off-by: Yixun Lan <dlan@gentoo.org>

dev-libs/libgpiod/Manifest

@@ -1,2 +1,3 @@
 DIST libgpiod-1.6.4.tar.xz 334552 BLAKE2B 3bf52dab263638967e0f59c858e22f3d8ec1c9565ba1edd665dff580a883fbc6aa49a944e6df4da8fca9c2df873e222ed4e055c9792ee27d4562b3c2d0c65b79 SHA512 23ea27147039ae34505263dbfbb3ca9985fc671d26e489ccaf150543d4e853f709393f46a8a5a1e682fa91378163bd2db6c689159ef73c3a8d1eeea422eacda0
 DIST libgpiod-2.2.1.tar.xz 505744 BLAKE2B 622d945fc002c9691ecce8fbb0df7350659244e3dbe5d014a032862b86527457bc3893172cbc4c4764d1f94d686602e85b56f2764014a031f6ad21c5f428999b SHA512 3be974ec11a46bb362dce105b22d2cd22b2282bb6bc3a43097d51ed86bd08334768a45d51f2ef1e99bd8c0f2c49462290c46d9b8e40ab0df66ff90e40d822f1a
+DIST libgpiod-2.2.2.tar.xz 509644 BLAKE2B 7fd6fa955caadabcd538f26d3fef3f7cf081d9ab99e0b85704671883836ba3d66bca37d58753328a1ac30aeb7623a70d875e96f5eca3d36f03938f3a033a048b SHA512 8237629214a36b14691bbf908cb2f1b27fe1b26fbafd714efeaf6896962a943f0f49eb3ef7ddfde876786d9d848c64b4a0731b7151924e973b361c2f3825ab84

dev-libs/libgpiod/libgpiod-2.2.2.ebuild

@@ -0,0 +1,66 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools linux-info
+
+DESCRIPTION="C library and tools for interacting with the linux GPIO character device"
+HOMEPAGE="https://git.kernel.org/pub/scm/libs/libgpiod/libgpiod.git/"
+SRC_URI="https://mirrors.edge.kernel.org/pub/software/libs/libgpiod/${P}.tar.xz"
+
+LICENSE="LGPL-2.1"
+# Reflects the ABI of libgpiod.so
+SLOT="0/3"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+IUSE="+tools cxx python static-libs test"
+RESTRICT="!test? ( test )"
+
+#  --enable-dbus #glib-2.80 masked
+#  --enable-tests          enable libgpiod tests [default=no]
+#  --enable-bindings-cxx   enable C++ bindings [default=no]
+#  --enable-bindings-python
+#  --enable-bindings-rust
+#  --enable-bindings-glib
+DEPEND="
+	test? (
+		>=dev-libs/glib-2.50
+		>=sys-apps/kmod-18
+		>=sys-apps/util-linux-2.33.1
+		>=virtual/libudev-215
+		cxx? ( <dev-cpp/catch-3.5:0 )
+	)
+"
+
+pkg_setup() {
+	CONFIG_CHECK="~GPIO_CDEV_V1"
+	linux-info_pkg_setup
+}
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myconf=(
+		$(use_enable tools)
+		$(use_enable cxx bindings-cxx)
+		$(use_enable test tests)
+		$(use_enable python bindings-python)
+		$(use_enable static-libs static)
+		--enable-examples
+		--disable-dbus
+		--disable-profiling
+		--disable-bindings-rust
+		--disable-bindings-glib
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+
+	find "${D}" -name '*.la' -type f -delete || die
+}