dev-python/h5py: Bump to 3.8.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/h5py/Manifest

@@ -1 +1,2 @@
 DIST h5py-3.7.0.tar.gz 392355 BLAKE2B efc974ff14457ef00329c6b2adf5b926e2dff33bbb4b9e9d60773760a973214c5279bfafca87c6fcab02bbffb85b780c708d26fb55a1e7a401d8d676f20acc15 SHA512 c10a9a623c88dbc965238cb2057b8924492c762c29610cfdb24f26f878a7322e414d3e5c90d750c2f5cfe1b4949f884bc17f09a126b01a4721ad6e14761174a2
+DIST h5py-3.8.0.tar.gz 400774 BLAKE2B 2e48991225170fbb728fa55a68aea795db42c7eae605d123a24a59a8730220ddc98e88dfbff60220ce8c6952ca7fc0c3e33d472acae09864a29bfe11d90fcca1 SHA512 13397f66a9fc735e1143eb9e3dd584280e955adf49de467bf56c1a98952903720480ab8d505921b7e22c16453498625ad93421a64e520f15ea3566472849a8fd

dev-python/h5py/h5py-3.8.0.ebuild

@@ -0,0 +1,70 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Simple Python interface to HDF5 files"
+HOMEPAGE="
+	https://www.h5py.org/
+	https://github.com/h5py/h5py/
+	https://pypi.org/project/h5py/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~riscv ~x86 ~amd64-linux ~x86-linux"
+# disable mpi until mpi4py gets python3_8
+#IUSE="examples mpi"
+IUSE="examples"
+
+#RDEPEND="sci-libs/hdf5:=[mpi=,hl(+)]
+DEPEND="
+	sci-libs/hdf5:=[hl(+)]
+"
+RDEPEND="
+	${DEPEND}
+	>=dev-python/numpy-1.14.5[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	>=dev-python/numpy-1.14.5[${PYTHON_USEDEP}]
+	dev-python/pkgconfig[${PYTHON_USEDEP}]
+	test? (
+		dev-python/QtPy[testlib,${PYTHON_USEDEP}]
+	)
+"
+#	mpi? ( virtual/mpi )
+#	mpi? ( dev-python/mpi4py[${PYTHON_USEDEP}] )
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs \
+	dev-python/alabaster
+
+#pkg_setup() {
+#	use mpi && export CC=mpicc
+#}
+
+python_prepare_all() {
+	# avoid pytest-mpi dep, we do not use mpi anyway
+	sed -i -e 's:pytest-mpi::' pytest.ini || die
+	distutils-r1_python_prepare_all
+
+	export H5PY_SETUP_REQUIRES=0
+}
+
+python_test() {
+	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+	epytest -m "not mpi"
+}
+
+python_install_all() {
+	use examples && dodoc -r examples
+	distutils-r1_python_install_all
+}