net-libs/libtorrent-rasterbar: add 2.0.7

Signed-off-by: Sam James <sam@gentoo.org>
This commit is contained in:
Sam James
2022-07-25 05:09:40 +01:00
parent 4e198c7eed
commit 0c5ed11543
2 changed files with 75 additions and 0 deletions
+1
View File
@@ -1 +1,2 @@
DIST libtorrent-rasterbar-2.0.6.tar.gz 4431174 BLAKE2B 4951a102b68a5a7ba9a98d771ca638e8438b2aeaa95f5d7bf616542c7a02d28e184ee1bf5b7a55cd91a068cd2d4e9756c479e4ddb5eabe89d8aa833d70aa7502 SHA512 4a5d710706040ef6193967dbb13998cb0ddebe7e95c3bf8aec0812876027c68c32b001fd3f07cd4ff1b819660a8d46ae8c7077e72caf92572288a51cdec7daea
DIST libtorrent-rasterbar-2.0.7.tar.gz 4453469 BLAKE2B b04884c55cb96031f6bfcef786ea101d18bb9310ec2e1ed528e27d8f625712855726575beae127f24c007144bb85e1eba293da748ad06794c58ebd9b38ec5aac SHA512 30e558245a261ccf3f23815a037477ae6da1a02da0b7b3aa40383058c5782a341a11ae684f959efc1c9b39e31475ec31451b9ff4b2db3c0bfccc4d42bd6d69c1
@@ -0,0 +1,74 @@
# Copyright 2021-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{8..10} )
inherit cmake python-single-r1
DESCRIPTION="C++ BitTorrent implementation focusing on efficiency and scalability"
HOMEPAGE="https://libtorrent.org/ https://github.com/arvidn/libtorrent"
SRC_URI="https://github.com/arvidn/libtorrent/releases/download/v${PV}/${P}.tar.gz"
LICENSE="BSD"
SLOT="0/2.0"
KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="+dht debug gnutls python ssl test"
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
RESTRICT="!test? ( test )"
DEPEND="
dev-libs/boost:=[threads(+)]
python? (
${PYTHON_DEPS}
$(python_gen_cond_dep '
dev-libs/boost[python,${PYTHON_USEDEP}]
')
)
ssl? (
gnutls? ( net-libs/gnutls:= )
!gnutls? ( dev-libs/openssl:= )
)
"
RDEPEND="${DEPEND}"
BDEPEND="python? (
$(python_gen_cond_dep '
dev-python/setuptools[${PYTHON_USEDEP}]
')
)"
pkg_setup() {
use python && python-single-r1_pkg_setup
}
src_configure() {
local mycmakeargs=(
-DCMAKE_CXX_STANDARD=17
-DBUILD_SHARED_LIBS=ON
-Dbuild_examples=OFF
-Ddht=$(usex dht ON OFF)
-Dencryption=$(usex ssl ON OFF)
-Dgnutls=$(usex gnutls ON OFF)
-Dlogging=$(usex debug ON OFF)
-Dpython-bindings=$(usex python ON OFF)
-Dbuild_tests=$(usex test ON OFF)
)
# We need to drop the . from the Python version to satisfy Boost's
# FindBoost.cmake module, bug #793038.
use python && mycmakeargs+=( -Dboost-python-module-name="${EPYTHON/./}" )
cmake_src_configure
}
src_test() {
local myctestargs=(
# Needs running UPnP server
-E "test_upnp"
)
# Checked out Fedora's test workarounds for inspiration
# https://src.fedoraproject.org/rpms/rb_libtorrent/blob/rawhide/f/rb_libtorrent.spec#_120
LD_LIBRARY_PATH="${BUILD_DIR}:${LD_LIBRARY_PATH}" cmake_src_test
}