Merge updates from master

This commit is contained in:
Repository QA checks
2015-08-22 15:25:57 -04:00
6 changed files with 612 additions and 0 deletions
+1
View File
@@ -6,4 +6,5 @@ DIST mesa-10.5.8.tar.xz 6993084 SHA256 2866b855c5299a4aed066338c77ff6467c389b2c3
DIST mesa-10.6.1.tar.xz 7035216 SHA256 6c80a2b647e57c85dc36e609d9aed17f878f0d8e0cf9ace86d14cf604101e1eb SHA512 7ba5f4a7e421e6f198c4e80c1f0259071e1115aecdbe2846a7986bcfe1503a6f4a1806126295e3d9f4b6aee63dd107e82c3972ccb8079b9b5baf1f65246d21ab WHIRLPOOL 1e72a397e30e0f02afc18d864aea004f13cc95a925b66538ac1e368dea9f4737168dcf6b6af715ae04331b0626b3bda7aa2affae95575c56edbeaf0177bc3117
DIST mesa-10.6.2.tar.xz 7033344 SHA256 05753d3db4212900927b9894221a1669a10f56786e86a7e818b6e18a0817dca9 SHA512 feaca60b7cc8310a613bd89d0008fb7807de403ce6782e0e62e47ecba040d3728602778f47c704751cb49f8e2d950de03153b84b66d28203e29a70987b96340b WHIRLPOOL 8b148e7bb36fdcc7c25bb02561489b796f01f82bc74ce1d927987eeeaed5f602647d435c046142f5384aa4fb0369bb4a288281b51a03be712b4af8ed7111bf23
DIST mesa-10.6.3.tar.xz 7036480 SHA256 58592e07c350cd2e8969b73fa83048c657a39fe2f13f3b88f5e5818fe2e4676d SHA512 4474e089c0b618d0b0469e31c213d84530f9dd22d4280612f34370578a7e7dfdfd1ac499feae470f032e462f5d7532aafa4416a7dd97d0cd6d9332aec5b44446 WHIRLPOOL 13f44d38e34b6b03919393918a65d2f47ef20de2b31a27ffb3b74c969414d40b01840652829a749924aa3ae548f2cf0abce8c830bcad6a4365ceedd4908e06cb
DIST mesa-10.6.5.tar.xz 7037400 SHA256 fb6fac3c85bcfa9d06b8dd439169f23f0c0924a88e44362e738b99b1feff762f SHA512 46be6bd683d286bdf9ab8b4c1b1b32f89c95701b8c48cee49b060f5beaacea4540a69b99b4fde0f80acdd8e725552bef17dbd4251b9e977caeb5fd9d0ba56595 WHIRLPOOL dee48a0c680aae01cc39dc9157ea7c4c353b7ffdf543ab1cde8e76612a462ff3e3cb33433abff6d88f6800b71a02cd8cfcc23be98218d3cc4f85f424f3d12474
DIST mesa-7.10.1-gentoo-patches-01.tar.bz2 5488 SHA256 31cd4f6d1a0a70249c40452919074856d120cd473a01a8457e3dc147a1b622d8 SHA512 c62b45b32e396e67f629003fc5242b7b4df054b8e20b5237489212bc4f0171534915a02fc9efa68965068121d10660b5cd92a419efabe33fd4596a97a39249c2 WHIRLPOOL 5f171959e3a31f5c38438b4806ce371bb8fdf1c7a87501865e4ed5d5ab284cda9568b7773005997d7a1cff151f95e64c027b36c0be48a4dd288a7ab8b5f69b97
+455
View File
@@ -0,0 +1,455 @@
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=5
EGIT_REPO_URI="git://anongit.freedesktop.org/mesa/mesa"
if [[ ${PV} = 9999* ]]; then
GIT_ECLASS="git-r3"
EXPERIMENTAL="true"
fi
PYTHON_COMPAT=( python2_7 )
inherit autotools multilib-minimal python-any-r1 pax-utils ${GIT_ECLASS}
OPENGL_DIR="xorg-x11"
MY_P="${P/_/-}"
FOLDER="${PV/_rc*/}"
DESCRIPTION="OpenGL-like graphic library for Linux"
HOMEPAGE="http://mesa3d.sourceforge.net/"
if [[ $PV == 9999* ]]; then
SRC_URI=""
else
SRC_URI="ftp://ftp.freedesktop.org/pub/mesa/${FOLDER}/${MY_P}.tar.xz"
fi
LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~amd64-linux ~arm-linux ~ia64-linux ~x86-linux ~sparc-solaris ~x64-solaris ~x86-solaris"
RESTRICT="!bindist? ( bindist )"
INTEL_CARDS="i915 i965 ilo intel"
RADEON_CARDS="r100 r200 r300 r600 radeon radeonsi"
VIDEO_CARDS="${INTEL_CARDS} ${RADEON_CARDS} freedreno nouveau vmware"
for card in ${VIDEO_CARDS}; do
IUSE_VIDEO_CARDS+=" video_cards_${card}"
done
IUSE="${IUSE_VIDEO_CARDS}
bindist +classic d3d9 debug +dri3 +egl +gallium +gbm gles1 gles2 +llvm
+nptl opencl osmesa pax_kernel openmax pic selinux +udev vaapi vdpau
wayland xvmc xa kernel_FreeBSD"
REQUIRED_USE="
d3d9? ( dri3 gallium )
llvm? ( gallium )
opencl? ( gallium llvm )
openmax? ( gallium )
gles1? ( egl )
gles2? ( egl )
vaapi? ( gallium )
vdpau? ( gallium )
wayland? ( egl gbm )
xa? ( gallium )
video_cards_freedreno? ( gallium )
video_cards_intel? ( classic )
video_cards_i915? ( || ( classic gallium ) )
video_cards_i965? ( classic )
video_cards_ilo? ( gallium )
video_cards_nouveau? ( || ( classic gallium ) )
video_cards_radeon? ( || ( classic gallium ) )
video_cards_r100? ( classic )
video_cards_r200? ( classic )
video_cards_r300? ( gallium llvm )
video_cards_r600? ( gallium )
video_cards_radeonsi? ( gallium llvm )
video_cards_vmware? ( gallium )
${PYTHON_REQUIRED_USE}
"
LIBDRM_DEPSTRING=">=x11-libs/libdrm-2.4.60"
# keep correct libdrm and dri2proto dep
# keep blocks in rdepend for binpkg
RDEPEND="
!<x11-base/xorg-server-1.7
!<=x11-proto/xf86driproto-2.0.3
abi_x86_32? ( !app-emulation/emul-linux-x86-opengl[-abi_x86_32(-)] )
classic? ( app-eselect/eselect-mesa )
gallium? ( app-eselect/eselect-mesa )
>=app-eselect/eselect-opengl-1.3.0
udev? ( kernel_linux? ( >=virtual/libudev-215:=[${MULTILIB_USEDEP}] ) )
>=dev-libs/expat-2.1.0-r3:=[${MULTILIB_USEDEP}]
gbm? ( >=virtual/libudev-215:=[${MULTILIB_USEDEP}] )
dri3? ( >=virtual/libudev-215:=[${MULTILIB_USEDEP}] )
>=x11-libs/libX11-1.6.2:=[${MULTILIB_USEDEP}]
>=x11-libs/libxshmfence-1.1:=[${MULTILIB_USEDEP}]
>=x11-libs/libXdamage-1.1.4-r1:=[${MULTILIB_USEDEP}]
>=x11-libs/libXext-1.3.2:=[${MULTILIB_USEDEP}]
>=x11-libs/libXxf86vm-1.1.3:=[${MULTILIB_USEDEP}]
>=x11-libs/libxcb-1.9.3:=[${MULTILIB_USEDEP}]
x11-libs/libXfixes:=[${MULTILIB_USEDEP}]
llvm? (
video_cards_radeonsi? ( || (
>=dev-libs/elfutils-0.155-r1:=[${MULTILIB_USEDEP}]
>=dev-libs/libelf-0.8.13-r2:=[${MULTILIB_USEDEP}]
) )
!video_cards_r600? (
video_cards_radeon? ( || (
>=dev-libs/elfutils-0.155-r1:=[${MULTILIB_USEDEP}]
>=dev-libs/libelf-0.8.13-r2:=[${MULTILIB_USEDEP}]
) )
)
>=sys-devel/llvm-3.4.2:=[${MULTILIB_USEDEP}]
)
opencl? (
app-eselect/eselect-opencl
dev-libs/libclc
|| (
>=dev-libs/elfutils-0.155-r1:=[${MULTILIB_USEDEP}]
>=dev-libs/libelf-0.8.13-r2:=[${MULTILIB_USEDEP}]
)
)
openmax? ( >=media-libs/libomxil-bellagio-0.9.3:=[${MULTILIB_USEDEP}] )
vaapi? ( >=x11-libs/libva-0.35.0:=[${MULTILIB_USEDEP}] )
vdpau? ( >=x11-libs/libvdpau-0.7:=[${MULTILIB_USEDEP}] )
wayland? ( >=dev-libs/wayland-1.2.0:=[${MULTILIB_USEDEP}] )
xvmc? ( >=x11-libs/libXvMC-1.0.8:=[${MULTILIB_USEDEP}] )
${LIBDRM_DEPSTRING}[video_cards_freedreno?,video_cards_nouveau?,video_cards_vmware?,${MULTILIB_USEDEP}]
"
for card in ${INTEL_CARDS}; do
RDEPEND="${RDEPEND}
video_cards_${card}? ( ${LIBDRM_DEPSTRING}[video_cards_intel] )
"
done
for card in ${RADEON_CARDS}; do
RDEPEND="${RDEPEND}
video_cards_${card}? ( ${LIBDRM_DEPSTRING}[video_cards_radeon] )
"
done
DEPEND="${RDEPEND}
llvm? (
video_cards_radeonsi? ( sys-devel/llvm[video_cards_radeon] )
)
opencl? (
>=sys-devel/llvm-3.4.2:=[${MULTILIB_USEDEP}]
>=sys-devel/clang-3.4.2:=[${MULTILIB_USEDEP}]
>=sys-devel/gcc-4.6
)
sys-devel/gettext
virtual/pkgconfig
>=x11-proto/dri2proto-2.8-r1:=[${MULTILIB_USEDEP}]
dri3? (
>=x11-proto/dri3proto-1.0:=[${MULTILIB_USEDEP}]
>=x11-proto/presentproto-1.0:=[${MULTILIB_USEDEP}]
)
>=x11-proto/glproto-1.4.17-r1:=[${MULTILIB_USEDEP}]
>=x11-proto/xextproto-7.2.1-r1:=[${MULTILIB_USEDEP}]
>=x11-proto/xf86driproto-2.1.1-r1:=[${MULTILIB_USEDEP}]
>=x11-proto/xf86vidmodeproto-2.3.1-r1:=[${MULTILIB_USEDEP}]
"
[[ ${PV} == "9999" ]] && DEPEND+="
sys-devel/bison
sys-devel/flex
${PYTHON_DEPS}
$(python_gen_any_dep ">=dev-python/mako-0.7.3[\${PYTHON_USEDEP}]")
"
S="${WORKDIR}/${MY_P}"
EGIT_CHECKOUT_DIR=${S}
# It is slow without texrels, if someone wants slow
# mesa without texrels +pic use is worth the shot
QA_EXECSTACK="usr/lib*/libGL.so*"
QA_WX_LOAD="usr/lib*/libGL.so*"
pkg_setup() {
# warning message for bug 459306
if use llvm && has_version sys-devel/llvm[!debug=]; then
ewarn "Mismatch between debug USE flags in media-libs/mesa and sys-devel/llvm"
ewarn "detected! This can cause problems. For details, see bug 459306."
fi
python-any-r1_pkg_setup
}
src_prepare() {
# fix for hardened pax_kernel, bug 240956
[[ ${PV} != 9999* ]] && epatch "${FILESDIR}"/glx_ro_text_segm.patch
eautoreconf
}
multilib_src_configure() {
local myconf
if use classic; then
# Configurable DRI drivers
driver_enable swrast
# Intel code
driver_enable video_cards_i915 i915
driver_enable video_cards_i965 i965
if ! use video_cards_i915 && \
! use video_cards_i965; then
driver_enable video_cards_intel i915 i965
fi
# Nouveau code
driver_enable video_cards_nouveau nouveau
# ATI code
driver_enable video_cards_r100 radeon
driver_enable video_cards_r200 r200
if ! use video_cards_r100 && \
! use video_cards_r200; then
driver_enable video_cards_radeon radeon r200
fi
fi
if use egl; then
myconf+="--with-egl-platforms=x11$(use wayland && echo ",wayland")$(use gbm && echo ",drm") "
fi
if use gallium; then
myconf+="
$(use_enable d3d9 nine)
$(use_enable llvm gallium-llvm)
$(use_enable openmax omx)
$(use_enable vaapi va)
$(use_enable vdpau)
$(use_enable xa)
$(use_enable xvmc)
"
gallium_enable swrast
gallium_enable video_cards_vmware svga
gallium_enable video_cards_nouveau nouveau
gallium_enable video_cards_i915 i915
gallium_enable video_cards_ilo ilo
if ! use video_cards_i915 && \
! use video_cards_i965; then
gallium_enable video_cards_intel i915
fi
gallium_enable video_cards_r300 r300
gallium_enable video_cards_r600 r600
gallium_enable video_cards_radeonsi radeonsi
if ! use video_cards_r300 && \
! use video_cards_r600; then
gallium_enable video_cards_radeon r300 r600
fi
gallium_enable video_cards_freedreno freedreno
# opencl stuff
if use opencl; then
myconf+="
$(use_enable opencl)
--with-clang-libdir="${EPREFIX}/usr/lib"
"
fi
fi
# x86 hardened pax_kernel needs glx-rts, bug 240956
if use pax_kernel; then
myconf+="
$(use_enable x86 glx-rts)
"
fi
# on abi_x86_32 hardened we need to have asm disable
if [[ ${ABI} == x86* ]] && use pic; then
myconf+=" --disable-asm"
fi
# build fails with BSD indent, bug #428112
use userland_GNU || export INDENT=cat
ECONF_SOURCE="${S}" \
econf \
--enable-dri \
--enable-glx \
--enable-shared-glapi \
$(use_enable !bindist texture-float) \
$(use_enable d3d9 nine) \
$(use_enable debug) \
$(use_enable dri3) \
$(use_enable egl) \
$(use_enable gbm) \
$(use_enable gles1) \
$(use_enable gles2) \
$(use_enable nptl glx-tls) \
$(use_enable osmesa) \
$(use_enable !udev sysfs) \
--enable-llvm-shared-libs \
--with-dri-drivers=${DRI_DRIVERS} \
--with-gallium-drivers=${GALLIUM_DRIVERS} \
PYTHON2="${PYTHON}" \
${myconf}
}
multilib_src_install() {
emake install DESTDIR="${D}"
if use classic || use gallium; then
ebegin "Moving DRI/Gallium drivers for dynamic switching"
local gallium_drivers=( i915_dri.so i965_dri.so r300_dri.so r600_dri.so swrast_dri.so )
keepdir /usr/$(get_libdir)/dri
dodir /usr/$(get_libdir)/mesa
for x in ${gallium_drivers[@]}; do
if [ -f "$(get_libdir)/gallium/${x}" ]; then
mv -f "${ED}/usr/$(get_libdir)/dri/${x}" "${ED}/usr/$(get_libdir)/dri/${x/_dri.so/g_dri.so}" \
|| die "Failed to move ${x}"
fi
done
if use classic; then
emake -C "${BUILD_DIR}/src/mesa/drivers/dri" DESTDIR="${D}" install
fi
for x in "${ED}"/usr/$(get_libdir)/dri/*.so; do
if [ -f ${x} -o -L ${x} ]; then
mv -f "${x}" "${x/dri/mesa}" \
|| die "Failed to move ${x}"
fi
done
pushd "${ED}"/usr/$(get_libdir)/dri || die "pushd failed"
ln -s ../mesa/*.so . || die "Creating symlink failed"
# remove symlinks to drivers known to eselect
for x in ${gallium_drivers[@]}; do
if [ -f ${x} -o -L ${x} ]; then
rm "${x}" || die "Failed to remove ${x}"
fi
done
popd
eend $?
fi
if use opencl; then
ebegin "Moving Gallium/Clover OpenCL implementation for dynamic switching"
local cl_dir="/usr/$(get_libdir)/OpenCL/vendors/mesa"
dodir ${cl_dir}/{lib,include}
if [ -f "${ED}/usr/$(get_libdir)/libOpenCL.so" ]; then
mv -f "${ED}"/usr/$(get_libdir)/libOpenCL.so* \
"${ED}"${cl_dir}
fi
if [ -f "${ED}/usr/include/CL/opencl.h" ]; then
mv -f "${ED}"/usr/include/CL \
"${ED}"${cl_dir}/include
fi
eend $?
fi
if use openmax; then
echo "XDG_DATA_DIRS=\"${EPREFIX}/usr/share/mesa/xdg\"" > "${T}/99mesaxdgomx"
doenvd "${T}"/99mesaxdgomx
keepdir /usr/share/mesa/xdg
fi
}
multilib_src_install_all() {
prune_libtool_files --all
einstalldocs
if use !bindist; then
dodoc docs/patents.txt
fi
# Install config file for eselect mesa
insinto /usr/share/mesa
newins "${FILESDIR}/eselect-mesa.conf.9.2" eselect-mesa.conf
}
multilib_src_test() {
if use llvm; then
local llvm_tests='lp_test_arit lp_test_arit lp_test_blend lp_test_blend lp_test_conv lp_test_conv lp_test_format lp_test_format lp_test_printf lp_test_printf'
pushd src/gallium/drivers/llvmpipe >/dev/null || die
emake ${llvm_tests}
pax-mark m ${llvm_tests}
popd >/dev/null || die
fi
emake check
}
pkg_postinst() {
# Switch to the xorg implementation.
echo
eselect opengl set --use-old ${OPENGL_DIR}
# Select classic/gallium drivers
if use classic || use gallium; then
eselect mesa set --auto
fi
# Switch to mesa opencl
if use opencl; then
eselect opencl set --use-old ${PN}
fi
# run omxregister-bellagio to make the OpenMAX drivers known system-wide
if use openmax; then
ebegin "Registering OpenMAX drivers"
BELLAGIO_SEARCH_PATH="${EPREFIX}/usr/$(get_libdir)/libomxil-bellagio0" \
OMX_BELLAGIO_REGISTRY=${EPREFIX}/usr/share/mesa/xdg/.omxregister \
omxregister-bellagio
eend $?
fi
# warn about patent encumbered texture-float
if use !bindist; then
elog "USE=\"bindist\" was not set. Potentially patent encumbered code was"
elog "enabled. Please see patents.txt for an explanation."
fi
if ! has_version media-libs/libtxc_dxtn; then
elog "Note that in order to have full S3TC support, it is necessary to install"
elog "media-libs/libtxc_dxtn as well. This may be necessary to get nice"
elog "textures in some apps, and some others even require this to run."
fi
}
pkg_prerm() {
if use openmax; then
rm "${EPREFIX}"/usr/share/mesa/xdg/.omxregister
fi
}
# $1 - VIDEO_CARDS flag
# other args - names of DRI drivers to enable
# TODO: avoid code duplication for a more elegant implementation
driver_enable() {
case $# in
# for enabling unconditionally
1)
DRI_DRIVERS+=",$1"
;;
*)
if use $1; then
shift
for i in $@; do
DRI_DRIVERS+=",${i}"
done
fi
;;
esac
}
gallium_enable() {
case $# in
# for enabling unconditionally
1)
GALLIUM_DRIVERS+=",$1"
;;
*)
if use $1; then
shift
for i in $@; do
GALLIUM_DRIVERS+=",${i}"
done
fi
;;
esac
}
@@ -0,0 +1,78 @@
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=5
inherit eutils linux-info linux-mod
DESCRIPTION="Broadcom's IEEE 802.11a/b/g/n hybrid Linux device driver"
HOMEPAGE="http://www.broadcom.com/support/802.11/linux_sta.php"
SRC_BASE="http://www.broadcom.com/docs/linux_sta/hybrid-v35"
SRC_URI="x86? ( ${SRC_BASE}-nodebug-pcoem-${PV//\./_}.tar.gz )
amd64? ( ${SRC_BASE}_64-nodebug-pcoem-${PV//\./_}.tar.gz )
http://www.broadcom.com/docs/linux_sta/README_${PV}.txt -> README-${P}.txt"
LICENSE="Broadcom"
KEYWORDS="-* ~amd64 ~x86"
RESTRICT="mirror"
DEPEND="virtual/linux-sources"
RDEPEND=""
S="${WORKDIR}"
MODULE_NAMES="wl(net/wireless)"
MODULESD_WL_ALIASES=("wlan0 wl")
pkg_setup() {
# bug #300570
# NOTE<lxnay>: module builds correctly anyway with b43 and SSB enabled
# make checks non-fatal. The correct fix is blackisting ssb and, perhaps
# b43 via udev rules. Moreover, previous fix broke binpkgs support.
CONFIG_CHECK="~!B43 ~!BCMA ~!SSB"
CONFIG_CHECK2="LIB80211 ~!MAC80211 ~LIB80211_CRYPT_TKIP"
ERROR_B43="B43: If you insist on building this, you must blacklist it!"
ERROR_BCMA="BCMA: If you insist on building this, you must blacklist it!"
ERROR_SSB="SSB: If you insist on building this, you must blacklist it!"
ERROR_LIB80211="LIB80211: Please enable it. If you can't find it: enabling the driver for \"Intel PRO/Wireless 2100\" or \"Intel PRO/Wireless 2200BG\" (IPW2100 or IPW2200) should suffice."
ERROR_MAC80211="MAC80211: If you insist on building this, you must blacklist it!"
ERROR_PREEMPT_RCU="PREEMPT_RCU: Please do not set the Preemption Model to \"Preemptible Kernel\"; choose something else."
ERROR_LIB80211_CRYPT_TKIP="LIB80211_CRYPT_TKIP: You will need this for WPA."
if kernel_is ge 3 8 8; then
CONFIG_CHECK="${CONFIG_CHECK} ${CONFIG_CHECK2} CFG80211 ~!PREEMPT_RCU ~!PREEMPT"
elif kernel_is ge 2 6 32; then
CONFIG_CHECK="${CONFIG_CHECK} ${CONFIG_CHECK2} CFG80211"
elif kernel_is ge 2 6 31; then
CONFIG_CHECK="${CONFIG_CHECK} ${CONFIG_CHECK2} WIRELESS_EXT ~!MAC80211"
elif kernel_is ge 2 6 29; then
CONFIG_CHECK="${CONFIG_CHECK} ${CONFIG_CHECK2} WIRELESS_EXT COMPAT_NET_DEV_OPS"
else
CONFIG_CHECK="${CONFIG_CHECK} IEEE80211 IEEE80211_CRYPT_TKIP"
fi
linux-mod_pkg_setup
BUILD_PARAMS="-C ${KV_DIR} M=${S}"
BUILD_TARGETS="wl.ko"
}
src_prepare() {
epatch \
"${FILESDIR}/${PN}-6.30.223.141-license.patch" \
"${FILESDIR}/${PN}-6.30.223.141-makefile.patch" \
"${FILESDIR}/${PN}-6.30.223.141-eth-to-wlan.patch" \
"${FILESDIR}/${PN}-6.30.223.141-gcc.patch" \
"${FILESDIR}/${PN}-6.30.223.248-r3-Wno-date-time.patch" \
"${FILESDIR}/${PN}-6.30.223.248-r3-linux-3.15-3.18.patch" \
"${FILESDIR}/${PN}-6.30.223.248-r3-linux-4.0.patch"
"${FILESDIR}/${PN}-6.30.223.248-r4-linux-4.2.patch"
epatch_user
}
src_install() {
linux-mod_src_install
dodoc "${DISTDIR}/README-${P}.txt"
}
@@ -0,0 +1,16 @@
diff --git a/src/wl/sys/wl_cfg80211_hybrid.c b/src/wl/sys/wl_cfg80211_hybrid.c
index ea0726f..1541dad 100644
--- a/src/wl/sys/wl_cfg80211_hybrid.c
+++ b/src/wl/sys/wl_cfg80211_hybrid.c
@@ -2047,7 +2047,11 @@ wl_notify_connect_status(struct wl_cfg80211_priv *wl, struct net_device *ndev,
}
else if ((event == WLC_E_LINK && ~(flags & WLC_EVENT_MSG_LINK)) ||
event == WLC_E_DEAUTH_IND || event == WLC_E_DISASSOC_IND) {
+#if LINUX_VERSION_CODE >= KERNEL_VERSION(4, 2, 0)
+ cfg80211_disconnected(ndev, 0, NULL, 0, false, GFP_KERNEL);
+#else
cfg80211_disconnected(ndev, 0, NULL, 0, GFP_KERNEL);
+#endif
clear_bit(WL_STATUS_CONNECTED, &wl->status);
wl_link_down(wl);
wl_init_prof(wl->profile);
+1
View File
@@ -8,3 +8,4 @@ DIST libdrm-2.4.56.tar.bz2 590856 SHA256 e20fbbe092177a8422913d8884a1255477456ab
DIST libdrm-2.4.58.tar.bz2 573202 SHA256 b155fae6b9c9a3b02ef8b77f58c7c219194c996a4018dc55ba66c03996a365dd SHA512 26776b3f93fe173f4e0f94668813ec1a756d9f15385d1cad70c7af8d4d5d503aef00e14081c76f6fcac6e0c606e106e47ddf76038f8601b71fc380306536f937 WHIRLPOOL 36d8915b3189fd0722f96698ce5e7a94188859c7372631c4126b0e09e8fa6dbd4e34de5e9d62e053c36e9f431d84d68d327be307d69caf92e1016893e77cf190
DIST libdrm-2.4.59.tar.bz2 592722 SHA256 68d26e1fd85582f4243d66864f9b43ca4ee93662825de32b5506fc8e181ea41b SHA512 b9f61cfd47cf4a02c10e7fe79b0e9c5701383c76425cf4985a9b91d909f905334ca1ace7334aa0a4ab400694ad84a1a3bc1c3f29842d808026702b35fa9f87c3 WHIRLPOOL 6b0e1be70164db86152503e4b72373736f0462ff97ffac2c79a6c1fce83d658e6030d5435be5a61c1f6ca50728db4c7e3a5d8f5e48073fc74169696ff1b7c5be
DIST libdrm-2.4.62.tar.bz2 637472 SHA256 906c294bdbe1c94c3ca084305d61a6e5a8367f3b4986e6cc13b1e9b3f75931dc SHA512 f7e2ef79c80dd0c3a837970052b7e66110e9b99d3e87b3cd278646bb4cb39832a9562144016a7e956a85212d9251b191279f5ba25d7e8bc0bfbfc1a311df3873 WHIRLPOOL e9ca493f01598bcb7e5664c531e48e74570a7ee0c754794ed2247314123821509448d62290b594073389ff545a019e24305d365ba7435f933665cc57d85385dc
DIST libdrm-2.4.64.tar.bz2 640440 SHA256 b60786fe7d6e42adb3966ce1a658f63fec528d537396381cbda93bcc99a934b6 SHA512 f4fae23b981c761622b6170ae1f5bc805fc9fe2c5f3531dd45b3e3fcb65c4c4f08d39744c30e2d7f9c14ce6f13dac4a655c0b0ca9785965c59917a4e594e507b WHIRLPOOL 49a96a5d2795f2a9c9fca5cc5808cbfa5e06717d7f4b8221cee55288e16cee503a109321aea04680900fb0bc80e56482a6c8cd15e887eee3d327f0af52706fac
+61
View File
@@ -0,0 +1,61 @@
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=5
XORG_MULTILIB=yes
inherit xorg-2
DESCRIPTION="X.Org libdrm library"
HOMEPAGE="http://dri.freedesktop.org/"
if [[ ${PV} = 9999* ]]; then
EGIT_REPO_URI="git://anongit.freedesktop.org/git/mesa/drm"
else
SRC_URI="http://dri.freedesktop.org/${PN}/${P}.tar.bz2"
fi
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~amd64-linux ~arm-linux ~x86-linux"
VIDEO_CARDS="exynos freedreno intel nouveau omap radeon tegra vmware"
for card in ${VIDEO_CARDS}; do
IUSE_VIDEO_CARDS+=" video_cards_${card}"
done
IUSE="${IUSE_VIDEO_CARDS} libkms valgrind"
RESTRICT="test" # see bug #236845
RDEPEND=">=dev-libs/libpthread-stubs-0.3-r1:=[${MULTILIB_USEDEP}]
video_cards_intel? ( >=x11-libs/libpciaccess-0.13.1-r1:=[${MULTILIB_USEDEP}] )
abi_x86_32? ( !app-emulation/emul-linux-x86-opengl[-abi_x86_32(-)] )"
DEPEND="${RDEPEND}
valgrind? ( dev-util/valgrind )"
src_prepare() {
if [[ ${PV} = 9999* ]]; then
# tests are restricted, no point in building them
sed -ie 's/tests //' "${S}"/Makefile.am
fi
xorg-2_src_prepare
}
src_configure() {
XORG_CONFIGURE_OPTIONS=(
# Udev is only used by tests now.
--disable-udev
--disable-cairo-tests
$(use_enable video_cards_exynos exynos-experimental-api)
$(use_enable video_cards_freedreno freedreno)
$(use_enable video_cards_intel intel)
$(use_enable video_cards_nouveau nouveau)
$(use_enable video_cards_omap omap-experimental-api)
$(use_enable video_cards_radeon radeon)
$(use_enable video_cards_radeon amdgpu)
$(use_enable video_cards_tegra tegra-experimental-api)
$(use_enable video_cards_vmware vmwgfx)
$(use_enable libkms)
# valgrind installs its .pc file to the pkgconfig for the primary arch
--enable-valgrind=$(usex valgrind auto no)
)
xorg-2_src_configure
}