gui-libs/libhandy: Version bump to 1.6.3

Signed-off-by: Matt Turner <mattst88@gentoo.org>

gui-libs/libhandy/Manifest

@@ -1 +1,2 @@
 DIST libhandy-1.6.2.tar.xz 1783660 BLAKE2B 4819ee8917d324f795b5f983ba69a3a5e5e77addf45c83b63ab676407aadb335f1130d02f011a6fb479f7ab71fdac7030b6fadb42dea92ac2fa949ed6d240844 SHA512 482a848ec5b085e2c5dcc94a1a9be618de22f779dc8c8cc07945f6269d1061e96009700ee9e3ddf0ccac0ce2ac01ccb4da3a8d366f1b3b9ceecc282a46021a6d
+DIST libhandy-1.6.3.tar.xz 1785692 BLAKE2B e48c8724a5298d61412562f4be00e7c3198dae896d143319adc3c84296f0ce1272a46b23e432df02f184a330c342ed6c34bc072fdcc648cbf1923aa17105b3bf SHA512 bf210bc49b512fe74438759e2b8238fbba9c8ccd57e96b7a72f484df080a407da56ffcacbef3265da8de6a1edc954d4b3d77eaddbd1f62141d41db5c17253b49

gui-libs/libhandy/libhandy-1.6.3.ebuild

@@ -0,0 +1,56 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit gnome.org meson xdg vala virtualx
+
+DESCRIPTION="Building blocks for modern adaptive GNOME apps"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/libhandy/"
+
+LICENSE="LGPL-2.1+"
+SLOT="1"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+IUSE="examples glade gtk-doc +introspection test +vala"
+REQUIRED_USE="vala? ( introspection )"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/glib-2.44:2
+	>=x11-libs/gtk+-3.24.1:3[introspection?]
+	glade? ( dev-util/glade:3.10= )
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-libs/libxml2:2
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	gtk-doc? ( >=dev-util/gi-docgen-2021.1
+		app-text/docbook-xml-dtd:4.3 )
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	use vala && vala_src_prepare
+	xdg_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dprofiling=false # -pg passing
+		$(meson_feature introspection)
+		$(meson_use vala vapi)
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use test tests)
+		$(meson_use examples)
+		$(meson_feature glade glade_catalog)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}