net-proxy/shadowsocks-libev: version bump, 3.3.5

Package-Manager: Portage-3.0.0, Repoman-2.3.23
Signed-off-by: Yixun Lan <dlan@gentoo.org>

net-proxy/shadowsocks-libev/Manifest

@@ -1 +1,2 @@
 DIST shadowsocks-libev-3.3.4.tar.gz 279666 BLAKE2B ea698a3cf29ed0b1268d17e25a492712cb90f515068de2f74d200ab04bb0d5ca859ea1d7f071714cc1c8dced0e566df4bfea0d780e24c9398f93ab1e362ec466 SHA512 4fb9e4a62f86f1504aab71022b5078a1f97b1f14da82c7b456dc9eaed23be990430769f37b7c2855c266be40ec215237bb0a40d254dffac8556ec4719cc9aa6d
+DIST shadowsocks-libev-3.3.5.tar.gz 303368 BLAKE2B bb7d6e64596710402db94085044c20315028395723828fa82dfba419bc41a0c740ece1f79c6cf05dda395d9442d553429f66d7f7b2de3cdd188d5b6adb0b8edf SHA512 c0cc869b4b7661ebd348bd5559c6a17c44b66a5f42374d97023adcfb525d934da3ed96245ff792ebc74870d30dd8f71fadcd89c79b2cd8a98d551ff7592508d0

net-proxy/shadowsocks-libev/shadowsocks-libev-3.3.5.ebuild

@@ -0,0 +1,82 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_PV="v${PV}"
+inherit autotools eutils systemd
+
+DESCRIPTION="A lightweight secured SOCKS5 proxy for embedded devices and low end boxes"
+HOMEPAGE="https://github.com/shadowsocks/shadowsocks-libev"
+
+#repack with git submodule populated: libbloom, libcork, libipset
+#SRC_URI="https://dev.gentoo.org/~dlan/distfiles/${P}.tar.xz"
+
+SRC_URI="https://github.com/shadowsocks/${PN}/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="debug doc"
+
+RDEPEND="net-libs/mbedtls:=
+	>=net-libs/libbloom-1.6
+	net-libs/libcork
+	net-libs/libcorkipset
+	>=dev-libs/libsodium-1.0.8:=
+	dev-libs/libev
+	net-dns/c-ares
+	dev-libs/libpcre
+	"
+DEPEND="${RDEPEND}
+	sys-kernel/linux-headers
+	doc? (
+		app-text/asciidoc
+		app-text/xmlto
+	)
+	"
+
+src_prepare() {
+	sed -i -e 's|AC_CONFIG_FILES(\[libbloom/Makefile libcork/Makefile libipset/Makefile\])||' \
+		configure.ac || die
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myconf="
+		$(use_enable debug assert)
+		--enable-system-shared-lib
+	"
+	use doc || myconf+="--disable-documentation"
+	econf ${myconf}
+}
+
+src_install() {
+	default
+
+	find "${D}" -name '*.la' -type f -delete || die
+
+	insinto "/etc/${PN}"
+	newins "${FILESDIR}/shadowsocks.json" shadowsocks.json
+
+	newinitd "${FILESDIR}/shadowsocks.initd" shadowsocks
+	dosym shadowsocks /etc/init.d/shadowsocks.server
+	dosym shadowsocks /etc/init.d/shadowsocks.client
+	dosym shadowsocks /etc/init.d/shadowsocks.redir
+	dosym shadowsocks /etc/init.d/shadowsocks.tunnel
+
+	dodoc -r acl
+
+	for i in debian/${PN}*.service; do
+		systemd_newunit $i $(basename $i)
+	done
+}
+
+pkg_setup() {
+	elog "You need to choose the mode"
+	elog "  server: rc-update add shadowsocks.server default"
+	elog "  client: rc-update add shadowsocks.client default"
+	elog "  redir:  rc-update add shadowsocks.redir default"
+	elog "  tunnel: rc-update add shadowsocks.tunnel default"
+}