dev-python/openstacksdk: Bump to 4.19.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/openstacksdk/Manifest

@@ -1,2 +1,3 @@
 DIST openstacksdk-4.17.0.tar.gz 1399124 BLAKE2B 0dc91a7afc378edf6e13e658832bba5ce7359fc32d13c1d7f106557b1ec5e63908b1dcf9c5bde6378c3f9f49f1f0aecee4b1a2e0538e6bf09fd0c58b865e3340 SHA512 053a9bd603d9b2aa936d00233af6467337514d614b7c0aa5d16adeac530f3aca142636ff87745a6fee033c89909eaa77bf961e007d4c3319ebe38468b25c1d1a
 DIST openstacksdk-4.18.0.tar.gz 1403478 BLAKE2B ae51d239ee397bff72bc28c567bcac2df89d44324f299f78bd8dfd6e1f56877ad1a87016fd330db74ddfe763b71f848a1f9d2669d2b1fc02e3343d94bf0d2871 SHA512 b88c786cb5e21e878b434f383d5b90d6268838c4649f7c9b2c5f23d9f5418fea03cc061283ba07dee9b9842a801434cf77a6db753a5e6abccf7f5c0eb7af43bf
+DIST openstacksdk-4.19.0.tar.gz 1438393 BLAKE2B bc20db082de592a141fde96fc9c5ef046106fc6ebdab440f030680e420b832f155e7f0baebb63ef5cfffcfb449b7e529d641bb680ef2bd90fed8f9d37fbbd5a2 SHA512 5ae2189ffb635b7d94d52aa30260f14284ca0ee8a3505d853dff80d6a6f88a1a19edfb116c96353be6aea66ca724e50ac9200071ffd179bad76133471e360165

dev-python/openstacksdk/openstacksdk-4.19.0.ebuild

@@ -0,0 +1,94 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=pbr
+PYTHON_COMPAT=( python3_{12..15} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A collection of libraries for building applications to work with OpenStack"
+HOMEPAGE="
+	https://opendev.org/openstack/openstacksdk/
+	https://github.com/openstack/openstacksdk/
+	https://pypi.org/project/openstacksdk/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/cryptography-2.7[${PYTHON_USEDEP}]
+	>=dev-python/decorator-4.4.1[${PYTHON_USEDEP}]
+	>=dev-python/dogpile-cache-0.6.5[${PYTHON_USEDEP}]
+	>=dev-python/iso8601-0.1.11[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.9.0[${PYTHON_USEDEP}]
+	>=dev-python/jsonpatch-1.21[${PYTHON_USEDEP}]
+	>=dev-python/keystoneauth1-5.10.0[${PYTHON_USEDEP}]
+	>=dev-python/os-service-types-1.8.1[${PYTHON_USEDEP}]
+	>=dev-python/pbr-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-3[${PYTHON_USEDEP}]
+	>=dev-python/psutil-3.2.2[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-3.13[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/ddt-1.0.1[${PYTHON_USEDEP}]
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/jsonschema-3.2.0[${PYTHON_USEDEP}]
+		>=dev-python/oslo-config-6.1.0[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+		>=dev-python/prometheus-client-0.4.2[${PYTHON_USEDEP}]
+		>=dev-python/requests-mock-1.2.0[${PYTHON_USEDEP}]
+		>=dev-python/statsd-3.3.0[${PYTHON_USEDEP}]
+		>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+		>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# Internet?
+	sed -e 's:test_create_dynamic_large_object:_&:' \
+		-i openstack/tests/unit/cloud/test_object.py || die
+
+	# TODO
+	sed -e 's:test_generate_form:_&:' \
+		-e 's:test_create_static_large_object:_&:' \
+		-e 's:test_object_segment_retries:_&:' \
+		-e 's:test_object_segment_retry_failure:_&:' \
+		-e 's:test_slo_manifest_retry:_&:' \
+		-i openstack/tests/unit/cloud/test_object.py || die
+	sed -e 's:test_servers:_&:' \
+		-i openstack/tests/unit/test_stats.py || die
+
+	# unhappy about paths due to test runner
+	sed -e 's:test_method_not_supported:_&:' \
+		-i openstack/tests/unit/test_exceptions.py || die
+	sed -e 's:test_repr:_&:' \
+		-i openstack/tests/unit/test_resource.py || die
+
+	# requires hacking
+	rm openstack/tests/unit/test_hacking.py || die
+
+	# fragile warning-based tests
+	sed -e 's:test_unsupported_version_override:_&:' \
+		-i openstack/tests/unit/test_missing_version.py || die
+	sed -e 's:test_create_unknown_proxy:_&:' \
+		-i openstack/tests/unit/test_connection.py || die
+
+	# stupid test checking if they pin to the newest os-service-types,
+	# except they don't actually do
+	sed -e 's:test_ost_version:_&:' \
+		-i openstack/tests/unit/test_utils.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# functional tests require cloud instance access
+	eunittest -b openstack/tests/unit
+}