dev-ml/utop: add 2.14.0

Signed-off-by: Alfredo Tupone <tupone@gentoo.org>

dev-ml/utop/Manifest

@@ -1 +1,2 @@
 DIST utop-2.12.1.tar.gz 416596 BLAKE2B a8a31c91fd4f989e3d89bc736caa7b611ba0ccc2de905adcd1cf59fff87770d5a00c2d7a43462940269ae8be2f5980fa5b8d2ec7ba547b937cc1e6a579621f2f SHA512 cc52bdb2a58141e6f7b678c93f69b0aa5ca4c628cb6841e02e6a783191a917bd838c06682d55f4f455a01a7004e43b5193d8574968b8400050b0f7b5a102ca3a
+DIST utop-2.14.0.tar.gz 418609 BLAKE2B 726ff00d6ce13f6bb81b6e1ad82749094f25a6394f6552f2a976f270d182a7b600a9a17a1c692e56fa807332b25638a8cf0c2082c12ef93262ef5409633fba27 SHA512 16c724c0d54cd14d2126060f00e8b86fe3b886cffd7ff306a825d7f9e045b74ffc5830f659ccb151dfaa36c41c2966c26bc2c2e7567f9e1d725b33e9f677d19e

dev-ml/utop/utop-2.14.0.ebuild

@@ -0,0 +1,66 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit dune elisp-common
+
+DESCRIPTION="Universal toplevel for OCaml"
+HOMEPAGE="https://github.com/ocaml-community/utop"
+SRC_URI="https://github.com/ocaml-community/utop/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~x86"
+IUSE="emacs +ocamlopt"
+
+ELISP_DEPEND="
+	emacs? (
+		>=app-editors/emacs-24:*
+		>=app-emacs/tuareg-mode-2.2.0
+	)
+"
+DEPEND="
+	>=dev-lang/ocaml-4.11
+	dev-ml/lambda-term:=[ocamlopt?]
+	dev-ml/logs:=[ocamlopt?]
+	dev-ml/lwt:=[ocamlopt?]
+	dev-ml/react:=
+	dev-ml/xdg:=[ocamlopt?]
+	dev-ml/zed:=[ocamlopt?]
+"
+RDEPEND="
+	${DEPEND}
+	${ELISP_DEPEND}
+"
+BDEPEND="
+	dev-ml/cppo
+	dev-ml/findlib
+	${ELISP_DEPEND}
+"
+
+SITEFILE="50${PN}-gentoo.el"
+
+src_compile() {
+	dune_src_compile
+
+	use emacs &&
+		BYTECOMPFLAGS="-L src/top" elisp-compile src/top/*.el
+}
+
+src_install() {
+	dune_src_install
+
+	if use emacs ; then
+		elisp-install ${PN} src/top/*.el{,c}
+		elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+	fi
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}