dev-libs/libgusb: add 0.4.9

Signed-off-by: Sam James <sam@gentoo.org>

dev-libs/libgusb/Manifest

@@ -1 +1,2 @@
 DIST libgusb-0.4.8.tar.xz 51632 BLAKE2B f904bb8a0766a61b0e7d6e5e80d7f0eed5c44537065db2b9bf33cd694fcaa58d93a7cdec37802fd278c2eb7ad2e4de79cd492baa1ead373e31e4d75488999e1e SHA512 b6446761ba4a19b8e7b7fc2bcf26064c89a574c328b794eb3f1723ef71b4100447c5b024bd8163c4e42af935ce0b7e11b93b722871061f7115da0003cc14b001
+DIST libgusb-0.4.9.tar.xz 51672 BLAKE2B b40d39b1d4db63ccc01c1c15807c15c867c84f76d0f36b71ea877e6aef11bb3f1ec6a68affaed385bea1485b945b8c513e10d26e31fa0b362e1607f7d532f9bc SHA512 61052b02ae826cdd24fd1ed8938ce893b37176aae839d789f56c2f37822c8b8f965ca0049cbdffc021eb379e46fc894d3621b46a7585719bde27d908137e4a27

dev-libs/libgusb/libgusb-0.4.9.ebuild

@@ -0,0 +1,72 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+PYTHON_REQ_USE="xml(+)"
+
+inherit meson-multilib python-any-r1 vala
+
+DESCRIPTION="GObject wrapper for libusb"
+HOMEPAGE="https://github.com/hughsie/libgusb"
+SRC_URI="https://github.com/hughsie/libgusb/releases/download/${PV}/${P}.tar.xz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+IUSE="gtk-doc +introspection test +vala"
+REQUIRED_USE="
+	gtk-doc? ( introspection )
+	vala? ( introspection )
+"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/glib-2.44.0:2[${MULTILIB_USEDEP}]
+	virtual/libusb:1[udev,${MULTILIB_USEDEP}]
+	>=dev-libs/json-glib-1.1.1[${MULTILIB_USEDEP},introspection?]
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+	sys-apps/hwdata
+"
+DEPEND="${RDEPEND}
+	test? ( >=dev-util/umockdev-0.17.7[${MULTILIB_USEDEP}] )"
+BDEPEND="
+	$(python_gen_any_dep 'dev-python/setuptools[${PYTHON_USEDEP}]')
+	gtk-doc? ( dev-util/gi-docgen )
+	vala? ( $(vala_depend) )
+	virtual/pkgconfig
+"
+
+python_check_deps() {
+	python_has_version "dev-python/setuptools[${PYTHON_USEDEP}]"
+}
+
+src_prepare() {
+	default
+	use vala && vala_setup
+}
+
+multilib_src_configure() {
+	local emesonargs=(
+		-Ddefault_library=shared
+		$(meson_use test tests)
+		$(meson_native_use_bool vala vapi)
+		-Dusb_ids="${EPREFIX}"/usr/share/hwdata/usb.ids
+		$(meson_native_use_bool gtk-doc docs)
+		$(meson_native_use_bool introspection)
+		$(meson_feature test umockdev)
+
+	)
+	meson_src_configure
+}
+
+multilib_src_install_all() {
+	einstalldocs
+
+	if use gtk-doc; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/ || die
+		mv "${ED}"/usr/share/{doc,gtk-doc}/libgusb || die
+	fi
+}