sci-mathematics/vampire: bump to 5.0.0

Signed-off-by: Maciej Barć <xgqt@gentoo.org>

sci-mathematics/vampire/Manifest

@@ -1 +1,2 @@
 DIST vampire-4.9-casc2023.tar.gz 1502934 BLAKE2B 399ca20578d30e6cca74e7e46a97d87975ebcc9cd18e61fc125b99eec008a46df7e12b8e3c5e448f1e112429a8f79d7d7b9866811d2cce1c523bd0fb322278c4 SHA512 f37ca777da8dad719e3072d6c0ff31b67152ed699a1f21ccb5f004398d6472ab8105f16bfd21ec8a42cf65f8aca4a197e9c4557724e2d1a38bed291b2c5aeef3
+DIST vampire-5.0.0.tar.gz 2674000 BLAKE2B 2de6034223dd8f9be0634ed6b052a6feb5e337d63e3862e9dee2fa7c16afee9a6c94d48c0a5d4e7ddd1ef4111f9f4b4eb5d9a174fa76b56a54f884a4a422c50a SHA512 1cc6573d00d0eeee0f4d824a46f8dbb9702ba00245863b231da6d6a67655dfebb8815b336f29ea1455f71a9c0aec327d5d47babe0e960ccfb644ab0823e916e4

sci-mathematics/vampire/vampire-5.0.0.ebuild

@@ -0,0 +1,66 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CMAKE_IN_SOURCE_BUILD="true"
+
+inherit flag-o-matic cmake
+
+DESCRIPTION="The Vampire Prover, theorem prover for first-order logic"
+HOMEPAGE="https://vprover.github.io/
+	https://github.com/vprover/vampire/"
+
+if [[ ${PV} == *9999* ]] ; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/vprover/${PN}"
+else
+	SRC_URI="https://github.com/vprover/${PN}/releases/download/v${PV}/${PN}.tar.gz
+		-> ${P}.tar.gz"
+	S="${WORKDIR}/${PN}"
+
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="BSD"
+SLOT="0/${PV}"
+IUSE="test +z3"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	z3? (
+		dev-libs/gmp:=
+		>=sci-mathematics/z3-4.11.2:=
+	)
+"
+DEPEND="
+	${RDEPEND}
+"
+
+src_configure() {
+	# -Werror=strict-aliasing warnings, bug #863269
+	filter-lto
+	append-flags -fno-strict-aliasing
+
+	# Only compiles in the Debug build.
+	local CMAKE_BUILD_TYPE="Debug"
+
+	local -a mycmakeargs=(
+		-DZ3_DIR=$(usex z3 "/usr/$(get_libdir)/cmake/z3/" "")
+	)
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+
+	if use test ; then
+		eninja vtest
+	fi
+}
+
+src_install() {
+	dobin "${PN}"
+	einstalldocs
+}