media-libs/gst-plugins-base: Version bump

Package-Manager: portage-2.3.0

media-libs/gst-plugins-base/Manifest

@@ -1,3 +1,4 @@
 DIST gst-plugins-base-0.10.36.tar.xz 2364108 SHA256 1fe45c3894903001d4d008b0713dab089f53726dcb5842d5b40c2595a984e64a SHA512 ea77778e073515df58229a641b4363df31f0b80204a5a43a8feb31f0b03a5a4b9b79d6e07e1615c773a59927a9b649f1b1d782def1120d581d09a090be8363b8 WHIRLPOOL e455f2a1aafd60078080735108e4ac336bc4764ed92b9579d83a453f75491331d16b48e5983f3c9712b6edb28ec379e696f06f6910c93168b019d6077c28fb6d
 DIST gst-plugins-base-1.4.5.tar.xz 2637680 SHA256 77bd8199e7a312d3d71de9b7ddf761a3b78560a2c2a80829d0815ca39cbd551d SHA512 63d3c531de736ad8a64d6962c0af75857d3b016d7f8e85d1884e8de50e64576902bb1161161b74130ab5dfb1d453eb995e374d8a958eac6e44ae5272eeaaf8b6 WHIRLPOOL cf6ef1c9589ed7a39be74e7663b0821c81b1b4cffdd612ccd7fd5b7929508af21d68817530a4b0fb2517f3a7044ee068afba7602816fdd0ada31444f0bcf8383
 DIST gst-plugins-base-1.6.3.tar.xz 2837460 SHA256 b6154f8fdba4877e95efd94610ef0ada4f0171cd12eb829a3c3c97345d9c7a75 SHA512 c4cc98e55c94864ccf45c38c9cbfb2a6d5d5c9cf59e761d10db873640adbf0d4adc583a349dfde56428315416412bb37a31851a10826d11807472ad28d0bfb30 WHIRLPOOL 63c0b2e1ebdf59512c82977b1a8f3a4a6e7a46484a5c726b641d01cc5671ea125bfff804948fbe5a9c3a567590c5ea12f31f1540cbb3493b1c6e1cacc73eba61
+DIST gst-plugins-base-1.8.2.tar.xz 2886960 SHA256 9d7109c8fb0a5dec8edb17b0053c59a46aba7ddf48dc48ea822ebbbd4339d38d SHA512 416b8755d2453e6a68f1ac605fe08ce64e63936c97c8931c85de4a87e8d3e4f2ae197422f7aadfc1eaecbd782141b6088543ed5ddaaf686dce860ac190c5fb19 WHIRLPOOL 298bc04291fab5c2e06835640c3266ec296a06b431a1442c45e6832d3ddb7b5bb1fe5e93940233f48010ed655882bc86502f3734024e709c31998a6f7339823d

media-libs/gst-plugins-base/gst-plugins-base-1.8.2.ebuild

@@ -0,0 +1,87 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+GST_ORG_MODULE="gst-plugins-base"
+
+inherit gstreamer
+
+DESCRIPTION="Basepack of plugins for gstreamer"
+HOMEPAGE="https://gstreamer.freedesktop.org/"
+
+LICENSE="GPL-2+ LGPL-2+"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+
+IUSE="alsa +introspection ivorbis +ogg +orc +pango theora +vorbis X"
+REQUIRED_USE="
+	ivorbis? ( ogg )
+	theora? ( ogg )
+	vorbis? ( ogg )
+"
+
+RDEPEND="
+	app-text/iso-codes
+	>=dev-libs/glib-2.40.0:2[${MULTILIB_USEDEP}]
+	>=media-libs/gstreamer-${PV}:1.0[introspection?,${MULTILIB_USEDEP}]
+	>=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}]
+	alsa? ( >=media-libs/alsa-lib-1.0.27.2[${MULTILIB_USEDEP}] )
+	introspection? ( >=dev-libs/gobject-introspection-1.31.1:= )
+	ivorbis? ( >=media-libs/tremor-0_pre20130223[${MULTILIB_USEDEP}] )
+	ogg? ( >=media-libs/libogg-1.3.0[${MULTILIB_USEDEP}] )
+	orc? ( >=dev-lang/orc-0.4.23[${MULTILIB_USEDEP}] )
+	pango? ( >=x11-libs/pango-1.36.3[${MULTILIB_USEDEP}] )
+	theora? ( >=media-libs/libtheora-1.1.1[encode,${MULTILIB_USEDEP}] )
+	vorbis? ( >=media-libs/libvorbis-1.3.3-r1[${MULTILIB_USEDEP}] )
+	X? (
+		>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXext-1.3.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXv-1.0.10[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.12
+	X? (
+		>=x11-proto/videoproto-2.3.1-r1[${MULTILIB_USEDEP}]
+		>=x11-proto/xextproto-7.2.1-r1[${MULTILIB_USEDEP}]
+		>=x11-proto/xproto-7.0.24[${MULTILIB_USEDEP}] )
+"
+
+multilib_src_configure() {
+	gstreamer_multilib_src_configure \
+		$(use_enable alsa) \
+		$(multilib_native_use_enable introspection) \
+		$(use_enable ivorbis) \
+		$(use_enable ogg) \
+		$(use_enable orc) \
+		$(use_enable pango) \
+		$(use_enable theora) \
+		$(use_enable vorbis) \
+		$(use_enable X x) \
+		$(use_enable X xshm) \
+		$(use_enable X xvideo) \
+		--disable-debug \
+		--disable-examples \
+		--disable-static
+	# cdparanoia and libvisual are split out, per leio's request
+
+	# bug #366931, flag-o-matic for the whole thing is overkill
+	if [[ ${CHOST} == *86-*-darwin* ]] ; then
+		sed -i \
+			-e '/FLAGS = /s|-O[23]|-O1|g' \
+			gst/audioconvert/Makefile \
+			gst/volume/Makefile || die
+	fi
+
+	if multilib_is_native_abi; then
+		local x
+		for x in libs plugins; do
+			ln -s "${S}"/docs/${x}/html docs/${x}/html || die
+		done
+	fi
+}
+
+multilib_src_install_all() {
+	DOCS="AUTHORS NEWS README RELEASE"
+	einstalldocs
+	prune_libtool_files --modules
+}