games-board/xboard: version bump to 4.9.0

* fdo-mime -> xdg-utils
  * sort IUSE
  * put docs into DOCS array
  * drop gnome2_icon_savelist

Package-Manager: Portage-2.3.49, Repoman-2.3.11
Signed-off-by: Philipp Ammann <philipp.ammann@posteo.de>
Closes: https://github.com/gentoo/gentoo/pull/9951
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

games-board/xboard/Manifest

@@ -1 +1,2 @@
 DIST xboard-4.8.0.tar.gz 3691531 BLAKE2B 7743b654e8bdd37672a6076ce032fcc92c846796a8cf84906ae8b74454297f0fed1bce078883e9aff6237c8bfee67db659bdd7b93acd94e1b27bc90629dc3b1a SHA512 fc3231f170baacdf97df5d08488f5a1fb9a144810f7b0eb72e3e95d345ce47aa2ff67a586ef45b6a9e45932300babc59c161a29e055dd0d19b133ba986985c81
+DIST xboard-4.9.0.tar.gz 4012576 BLAKE2B f2b1a8f2393e6270c7b68a70d563fee93befdcb4da961d6dbda22b2fd5ef1de837ce5befe786667643f39e66dcbd1f49a808ef1eff72a4acde4bb4e9ae904c7c SHA512 4eeda52ecb7ab0111020af08e997e0de5b1bc85ec1734f6f597becc08f64a3cfe470be6e25bf36ce5355463caa9ecde2d3077ac55f94f32f781c5a4b02e5bb6d

games-board/xboard/xboard-4.9.0.ebuild

@@ -0,0 +1,87 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools xdg-utils gnome2-utils
+
+DESCRIPTION="GUI for gnuchess and for internet chess servers"
+HOMEPAGE="https://www.gnu.org/software/xboard/"
+SRC_URI="mirror://gnu/xboard/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+IUSE="+default-font gtk nls Xaw3d zippy"
+RESTRICT="test" #124112
+
+RDEPEND="
+	dev-libs/glib:2
+	gnome-base/librsvg:2
+	virtual/libintl
+	x11-libs/cairo[X]
+	x11-libs/libXpm
+	default-font? (
+		media-fonts/font-adobe-100dpi[nls?]
+		media-fonts/font-misc-misc[nls?]
+	)
+	!gtk? (
+		x11-libs/libX11
+		x11-libs/libXt
+		x11-libs/libXmu
+		Xaw3d? ( x11-libs/libXaw3d )
+		!Xaw3d? ( x11-libs/libXaw )
+	)
+	gtk? ( x11-libs/gtk+:2 )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	x11-base/xorg-proto
+	nls? ( sys-devel/gettext )"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-4.8.0-gettext.patch
+	"${FILESDIR}"/${PN}-4.8.0-gnuchess-default.patch
+)
+
+DOCS=( AUTHORS COPYRIGHT ChangeLog FAQ.html NEWS README TODO ics-parsing.txt )
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--disable-update-mimedb \
+		--datadir="${EPREFIX}"/usr/share \
+		$(use_enable nls) \
+		$(use_enable zippy) \
+		--disable-update-mimedb \
+		$(use_with gtk) \
+		$(use_with Xaw3d) \
+		$(usex gtk "--without-Xaw" "$(use_with !Xaw3d Xaw)") \
+		--with-gamedatadir="${EPREFIX}/usr/share/games/${PN}"
+}
+
+src_install() {
+	default
+	use zippy && dodoc zippy.README
+}
+
+pkg_postinst() {
+	xdg_mimeinfo_database_update
+	xdg_desktop_database_update
+	gnome2_icon_cache_update
+	elog "No chess engines are emerged by default! If you want a chess engine"
+	elog "to play with, you can emerge gnuchess or crafty."
+	elog "Read xboard FAQ for information."
+	if ! use default-font ; then
+		ewarn "Read the xboard(6) man page for specifying the font for xboard to use."
+	fi
+}
+
+pkg_postrm() {
+	xdg_mimeinfo_database_update
+	xdg_desktop_database_update
+	gnome2_icon_cache_update
+}