xfce-base/thunar: Bump to 4.17.7

Signed-off-by: Michał Górny <mgorny@gentoo.org>

xfce-base/thunar/Manifest

@@ -1,2 +1,3 @@
 DIST thunar-4.16.10.tar.bz2 2324476 BLAKE2B a8305f234b6f69654d6559594f1228ebbb5009b337fbdee6d94dc2f3c309d67cbe2aa5c357fd5207d4e907b9d06875dd3164d501c84a22c9f73e71b705577fd7 SHA512 b6fbb27acaae85e7d5c711213c5c457d7eaf973dabafbeabbc00ef01491b54b05da00304503ed03a1ee0716c2558f435754666dd5358f36b2e155e4c8132ebce
 DIST thunar-4.17.6.tar.bz2 2474323 BLAKE2B add0ec83dfff7119df7b0c7dfde579cbd8ea5ae86f77e38f8d1777d47c85145a8f301b3008a278a5ab94efd8ab3fcd6467cf09671630335b2e06123432e8209f SHA512 8ee9508ef1384525991fa96c7b69a4722bbb5d8f7a16c065f47daae9e9eca6e06875c92ba4a15b9c420a8162b9bd547d5a15120cc2f08e0824d318f52fd14b44
+DIST thunar-4.17.7.tar.bz2 2507703 BLAKE2B 18393d33066059892e0a1bff68728d69aacc36604b48483789783aa3474ad3fa7c48c80a3af2380d61ac01bb027f092be63dc78fa40638b662348cb2c53bd4bf SHA512 79ccfd2baed6f956706dda52de9a0fe4dda6c59c10833fe9e699f6797abb092ba1640a97150413f890829d83fe78bb700f7a1fa912515866bc3ba7f53a350223

xfce-base/thunar/thunar-4.17.7.ebuild

@@ -0,0 +1,76 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit xdg-utils
+
+DESCRIPTION="File manager for the Xfce desktop environment"
+HOMEPAGE="https://www.xfce.org/projects/ https://docs.xfce.org/xfce/thunar/start"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="0/3"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="exif introspection libnotify pcre +trash-panel-plugin udisks"
+
+GVFS_DEPEND=">=gnome-base/gvfs-1.18.3"
+DEPEND=">=dev-libs/glib-2.56
+	>=x11-libs/gdk-pixbuf-2.14
+	>=x11-libs/gtk+-3.22:3
+	>=xfce-base/exo-4.17.0:=
+	>=xfce-base/libxfce4ui-4.17.0:=
+	>=xfce-base/libxfce4util-4.17.1:=
+	>=xfce-base/xfconf-4.12:=
+	exif? ( >=media-libs/libexif-0.6.19:= )
+	introspection? ( dev-libs/gobject-introspection:= )
+	libnotify? ( >=x11-libs/libnotify-0.7 )
+	pcre? ( >=dev-libs/libpcre-6:= )
+	trash-panel-plugin? ( >=xfce-base/xfce4-panel-4.10:= )
+	udisks? ( dev-libs/libgudev:= )"
+RDEPEND="${DEPEND}
+	>=dev-util/desktop-file-utils-0.20-r1
+	x11-misc/shared-mime-info
+	trash-panel-plugin? ( ${GVFS_DEPEND} )
+	udisks? (
+		virtual/udev
+		${GVFS_DEPEND}[udisks,udev]
+		)"
+BDEPEND="
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+src_configure() {
+	local myconf=(
+		$(use_enable introspection)
+		$(use_enable udisks gudev)
+		$(use_enable libnotify notifications)
+		$(use_enable exif)
+		$(use_enable pcre)
+		$(use_enable trash-panel-plugin tpa-plugin)
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	elog "If you were using an older Xfce version and Thunar fails to start"
+	elog "with a message similar to:"
+	elog "  Failed to register: Timeout was reached"
+	elog "you may need to reset your xfce4 session:"
+	elog "  rm ~/.cache/sessions/xfce4-session-*"
+	elog "See https://bugs.gentoo.org/698914."
+
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}