dev-util/intel-graphics-compiler: bump to version 1.0.8517

Package-Manager: Portage-3.0.22, Repoman-3.0.3
Signed-off-by: Conrad Kostecki <conikost@gentoo.org>
This commit is contained in:
Conrad Kostecki
2021-09-01 22:27:53 +02:00
parent 389574bfae
commit 0fb4e4c9f6
2 changed files with 79 additions and 0 deletions
@@ -3,3 +3,4 @@ DIST intel-graphics-compiler-1.0.4944.tar.gz 6632351 BLAKE2B a3d72730b8c10fd3810
DIST intel-graphics-compiler-1.0.5353.tar.gz 6642256 BLAKE2B 34b80b30f33dbd57bcea15852c80cdf8bdbf4630a7904946c7ce84481789e7db42f5216ba14140d445e9b0adbfcfe224468e462ea27768f0e8d31525ce56cde1 SHA512 e9f20e2261c5cb79d365d5d8257e8f4830b2364962c48413cc80154469db34c1c844ae5d576cbce2e3c5e5cbe22c7c3710ebd0a7fe7208e5412e81ce20077c80
DIST intel-graphics-compiler-1.0.8173.tar.gz 7471884 BLAKE2B 2248a8d5f23d4578c5bd04a799af65767916b3705e16a8145149794a2cf16e5a0e16c21669336151a241cc52e7672b05eb892ac4925f2c2d0b22673af4ebf67f SHA512 bebccee0699dea48e98ddcdb320cacacda0cdcd36b68e51d932791756b0a8e2171a78cc1921ca2a092b9fe7dbd7a783d4898ada08c58bf856dd29bfc08334fa0
DIST intel-graphics-compiler-1.0.8365.tar.gz 7509633 BLAKE2B ffe18d18b409db36bd24215d841daaa36d5055d61b9021e385fe9178351b6a92383839e271a12d1e5017150b9697060fe37f803c5153d2f107813aeb2e7a74cf SHA512 6597afbab2c101d69e6a991b5b065ebbded7ccc6227c0ed82b6b0bd33fec26489c30a0a7a9558617578a767ca6d7382a6ab36144f4c64df742c6bd545ce991e9
DIST intel-graphics-compiler-1.0.8517.tar.gz 7539946 BLAKE2B 034d2e3dcfc25186e29eebfabffbca7b8a5adab1f766c7515b4a3206c9c52eca3dd766e17320ea0c40067385fc6235d92eec13f1d12909915b86fb42a7862825 SHA512 35f09d1f6b117e78814cc235d03b1f1164f11a2d2a5d188b6658677c4b759422048764e765f7690f4789dc8b8c068714a68642c2d956ccc84b387a959f9af07f
@@ -0,0 +1,78 @@
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
CMAKE_BUILD_TYPE="Release"
LLVM_MAX_SLOT="10"
MY_PN="igc"
MY_P="${MY_PN}-${PV}"
PYTHON_COMPAT=( python3_{8..10} )
inherit cmake flag-o-matic llvm python-any-r1
DESCRIPTION="LLVM-based OpenCL compiler for OpenCL targetting Intel Gen graphics hardware"
HOMEPAGE="https://github.com/intel/intel-graphics-compiler"
SRC_URI="https://github.com/intel/${PN}/archive/${MY_P}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}/${PN}-${MY_P}"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64"
IUSE="debug"
DEPEND="
dev-libs/opencl-clang:${LLVM_MAX_SLOT}=
sys-devel/llvm:${LLVM_MAX_SLOT}=
"
RDEPEND="${DEPEND}"
BDEPEND="
${PYTHON_DEPS}
>=sys-devel/lld-${LLVM_MAX_SLOT}
"
PATCHES=(
"${FILESDIR}/${PN}-1.0.9-no_Werror.patch"
"${FILESDIR}/${PN}-1.0.8173-opencl-clang_version.patch"
"${FILESDIR}/${PN}-1.0.8173-fix-missing-limits.patch"
"${FILESDIR}/${PN}-1.0.8365-disable-git.patch"
"${FILESDIR}/${PN}-1.0.8365-cmake-project.patch"
"${FILESDIR}/${PN}-1.0.8365-cmake-minimum-version.patch"
)
pkg_setup() {
llvm_pkg_setup
python-any-r1_pkg_setup
}
src_configure() {
# Since late March 2020 cmake.eclass does not set -DNDEBUG any more,
# and the way IGC uses this definition causes problems for some users.
# See bug #718824 for more information.
! use debug && append-cppflags -DNDEBUG
local mycmakeargs=(
# Those options are ensuring, that we are using
# the system LLVM with the correct slot.
-DCCLANG_SONAME_VERSION="${LLVM_MAX_SLOT}"
-DCMAKE_LIBRARY_PATH="$(get_llvm_prefix ${LLVM_MAX_SLOT})/$(get_libdir)"
-DIGC_OPTION__ARCHITECTURE_TARGET="Linux64"
-DIGC_OPTION__CLANG_MODE="Prebuilds"
-DIGC_OPTION__LLD_MODE="Prebuilds"
-DIGC_OPTION__LLDELF_H_DIR="${EPREFIX}/usr/include/lld/Common"
-DIGC_OPTION__LLVM_MODE="Prebuilds"
-DIGC_OPTION__LLVM_PREFERRED_VERSION="${LLVM_MAX_SLOT}"
# VectorCompiler needs work, as at the moment upstream
# only supports building vc-intrinsics in place.
-DIGC_BUILD__VC_ENABLED="NO"
# This will suspress some CMake warnings,
# which cannot be fixed at the moment.
-Wno-dev
)
cmake_src_configure
}