net-misc/smb4k: add 4.0.3

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

net-misc/smb4k/Manifest

@@ -1 +1,2 @@
 DIST smb4k-4.0.2.tar.xz 4852912 BLAKE2B cfa95733a84c63f95ecc4dbeee1a08ed55b5c4939aef370dbc378594d66b6014c8d448195ab2037dcc519437025c352ad9641ff39fdc77b125e1bd712cceb88f SHA512 2b4bd3b698ac4477f8a6fcb317bcdcf9549077062802969595e0bcae96c1f9b35f9c0942da81583577cb3367b7873fa1b4205c5f4fe11d250e08d5a4e6be7ecc
+DIST smb4k-4.0.3.tar.xz 4852680 BLAKE2B 6f50c60ce5358d6945ba5714af3703aff6f9c579400b8d801d4bdf54f8144be400afec412a92d725d68c0654fe0f5a89769b75d3b7f1d293a9199575196388fb SHA512 67fc9b9bbc3f6b65596871055b40586174a7ff5440c5f1d086b7be7b9a69776f512317dd86652925dcde14e0169a24e006b50c00117538d1e800afa06e94fbab

net-misc/smb4k/smb4k-4.0.3.ebuild

@@ -0,0 +1,77 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+KFMIN=6.9.0
+QTMIN=6.8.1
+inherit ecm kde.org xdg
+
+DESCRIPTION="Advanced network neighborhood browser"
+HOMEPAGE="https://apps.kde.org/smb4k/
+https://sourceforge.net/p/smb4k/home/Home/"
+
+if [[ ${KDE_BUILD_TYPE} = release ]]; then
+	SRC_URI="https://downloads.sourceforge.net/${PN}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="+discovery plasma"
+
+DEPEND="
+	>=dev-libs/qtkeychain-0.14.2:=[qt6(+)]
+	>=dev-qt/qtbase-${QTMIN}:6[gui,network,widgets]
+	>=dev-qt/qtdeclarative-${QTMIN}:6
+	>=kde-frameworks/kauth-${KFMIN}:6
+	>=kde-frameworks/kcompletion-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kcrash-${KFMIN}:6
+	>=kde-frameworks/kdbusaddons-${KFMIN}:6
+	>=kde-frameworks/kdnssd-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kiconthemes-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/kjobwidgets-${KFMIN}:6
+	>=kde-frameworks/knotifications-${KFMIN}:6
+	>=kde-frameworks/kstatusnotifieritem-${KFMIN}:6
+	>=kde-frameworks/kwallet-${KFMIN}:6
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
+	>=kde-frameworks/kwindowsystem-${KFMIN}:6
+	>=kde-frameworks/kxmlgui-${KFMIN}:6
+	>=kde-frameworks/solid-${KFMIN}:6
+	net-fs/samba[cups]
+	discovery? (
+		>=net-libs/kdsoap-2.2.0:=[qt6(+)]
+		>=net-libs/kdsoap-ws-discovery-client-0.4.0
+	)
+"
+RDEPEND="${DEPEND}
+	!${CATEGORY}/${PN}:5
+	plasma? (
+		>=kde-frameworks/kirigami-${KFMIN}:6
+		kde-plasma/libplasma:6
+	)
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DSMB4K_WITH_WS_DISCOVERY=$(usex discovery)
+		-DSMB4K_INSTALL_PLASMOID=$(usex plasma)
+	)
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	elog "Users of Samba 4.7 and above please note that for the time being,"
+	elog "the following setting has to be added to or changed in the [global]"
+	elog "section of the smb.conf file:"
+	elog
+	elog "[global]"
+	elog "client max protocol = NT1"
+}