dev-ml/js_of_ocaml: bump to 3.0.0 and update live ebuild

Package-Manager: Portage-2.3.6, Repoman-2.3.2

dev-ml/js_of_ocaml/Manifest

@@ -1 +1,2 @@
 DIST js_of_ocaml-2.8.4.tar.gz 1344082 SHA256 74edd38a964fcee930778a908c896b5c9795f64fc34a3c58361ccfa441811725 SHA512 8dc65bac7d60f2d3534e31e0fddb061f1b97bfd8146b1a34b4a1a516574c6a39f66d115646aa9767b7e24a51ec76949b05841088601f97d76972c8899a50c4fd WHIRLPOOL bc444184519ae90d308ae4675078e1d5fd461ea32f4dccf5e74bab25f0a0e8ba49d229f951205effd676b337656633fb7046cd908c2167799253dcee0a61f20f
+DIST js_of_ocaml-3.0.0.tar.gz 1433377 SHA256 eb49ca6d66ac51a41cf611f1a6a85269d310dbc1711ac4b819c9a04ee53b5a4e SHA512 dc4bbbfdacb43338aa7f97b7012b6de8a2eac5d7c5f535ceb9565c477c961a212ce5b2a75b1719fcd9f2d57938ee2162f6f04d3364397a469d7a13d1fe4e3908 WHIRLPOOL a43b35000af7714f571f0cf373b529883063194ff0a4b57a9bae9670b257ee38288a5b8f4caf19b9ee18fdceeea0a2f5fc0f45cd503ebfa1281b657115a54fc1

dev-ml/js_of_ocaml/js_of_ocaml-3.0.0.ebuild

@@ -0,0 +1,75 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+inherit findlib eutils
+
+DESCRIPTION="A compiler from OCaml bytecode to javascript"
+HOMEPAGE="http://ocsigen.org/js_of_ocaml/"
+
+if [ "${PV#9999}" != "${PV}" ] ; then
+	inherit git-r3
+	SRC_URI=""
+	EGIT_REPO_URI="https://github.com/ocsigen/js_of_ocaml"
+	KEYWORDS=""
+else
+	SRC_URI="https://github.com/ocsigen/js_of_ocaml/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="LGPL-2.1-with-linking-exception"
+SLOT="0/${PV}"
+IUSE="+ocamlopt camlp4 lwt doc +deriving +ppx +xml test"
+
+RDEPEND="
+	>=dev-lang/ocaml-3.12:=[ocamlopt?]
+
+	camlp4? ( dev-ml/camlp4:= )
+
+	dev-ml/cmdliner:=
+	dev-ml/cppo:=
+
+	lwt? ( >=dev-ml/lwt-2.4.4:= )
+
+	dev-ml/ocamlbuild:=
+
+	dev-ml/ocaml-migrate-parsetree:=
+	dev-ml/ppx_tools_versioned:=
+	dev-ml/uchar:=
+
+	ppx? ( dev-ml/ppx_tools:= dev-ml/ppx_deriving:= )
+
+	xml? ( >=dev-ml/tyxml-4:= dev-ml/reactiveData:= )
+"
+DEPEND="${RDEPEND}
+	dev-ml/jbuilder
+	dev-ml/opam
+	test? ( dev-util/patdiff )
+"
+REQUIRED_USE="xml? ( ppx )"
+
+src_compile() {
+	emake
+	use doc && emake doc
+}
+
+oinstall() {
+	opam-installer -i \
+		--prefix="${ED}/usr" \
+		--libdir="${D}/$(ocamlc -where)" \
+		--docdir="${ED}/usr/share/doc/${PF}" \
+		--mandir="${ED}/usr/share/man" \
+		${1}.install || die
+}
+
+src_install() {
+	use camlp4 && oinstall js_of_ocaml-camlp4
+	oinstall js_of_ocaml-compiler
+	use lwt && oinstall js_of_ocaml-lwt
+	oinstall js_of_ocaml-ocamlbuild
+	oinstall js_of_ocaml
+	use ppx && oinstall js_of_ocaml-ppx
+	use ppx && oinstall js_of_ocaml-toplevel
+	use xml && oinstall js_of_ocaml-tyxml
+}

dev-ml/js_of_ocaml/js_of_ocaml-9999.ebuild

@@ -20,46 +20,56 @@ fi
 
 LICENSE="LGPL-2.1-with-linking-exception"
 SLOT="0/${PV}"
-IUSE="+ocamlopt doc +deriving +ppx +react +xml X"
+IUSE="+ocamlopt camlp4 lwt doc +deriving +ppx +xml test"
 
 RDEPEND="
-	>=dev-lang/ocaml-3.12:=[ocamlopt?,X?]
-	>=dev-ml/lwt-2.4.4:=[camlp4(+)]
-	react? ( dev-ml/react:=  dev-ml/reactiveData:= )
-	xml? ( >=dev-ml/tyxml-4:= )
-	ppx? ( dev-ml/ppx_tools:= dev-ml/ppx_deriving:= dev-ml/ppx_driver:= )
-	dev-ml/cmdliner:=
-	dev-ml/menhir:=
-	dev-ml/ocaml-base64:=
-	dev-ml/camlp4:=
-	dev-ml/cppo:=
-	dev-ml/uchar:=
-	dev-ml/ocamlbuild:=
-	dev-ml/yojson:=
-	deriving? ( >=dev-ml/deriving-0.6:= )"
-DEPEND="${RDEPEND}"
+	>=dev-lang/ocaml-3.12:=[ocamlopt?]
 
-src_configure() {
-	printf "\n\n" >> Makefile.conf
-	use ocamlopt || echo "BEST := byte" >> Makefile.conf
-	use ocamlopt || echo "NATDYNLINK := NO" >> Makefile.conf
-	use deriving || echo "WITH_DERIVING := NO" >> Makefile.conf
-	use X || echo "WITH_GRAPHICS := NO" >> Makefile.conf
-	use react || echo "WITH_REACT := NO" >> Makefile.conf
-	use ppx || echo "WITH_PPX := NO" >> Makefile.conf
-	use ppx || echo "WITH_PPX_DERIVING := NO" >> Makefile.conf
-	use ppx || echo "WITH_PPX_DRIVER := NO" >> Makefile.conf
-	echo "WITH_ASYNC := NO" >> Makefile.conf
-}
+	camlp4? ( dev-ml/camlp4:= )
+
+	dev-ml/cmdliner:=
+	dev-ml/cppo:=
+
+	lwt? ( >=dev-ml/lwt-2.4.4:= )
+
+	dev-ml/ocamlbuild:=
+
+	dev-ml/ocaml-migrate-parsetree:=
+	dev-ml/ppx_tools_versioned:=
+	dev-ml/uchar:=
+
+	ppx? ( dev-ml/ppx_tools:= dev-ml/ppx_deriving:= )
+
+	xml? ( >=dev-ml/tyxml-4:= dev-ml/reactiveData:= )
+"
+DEPEND="${RDEPEND}
+	dev-ml/jbuilder
+	dev-ml/opam
+	test? ( dev-util/patdiff )
+"
+REQUIRED_USE="xml? ( ppx )"
 
 src_compile() {
-	emake -j1
+	emake
 	use doc && emake doc
 }
 
-src_install() {
-	findlib_src_preinst
-	emake BINDIR="${ED}/usr/bin/" install
-	dodoc CHANGES README.md
-	use doc && dohtml -r doc/api/html/
+oinstall() {
+	opam-installer -i \
+		--prefix="${ED}/usr" \
+		--libdir="${D}/$(ocamlc -where)" \
+		--docdir="${ED}/usr/share/doc/${PF}" \
+		--mandir="${ED}/usr/share/man" \
+		${1}.install || die
+}
+
+src_install() {
+	use camlp4 && oinstall js_of_ocaml-camlp4
+	oinstall js_of_ocaml-compiler
+	use lwt && oinstall js_of_ocaml-lwt
+	oinstall js_of_ocaml-ocamlbuild
+	oinstall js_of_ocaml
+	use ppx && oinstall js_of_ocaml-ppx
+	use ppx && oinstall js_of_ocaml-toplevel
+	use xml && oinstall js_of_ocaml-tyxml
 }

dev-ml/js_of_ocaml/metadata.xml

@@ -6,7 +6,9 @@
     <name>Gentoo ML Project</name>
   </maintainer>
   <use>
+	<flag name="camlp4">Build with camlp4 syntax extensions.</flag>
     <flag name="deriving">Enable <pkg>dev-ml/deriving</pkg> support for improving the type safety.</flag>
+	<flag name="lwt">Enable <pkg>dev-ml/lwt</pkg> support.</flag>
 	<flag name="ppx">Enables the ppx syntax extension</flag>
 	<flag name="react">Enable functionnal reactive programming support.</flag>
   </use>