net-misc/x2goclient: drop qt4 support, bug #631892

Also drop nsplugin support at the same time (does not work with qt5)

Package-Manager: Portage-2.3.10, Repoman-2.3.3

net-misc/x2goclient/x2goclient-4.1.0.1-r1.ebuild

@@ -0,0 +1,61 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils qmake-utils
+
+DESCRIPTION="The X2Go Qt client"
+HOMEPAGE="http://www.x2go.org"
+SRC_URI="http://code.x2go.org/releases/source/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="ldap"
+
+DEPEND="dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	>=net-libs/libssh-0.6.0_rc1
+	net-print/cups
+	x11-libs/libXpm
+	ldap? ( net-nds/openldap )
+"
+RDEPEND="${DEPEND}
+	net-misc/nx"
+
+CLIENT_BUILD="${WORKDIR}"/${P}.client_build
+PLUGIN_BUILD="${WORKDIR}"/${P}.plugin_build
+
+src_prepare() {
+	default
+
+	if ! use ldap; then
+		sed -e "s/-lldap//" -i x2goclient.pro || die
+		sed -e "s/#define USELDAP//" -i src/x2goclientconfig.h || die
+	fi
+}
+
+src_configure() {
+	eqmake5 "${S}"/x2goclient.pro
+}
+
+src_install() {
+	dobin ${PN}
+
+	local size
+	for size in 16 32 48 64 128 ; do
+		doicon -s ${size} res/img/icons/${size}x${size}/${PN}.png
+	done
+	newicon -s scalable res/img/icons/hildon/${PN}_hildon.svg ${PN}.svg
+
+	insinto /usr/share/pixmaps
+	doins res/img/icons/${PN}.xpm
+
+	domenu desktop/${PN}.desktop
+	doman man/man?/*
+}