mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-20 10:17:08 -08:00
media-sound/umurmur: Bump to version 0.2.18
Package-Manager: Portage-3.0.12, Repoman-3.0.2 Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>
This commit is contained in:
@@ -1 +1,2 @@
|
||||
DIST umurmur-0.2.17.tar.gz 93786 BLAKE2B 92fc7d63dc0eed228c3fbcb0d18861cd49967f44378d980e856f8fb24fe7abc3429a4ca8e811eda6096727b76780724c909c46c04975b5edef70d848b7511618 SHA512 a496a51fd7815ad117f5aee17bb78cbd319c584ad60ab8aebbfd8ddf7b1760f443f2337bc74be1e0d5af17d3c3df2ae6c9060eca576cf1e6ed4c6cb0825e9c15
|
||||
DIST umurmur-0.2.18.tar.gz 93039 BLAKE2B 45a6e247dee604861e70698350b7b0ee28fd7ee82a94f684eae8ff5ab7daa0c3446b32c4aa28b39e64588944b8b81c4e2a11db79d0bde9e4a2012e67b4125be2 SHA512 bd1cd7149684dbe42b9804c9a5539cdb2becf6b721d74bd88d154e9037d3289ab57ee816c0592a0167ddd302da68d94017c86deb96348d272ec9bd21e9628656
|
||||
|
||||
@@ -0,0 +1,115 @@
|
||||
# Copyright 1999-2021 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=7
|
||||
|
||||
inherit autotools systemd readme.gentoo-r1
|
||||
|
||||
DESCRIPTION="Minimalistic Murmur (Mumble server)"
|
||||
HOMEPAGE="https://github.com/umurmur/umurmur"
|
||||
if [[ "${PV}" == *9999 ]] ; then
|
||||
inherit git-r3
|
||||
EGIT_REPO_URI="https://github.com/umurmur/umurmur.git"
|
||||
else
|
||||
SRC_URI="https://github.com/${PN}/${PN}/archive/${PV/_}.tar.gz -> ${P}.tar.gz"
|
||||
KEYWORDS="~amd64 ~arm ~x86"
|
||||
fi
|
||||
LICENSE="BSD"
|
||||
SLOT="0"
|
||||
IUSE="gnutls libressl mbedtls shm"
|
||||
|
||||
# ssl-provider precendence: gnutls, mbedtls, libressl
|
||||
# and openssl if none specified
|
||||
DEPEND=">=dev-libs/protobuf-c-1.0.0_rc2:=
|
||||
dev-libs/libconfig:=
|
||||
gnutls? (
|
||||
dev-libs/nettle:=
|
||||
>=net-libs/gnutls-3.0.0:=
|
||||
)
|
||||
!gnutls? (
|
||||
mbedtls? ( net-libs/mbedtls:= )
|
||||
!mbedtls? (
|
||||
libressl? ( dev-libs/libressl:0= )
|
||||
!libressl? ( dev-libs/openssl:0= )
|
||||
)
|
||||
)
|
||||
"
|
||||
|
||||
RDEPEND="${DEPEND}
|
||||
acct-group/murmur
|
||||
acct-user/murmur
|
||||
"
|
||||
|
||||
DOC_CONTENTS="
|
||||
A configuration file has been installed at /etc/umurmur/umurmur.conf - you
|
||||
may want to review it. See also\n
|
||||
https://github.com/umurmur/umurmur/wiki/Configuration "
|
||||
|
||||
S="${WORKDIR}/${P/_}"
|
||||
|
||||
get_ssl_impl() {
|
||||
local ssl_provider=()
|
||||
|
||||
use gnutls && ssl_provider+=( gnutls )
|
||||
use mbedtls && ssl_provider+=( mbedtls )
|
||||
use libressl && ssl_provider+=( libressl )
|
||||
|
||||
if ! use gnutls && ! use mbedtls && ! use libressl ; then
|
||||
ssl_provider+=( openssl )
|
||||
fi
|
||||
echo ${ssl_provider[@]}
|
||||
}
|
||||
|
||||
pkg_pretend() {
|
||||
local ssl_provider=( $(get_ssl_impl) )
|
||||
|
||||
if [[ ${#ssl_provider[@]} -gt 1 ]] ; then
|
||||
ewarn "More than one ssl provider selected (${ssl_provider[@]})"
|
||||
ewarn "defaulting to ${ssl_provider[0]}."
|
||||
fi
|
||||
}
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
eautoreconf
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
local ssl_provider=( $(sed 's@libressl@openssl@' <<< $(get_ssl_impl)) )
|
||||
|
||||
local myeconfargs=(
|
||||
--with-ssl="${ssl_provider[@]}"
|
||||
$(use_enable shm shmapi)
|
||||
)
|
||||
econf "${myeconfargs[@]}"
|
||||
}
|
||||
|
||||
src_install() {
|
||||
local confdir
|
||||
|
||||
emake DESTDIR="${D}" install
|
||||
|
||||
newinitd "${FILESDIR}"/umurmurd.initd umurmurd
|
||||
newconfd "${FILESDIR}"/umurmurd.confd umurmurd
|
||||
systemd_dounit "${FILESDIR}"/umurmurd.service
|
||||
|
||||
dodoc AUTHORS ChangeLog
|
||||
newdoc README.md README
|
||||
|
||||
confdir="/etc/umurmur"
|
||||
insinto "${confdir}"
|
||||
doins "${FILESDIR}"/umurmur.conf
|
||||
|
||||
# Some permissions are adjusted as the config may contain a server
|
||||
# password, and /etc/umurmur will typically contain the cert and the
|
||||
# key used to sign it, which are read after priveleges are dropped.
|
||||
fperms 0750 "${confdir}"
|
||||
fowners -R root:murmur "${confdir}"
|
||||
fperms 0640 "${confdir}"/umurmur.conf
|
||||
|
||||
readme.gentoo_create_doc
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
readme.gentoo_print_elog
|
||||
}
|
||||
Reference in New Issue
Block a user