dev-util/eric: version bump 17.07

Package-Manager: Portage-2.3.6, Repoman-2.3.3

dev-util/eric/Manifest

@@ -1,2 +1,3 @@
 DIST eric6-17.03.tar.gz 18904799 SHA256 cfa78bea6812303689223d42efdc8de530e7c714acc0d1d5aeb375cc9006a2d3 SHA512 3bc71e87475eeeac02c9a186cd5c0044c5196d884ec56a228ff66e2af6ee5dd3d0e7356486e284b28aa945b0e225c9b626e1a21773878d6834e211d4151af3a7 WHIRLPOOL c7cb12562424395b12687e6f4f3489b57a50fa1363ebbd2aa0a4e48051ae52ce62512904af1104a881999ea4fdfa355544e8fdee802c0584255e9c9697486ea9
 DIST eric6-17.04.1.tar.gz 18688754 SHA256 b6c08e646d920551392f1a93f231adefd504999933891eb8bb4038fe6ab405ba SHA512 e3f2bd47e3d3308db2c6443b3f616db130cc6a04e904930a2f1733c32dab8114e3094520c2def044d923fc5e7f526dc1ca1f30ebbefa1bf70ff2beef0508547d WHIRLPOOL bc09e505d2e44763d87c17786e3a4268d11e1ea0dff518611862a8bb497fc63836c105356b1936c8469c6b159fdbf41527fd382e432b3ab7f349da089fdb14a2
+DIST eric6-17.07.tar.gz 18822449 SHA256 6d3d83c6815e89634aca532468cbedff8ae636dfc0b4187206e548af24468e04 SHA512 5d1430262fce9eba19487f45c663c5e455bbf85b07c753d9bca78ec658db5f4eedd4db177d293335466dbc2362dc8a775ffac8d18eb48592451a61ef7592ca13 WHIRLPOOL 43f089156dccfe40f56cc026a5b5fc4fa982aca50c741990595bd4e8a210169f10cef0627ffd1fd99d1c717fba818fcb62b74295fbf0f1ced1a149542971561a

dev-util/eric/eric-17.07.ebuild

@@ -0,0 +1,66 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5} )
+PYTHON_REQ_USE="sqlite,xml"
+
+inherit python-single-r1
+
+DESCRIPTION="A full featured Python IDE using PyQt and QScintilla"
+HOMEPAGE="http://eric-ide.python-projects.org/"
+LICENSE="GPL-3"
+SLOT="6"
+
+MY_P=${PN}${SLOT}-${PV}
+SRC_URI="mirror://sourceforge/eric-ide/${PN}${SLOT}/stable/${PV}/${MY_P}.tar.gz"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+IUSE=""
+
+DEPEND="
+	${PYTHON_DEPS}
+	>=dev-python/sip-4.14.3[${PYTHON_USEDEP}]
+	>=dev-python/PyQt5-5.5.1[${PYTHON_USEDEP},gui,help,network,printsupport,sql,svg,webkit]
+	>=dev-python/qscintilla-python-2.8[qt5,${PYTHON_USEDEP}]
+"
+RDEPEND="${DEPEND}
+	>=dev-python/chardet-3.0.4[${PYTHON_USEDEP}]
+	>=dev-python/coverage-4.1.0[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.2.0[${PYTHON_USEDEP}]
+	!dev-util/eric:4
+	!dev-util/eric:5
+"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+S=${WORKDIR}/${MY_P}
+
+DOCS=(changelog README.rst THANKS)
+
+src_prepare() {
+	default
+
+	# Delete internal copies of dev-python/chardet and dev-python/pygments
+	rm -fr eric/ThirdParty/{CharDet,Pygments} || die
+
+	# Delete internal copy of dev-python/coverage
+	rm -fr eric/DebugClients/Python{,3}/coverage || die
+	sed -i -e 's/from DebugClients\.Python3\?\.coverage/from coverage/' \
+		$(grep -lr 'from DebugClients\.Python3\?\.coverage' .) || die
+
+	# Fix desktop files (bug 458092)
+	sed -i -re '/^Categories=/s:(Python|QtWeb):X-&:g' eric/eric6{,_{,web}browser}.desktop || die
+}
+
+src_install() {
+	"${PYTHON}" install.py \
+		-b "${EPREFIX}/usr/bin" \
+		-d "$(python_get_sitedir)" \
+		-i "${D}" \
+		-c \
+		-z \
+		|| die
+
+	python_optimize
+	einstalldocs
+}