dev-python/apache-libcloud: Bump to 3.9.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/apache-libcloud/Manifest

@@ -1 +1,2 @@
 DIST apache-libcloud-3.8.0.tar.gz 2457665 BLAKE2B 39a6f3f99d3b685150e9a5ec198da705e0c8a3fed7da1300a734fe69310f888401da6683a8ea4b3fe042776a19ebff28f7c82921f29ebc91349a3c1a24e60e20 SHA512 ef221c79be2adf22bbd9fa739c619fa8c0afb493a410bf36a6cf2b3ad5cb18b61f552a1d98400b9152c790e3a88ca504848e03bae1fe8a14b94f72f9b7358f50
+DIST apache_libcloud-3.9.0.tar.gz 2579758 BLAKE2B 642f8a61ac0f61cdfb6213bda7fd1cea5c5258a9ed758ae596848d6c32297c5f4f37800b86e8b99525db1e3ff2f07988e6a1a6bc5f396588dad81158abb53514 SHA512 dd803435ab5a33492dc54ccd0799a718167912cdbd772a2e532efc360208b19908323c58c9d728ff5792c2172f9f27ba5c5e09945171021bcc1b8980ca472824

dev-python/apache-libcloud/apache-libcloud-3.9.0.ebuild

@@ -0,0 +1,72 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{12..14} )
+PYTHON_REQ_USE="ssl(+)"
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Unified Interface to the Cloud - python support libs"
+HOMEPAGE="
+	https://libcloud.apache.org/
+	https://github.com/apache/libcloud/
+	https://pypi.org/project/apache-libcloud/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+IUSE="examples"
+
+# Includes optional driver dependencies that are also test dependencies.
+RDEPEND="
+	>=dev-python/cryptography-44.0.2[${PYTHON_USEDEP}]
+	dev-python/fasteners[${PYTHON_USEDEP}]
+	>=dev-python/pyopenssl-25.0.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.26.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/requests-mock[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	if use examples; then
+		mkdir examples || die
+		mv example_*.py examples || die
+	fi
+
+	# needed for tests
+	cp libcloud/test/secrets.py-dist libcloud/test/secrets.py || die
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO
+		libcloud/test/test_init.py::TestUtils::test_init_once_and_debug_mode
+		libcloud/test/common/test_openstack_identity.py::OpenStackIdentityConnectionTestCase::test_token_expiration_and_force_reauthenti
+	)
+	local EPYTEST_IGNORE=(
+		libcloud/test/benchmarks
+		# broken by modern paramiko
+		libcloud/test/compute/test_ssh_client.py
+	)
+
+	local -x NO_INTERNET=1
+	epytest
+}
+
+src_install() {
+	use examples && dodoc -r examples
+	distutils-r1_src_install
+}