sys-apps/azure-vm-utils: Bump to 0.6.0, fix automagics

Signed-off-by: James Le Cuirot <chewi@gentoo.org>

sys-apps/azure-vm-utils/Manifest

@@ -1 +1,2 @@
 DIST azure-vm-utils-0.5.2.tar.gz 42079 BLAKE2B e5380af38f072b15adb5b25b3df77fea699e88cddc1dd2779a263d63ee795cf79f3df8127265aebbdb031f96dbcfa10e36be71ebca35998f9d7e860b74b753e0 SHA512 2df38df001ee08da68543a8597c485b8f2b4e50fcdbe93defb443a1905fbc87ed5c2ef7903b79d795733b78e37fa8584a4ce33082b7a4490a1c7c4a8e5d8fcac
+DIST azure-vm-utils-0.6.0.tar.gz 48676 BLAKE2B c58a68ffcfa25fdab554c501de30e859f38b949ad7da215b9cf59b5884688a52b7279af2aec0c4dfe80d5240e8baa7460bb8c3e0800235ba7e676a78ac2e90b0 SHA512 f54dc3c6ca45b50a063a9c774f94cec3dd01e910088dbcbbf1ce279dc0c4874aa0fe2b27c9596248c137f787e9be51190cacb0d5ab8ab0cdd4ba994f60b64ddc

sys-apps/azure-vm-utils/azure-vm-utils-0.6.0.ebuild

@@ -0,0 +1,51 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake udev
+
+DESCRIPTION="Utilities and udev rules to support Linux on Azure"
+HOMEPAGE="https://github.com/Azure/azure-vm-utils"
+SRC_URI="https://github.com/Azure/${PN}/archive/refs/tags/v${PV}/${P}.tar.gz"
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+IUSE="dracut test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	test? ( dev-util/cmocka )
+"
+RDEPEND="
+	dracut? ( sys-kernel/dracut )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DDRACUT=$(usex dracut dracut "")
+		-DENABLE_TESTS=$(usex test)
+		-DINITRAMFS_TOOLS=
+		-DUDEV_RULES_INSTALL_DIR="$(get_udevdir)/rules.d"
+		-DVERSION="v${PV}"
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	# Remove post-install test that only works on Azure.
+	rm -v \
+		"${ED}"/usr/sbin/azure-vm-utils-selftest \
+		"${ED}"/usr/share/man/man*/azure-vm-utils-selftest.* \
+		|| die
+}
+
+pkg_postinst() {
+	udev_reload
+}
+
+pkg_postrm() {
+	udev_reload
+}

sys-apps/azure-vm-utils/metadata.xml

@@ -5,6 +5,9 @@
 		<email>chewi@gentoo.org</email>
 		<name>James Le Cuirot</name>
 	</maintainer>
+	<use>
+		<flag name="dracut">Install dracut module</flag>
+	</use>
 	<upstream>
 		<remote-id type="github">Azure/azure-vm-utils</remote-id>
 	</upstream>