dev-java/openjdk-jre-bin: add 8.372_p07

Bug: https://bugs.gentoo.org/908243
Signed-off-by: Georgy Yakovlev <gyakovlev@gentoo.org>

dev-java/openjdk-jre-bin/Manifest

@@ -1,3 +1,4 @@
 DIST OpenJDK11U-jre_x64_linux_hotspot_11.0.18_10.tar.gz 42824761 BLAKE2B 481317f316bac10e098d706a04e94b57bad4388c94168da27403e18489f66d322177f7f9b59c5ebdfc6f3e70080550f6f5e5fc922e9b21a9a59dcc60116243be SHA512 07a0483b4536129974706ee79864e9fd737810b396a605170e68c74dacdb3c65e10ccde9073e8ec0c907709172dd2e08e7c454a5bd88cf0e92f879ace1eedbd0
 DIST OpenJDK17U-jre_x64_linux_hotspot_17.0.6_10.tar.gz 46078462 BLAKE2B 2d0bc958f64da82e82b3a8a9d6bc686ecd2a09943e851f0f1a8efcec7cf0135b76a65abfa7f1175d09bc42583d151a4161d891a9861050751ae0c8aa4b1bbdc2 SHA512 253a030ab87e949091b24bacd638a91c673d775e76f3a83e8ab0c1824f697516405fe8fcf7d3b460bd25ddbb441685fa396b390e7ab8bc802294ea36b4700fac
 DIST OpenJDK8U-jre_x64_linux_hotspot_8u362b09.tar.gz 41359704 BLAKE2B ae4238725544b03abdc32f82fcb1e13fe2aba460c13a48ccc8ccd608f1e8b0f5ac6036b06e941e89b936f01250a4fc3f6fb0f9d7eb5ae9129b8cd5de6c1da33a SHA512 6cb0bdc28596e23807f3e7f31c40f095d20395492bf30dae26a735686f82d9d216110403d59c769700a23dd3187a2603832bd84204051800d474af24c68c8cbc
+DIST OpenJDK8U-jre_x64_linux_hotspot_8u372b07.tar.gz 41375309 BLAKE2B 4e439b329d020b30a118237d54e2a6bbb3d321e73b71c320a51b73f36662da82a846a306509537bc91f026177d31d1351a6de3d999881c6cd93e4b679e0a9a40 SHA512 affd576e85a28bb6d64d2967ee17ec13c36ec5c037ccb86caad41d6d7c9844656f325796abda0b5f234b1a6cbddbc7508ed36af4eaa1d29465e3719412419829

dev-java/openjdk-jre-bin/openjdk-jre-bin-8.372_p07.ebuild

@@ -0,0 +1,82 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit java-vm-2
+
+abi_uri() {
+	echo "${2-$1}? (
+			https://github.com/adoptium/temurin${SLOT}-binaries/releases/download/jdk${MY_PV}/OpenJDK8U-jre_${1}_linux_hotspot_${MY_PV/-/}.tar.gz
+		)"
+}
+
+MY_PV=$(ver_rs 1 'u' 2 '-' ${PV//p/b})
+SLOT="$(ver_cut 1)"
+
+DESCRIPTION="Prebuilt Java JRE binaries provided by Eclipse Temurin"
+HOMEPAGE="https://adoptium.net"
+SRC_URI="
+	$(abi_uri x64 amd64)
+"
+
+LICENSE="GPL-2-with-classpath-exception"
+KEYWORDS="~amd64"
+
+IUSE="alsa cups headless-awt selinux"
+
+RDEPEND="
+	media-libs/fontconfig:1.0
+	media-libs/freetype:2
+	>net-libs/libnet-1.1
+	>=sys-apps/baselayout-java-0.1.0-r1
+	>=sys-libs/glibc-2.2.5:*
+	sys-libs/zlib
+	alsa? ( media-libs/alsa-lib )
+	cups? ( net-print/cups )
+	selinux? ( sec-policy/selinux-java )
+	!headless-awt? (
+		x11-libs/libX11
+		x11-libs/libXext
+		x11-libs/libXi
+		x11-libs/libXrender
+		x11-libs/libXtst
+	)"
+
+RESTRICT="preserve-libs splitdebug"
+QA_PREBUILT="*"
+
+S="${WORKDIR}/jdk${MY_PV}-jre"
+
+src_install() {
+	local dest="/opt/${P}"
+	local ddest="${ED}/${dest#/}"
+
+	rm ASSEMBLY_EXCEPTION LICENSE THIRD_PARTY_README || die
+
+	# this does not exist on arm64 hence -f
+	rm -fv lib/*/libfreetype.so* || die
+
+	if ! use alsa ; then
+		rm -v lib/*/libjsoundalsa.so* || die
+	fi
+
+	if use headless-awt ; then
+		rm -fvr lib/*/lib*{[jx]awt,splashscreen}* \
+			bin/policytool || die
+	fi
+
+	rm -v lib/security/cacerts || die
+	dosym -r /etc/ssl/certs/java/cacerts "${dest}"/lib/security/cacerts
+
+	dodir "${dest}"
+	cp -pPR * "${ddest}" || die
+
+	# provide stable symlink
+	dosym "${P}" "/opt/${PN}-${SLOT}"
+
+	java-vm_install-env "${FILESDIR}"/${PN}-${SLOT}.env.sh
+	java-vm_set-pax-markings "${ddest}"
+	java-vm_revdep-mask
+	java-vm_sandbox-predict /dev/random /proc/self/coredump_filter
+}