dev-python/pyatspi: Version bump to 2.38.2

Signed-off-by: Matt Turner <mattst88@gentoo.org>

dev-python/pyatspi/Manifest

@@ -1 +1,2 @@
 DIST pyatspi-2.38.1.tar.xz 316724 BLAKE2B 59ca2569575f3d319d33972477ebc966670138df8cb6570ac260dd903f54df66fd12beeeee53e3380938e4571910b99ae2bf3f395776b16a73ac27f8fa023c49 SHA512 bf8f1ee9a6e00014a84e4329bb971bec8b4bc8f72c3905ca585ca20b1cf000b855965159fcc10871eb92e9808a6b41b5d793f3ab563ff0867f185279eedcd487
+DIST pyatspi-2.38.2.tar.xz 318596 BLAKE2B aba5d4fbbc9e0ce4793843270394712e675e6546c781f0523f7f17a79f018fcf4cf209257e9ef0dc03cbe92be7a17c774fd82f2d9997d9aa8c6b6be65a72ef8a SHA512 03e10af5f0eb2ab89518229f049f497635ec1ae85a948a02813a5eb00eef395a3934f578b56054f8e73ae3c5c28760ad1f2b93e8876b8724c64b622d966aa5d9

dev-python/pyatspi/pyatspi-2.38.2.ebuild

@@ -0,0 +1,60 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit gnome2 python-r1 virtualx
+
+DESCRIPTION="Python client bindings for D-Bus AT-SPI"
+HOMEPAGE="https://wiki.gnome.org/Accessibility"
+
+# Note: only some of the tests are GPL-licensed, everything else is LGPL
+LICENSE="LGPL-2 GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+IUSE="test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="
+	${PYTHON_DEPS}
+	>=dev-libs/atk-2.11.2
+	dev-python/dbus-python[${PYTHON_USEDEP}]
+	>=dev-python/pygobject-2.90.1:3[${PYTHON_USEDEP}]
+"
+RDEPEND="${DEPEND}
+	>=sys-apps/dbus-1
+	>=app-accessibility/at-spi2-core-2.34[introspection]
+"
+BDEPEND="virtual/pkgconfig
+	test? ( x11-libs/gtk+:3 )
+"
+
+src_prepare() {
+	gnome2_src_prepare
+	python_copy_sources
+}
+
+src_configure() {
+	python_foreach_impl run_in_build_dir gnome2_src_configure $(use_enable test tests)
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir gnome2_src_compile
+}
+
+src_test() {
+	python_foreach_impl run_in_build_dir virtx dbus-run-session emake check
+}
+
+src_install() {
+	installing() {
+		gnome2_src_install
+		python_optimize
+	}
+	python_foreach_impl run_in_build_dir installing
+
+	docinto examples
+	dodoc examples/*.py
+}