mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-21 10:37:22 -08:00
xfce-extra/xfce4-screensaver: Bump to 0.1.10
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
@@ -1,2 +1,3 @@
|
||||
DIST xfce4-screensaver-0.1.10.tar.bz2 665624 BLAKE2B 9af4a821bcbb461462cf620dbd2c064a32b904f0d6887095cd00939f857244d69612e18559c0cf0be93e9044047d0e3dba8c756acc16fe9e3e136a718beb3942 SHA512 a04842697c7a8f84ee937f0371b3d1413163b59d1a54b9adf0b904dd501d6328ab645160567ff79afbe063cc113a488567ec5d8df4d6ed2db354738275c00b2e
|
||||
DIST xfce4-screensaver-0.1.8.tar.bz2 593968 BLAKE2B 693fe6e057bc1f5f1abff67c8a0a99244d5c270ab9c9afd7945f21b6eeb2bea027448d1485dea9a9f912b5f231211878a92a882bac56f28696557e44215ce283 SHA512 4cb76272f2f94f5e265a86d3fa58de8da6167da013466a4dd2a08a2e94fafe14816ce6c5a1e635a8c07e91497ede0650c014d21b0bbac666b8a72bc5f4645f69
|
||||
DIST xfce4-screensaver-0.1.9.tar.bz2 665025 BLAKE2B 290fc9cc81a19971cebd2876c767c04f1e010ed4282c9ccae8d2f615230f8fdb65fffbfb0ec7526cd5e23c7e1450565e6d23c108d23e6f2fd29c94ee4d6fc873 SHA512 ff2a967ebb62a5290405e1070ea064dba18e4a4062c2b2d990a23f44a6f730e0c56a98eac5ba86a166e5a8f67388333b0be695e2e59318abd76e8b6c3765d8eb
|
||||
|
||||
@@ -0,0 +1,74 @@
|
||||
# Copyright 1999-2020 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=7
|
||||
|
||||
DESCRIPTION="Screen saver and locker (port of MATE screensaver)"
|
||||
HOMEPAGE="https://git.xfce.org/apps/xfce4-screensaver/about/"
|
||||
SRC_URI="https://archive.xfce.org/src/apps/${PN}/${PV%.*}/${P}.tar.bz2"
|
||||
|
||||
LICENSE="GPL-2+ LGPL-2+"
|
||||
SLOT="0"
|
||||
KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~x86"
|
||||
IUSE="consolekit elogind +locking opengl pam systemd"
|
||||
|
||||
# Xrandr: optional but automagic
|
||||
RDEPEND="
|
||||
>=dev-libs/dbus-glib-0.30
|
||||
>=dev-libs/glib-2.50:2
|
||||
>=x11-libs/gtk+-3.22:3
|
||||
>=x11-libs/libwnck-3.20:3
|
||||
x11-libs/libICE:=
|
||||
x11-libs/libX11:=
|
||||
x11-libs/libXScrnSaver:=
|
||||
x11-libs/libXext:=
|
||||
x11-libs/libXxf86vm:=
|
||||
>=x11-libs/libXrandr-1.3:=
|
||||
>=x11-libs/libxklavier-5.2:=
|
||||
>=xfce-base/garcon-0.5.0:=
|
||||
>=xfce-base/libxfce4ui-4.12.1:=
|
||||
>=xfce-base/libxfce4util-4.12.1:=
|
||||
>=xfce-base/xfconf-4.12.1:=
|
||||
consolekit? ( sys-auth/consolekit )
|
||||
elogind? ( sys-auth/elogind )
|
||||
locking? (
|
||||
pam? ( sys-libs/pam )
|
||||
)
|
||||
opengl? ( virtual/opengl )
|
||||
systemd? ( sys-apps/systemd:= )
|
||||
"
|
||||
DEPEND="${RDEPEND}
|
||||
dev-util/glib-utils
|
||||
dev-util/intltool
|
||||
sys-apps/dbus
|
||||
virtual/pkgconfig"
|
||||
|
||||
src_configure() {
|
||||
local myconf=(
|
||||
# disable docbook for now
|
||||
ac_cv_path_XMLTO=no
|
||||
|
||||
# xscreensaver dirs autodetection doesn't seem to work
|
||||
--with-xscreensaverdir=/usr/share/xscreensaver/config
|
||||
--with-xscreensaverhackdir=/usr/$(get_libdir)/misc/xscreensaver
|
||||
|
||||
$(use_with opengl libgl)
|
||||
$(use_enable locking)
|
||||
$(use_enable pam)
|
||||
$(use_with consolekit console-kit)
|
||||
$(use_with elogind)
|
||||
$(use_with systemd)
|
||||
)
|
||||
|
||||
if use pam; then
|
||||
myconf+=( --with-pam-auth-type=system )
|
||||
fi
|
||||
|
||||
econf "${myconf[@]}"
|
||||
}
|
||||
|
||||
src_install() {
|
||||
default
|
||||
|
||||
find "${D}" -name '*.la' -delete || die
|
||||
}
|
||||
Reference in New Issue
Block a user