xfce-base/thunar: Bump to 1.8.0

xfce-base/thunar/Manifest

@@ -3,3 +3,4 @@ DIST Thunar-1.6.14.tar.bz2 1964822 BLAKE2B f080f3d0634b4b4a8e11cdb902d5f300b1829
 DIST Thunar-1.6.15.tar.bz2 1964447 BLAKE2B 07dd4241f5aad975ae8f3c4cffb1b40338fd31f5434fb436a2772a9671673b4b124ac4363dd7c1267b0b51d42550735bbb733ada16f77a5b89176a353c84edbc SHA512 836d2d10347915b2e03be5501806e358af1c60786284c5e5afa11a6a79bc6a790966ea43bd9add6783fab91b08f06ae7852c21152f3aa0f29814325a16d65a7f
 DIST Thunar-1.7.1.tar.bz2 2264496 BLAKE2B 84fc0ae18ec4d4bd414bbce30b6ba7f1f0c90de6202d8b830335fb49561c85428ee13753bdc1cb810713e628b977aacf78c93d7bd88c9ac90e3a78f8d74f5737 SHA512 200d2f7a30529fa9a93340a24d019a883193952157f3b37e67d4618ccff95823dfa06f6b04845d185fcb5ead780ea5c69ba9b846c82ea22bc433321b2b160ffb
 DIST Thunar-1.7.2.tar.bz2 2236176 BLAKE2B e7ebcd8b74295539edfeed710cc25204691af3eaa1c84dcd9b56399f5af2220aabc9ce2736f03c7c1bfe9a61600c6acc4f659ba8d56e575f0e4679a644f1c459 SHA512 b98b72558c9a8872f89632820be816f2c2e7f7e07750cc62eace741794cde4aa4daf2f4ed7fd52a5b1e3c4e9965925a038a948124d32ed6d392db65b8780ccdb
+DIST Thunar-1.8.0.tar.bz2 2240878 BLAKE2B 03b77fe7f7695eec3430c7c6350825b9fcda76ffab408461bbf6e7f21f76bd8cbab05caf144222471ab7225086a2a7e541bc4777593abfb6bdcd9bb0c22db287 SHA512 4f0cc00904e9e7f02d2cf79fe36bda4857c1354917f656a2376c73bb755c3dc359e277f3a050fa60754f9adfadb75cefa9287334f6a97c1b4ebdf1f63545da4b

xfce-base/thunar/thunar-1.8.0.ebuild

@@ -0,0 +1,80 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit gnome2-utils virtualx xdg-utils
+
+MY_P=${P^}
+
+DESCRIPTION="File manager for the Xfce desktop environment"
+HOMEPAGE="https://www.xfce.org/projects/ https://docs.xfce.org/xfce/thunar/start"
+SRC_URI="mirror://xfce/src/xfce/${PN}/${PV%.*}/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="exif introspection libnotify pcre test +trash-panel-plugin udisks"
+
+GVFS_DEPEND=">=gnome-base/gvfs-1.18.3"
+COMMON_DEPEND=">=dev-lang/perl-5.6
+	>=dev-libs/glib-2.30:=
+	>=x11-libs/gdk-pixbuf-2.14:=
+	>=x11-libs/gtk+-3.22:3=
+	>=xfce-base/exo-0.11:=
+	>=xfce-base/libxfce4ui-4.12:=
+	>=xfce-base/libxfce4util-4.12:=
+	>=xfce-base/xfconf-4.12:=
+	exif? ( >=media-libs/libexif-0.6.19:= )
+	introspection? ( dev-libs/gobject-introspection:= )
+	libnotify? ( >=x11-libs/libnotify-0.7:= )
+	pcre? ( >=dev-libs/libpcre-6:= )
+	trash-panel-plugin? ( >=xfce-base/xfce4-panel-4.10:= )
+	udisks? ( virtual/libgudev:= )"
+RDEPEND="${COMMON_DEPEND}
+	>=dev-util/desktop-file-utils-0.20-r1
+	x11-misc/shared-mime-info
+	trash-panel-plugin? ( ${GVFS_DEPEND} )
+	udisks? (
+		virtual/udev
+		${GVFS_DEPEND}[udisks,udev]
+		)"
+DEPEND="${COMMON_DEPEND}
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+S=${WORKDIR}/${MY_P}
+
+DOCS=( AUTHORS ChangeLog FAQ HACKING NEWS README THANKS TODO )
+
+src_configure() {
+	local myconf=(
+		$(use_enable introspection)
+		$(use_enable udisks gudev)
+		$(use_enable libnotify notifications)
+		$(use_enable exif)
+		$(use_enable pcre)
+		$(use_enable trash-panel-plugin tpa-plugin)
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_test() {
+	virtx emake check
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	gnome2_icon_cache_update
+}