kde-apps/umbrello: 21.12.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

kde-apps/umbrello/Manifest

@@ -1 +1,2 @@
 DIST umbrello-21.08.3.tar.xz 5650048 BLAKE2B da8d0fd63e7d603a52866e8a91e3aa0d6f4c80f4e95096b4dea4746348ad0cfcde11ec194d4771c6540a6861a206dda371316b12b8f1c69d4853783380d0e92a SHA512 176804977069383aab5e809b2a3e94b2b965d5b57bf14eb8215416a2288d5a141a8bdeabae241b3f08bab498b36b018ac501797f8f61653bf18910302aa61130
+DIST umbrello-21.12.0.tar.xz 5651284 BLAKE2B ee1254a03c6f991e492265308c57b0276ccba53a23a51234e422166b5a9c6c691936124e36198b626aa19f4a536692d36ba01f51d9cb96450a894310fd40657a SHA512 44b1e39bf1cdada211c8a59523b16bc313a9954291f490c6291bd4771137c6243cd0beca769be206a6108b49239538c67b56dd60254fa39b87d0e310037f9558

kde-apps/umbrello/umbrello-21.12.0.ebuild

@@ -0,0 +1,75 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_QTHELP="false" # TODO: figure out install error
+ECM_TEST="forceoptional"
+KFMIN=5.88.0
+QTMIN=5.15.2
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="KDE UML Modeller"
+HOMEPAGE="https://apps.kde.org/umbrello/ https://umbrello.kde.org"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="php"
+
+RDEPEND="
+	dev-libs/libxml2
+	dev-libs/libxslt
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdelibs4support-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/ktexteditor-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	php? (
+		dev-util/kdevelop:5=
+		dev-util/kdevelop-pg-qt:5
+		dev-util/kdevelop-php:5
+	)
+"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-20.08.3-no-qtwebkit.patch
+	"${FILESDIR}"/${PN}-20.08.3-gentoo-docbundledir.patch # fix hardcoded path
+)
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_Doxygen=ON # broken, re-enable w/ ECM_QTHELP
+		-DCMAKE_DISABLE_FIND_PACKAGE_Qt5WebKitWidgets=ON
+		-DBUILD_APIDOC=OFF
+		-DBUILD_KF5=ON
+		-DBUILD_PHP_IMPORT=$(usex php)
+		-DBUILD_unittests=$(usex test)
+	)
+	use test && mycmakeargs+=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_LLVM=ON
+		-DCMAKE_DISABLE_FIND_PACKAGE_Clang=ON
+		-DCMAKE_DISABLE_FIND_PACKAGE_CLANG=ON
+	)
+
+	ecm_src_configure
+}