dev-vcs/gitg: Version bump

Package-Manager: portage-2.3.0_rc1

dev-vcs/gitg/Manifest

@@ -1 +1,2 @@
 DIST gitg-3.18.0.tar.xz 1413188 SHA256 fa4b7b9c492f13f5f1d864af1281ea377ac8c7619c856e05f533b18989edf421 SHA512 df6944df057d6863ec6a551749edf4d003bf9954c474b0d83ef1476747df210f1e7ead4d007dce06de6f84e25afcafb8aa4f61d8af703861c014c4189cf008d0 WHIRLPOOL 4a27708999e33a533988d62e94a2ad2ee6424184d9862e79bd5dd4a1033e38505672f407f492d9831465249cae68b20a112de6d5737286d28d6d952793c33265
+DIST gitg-3.20.0.tar.xz 1477588 SHA256 1f09f61208349d003f228e51dc9709bd3426960f5585c0e38197bd02b51f3346 SHA512 ff7ef79d41772dfca3b48a1a443ebde386d0075fcee6aa4aa389a4b04bb3ff5ca267791866d368f871c3df23301dae0fe037328e5df3be41cef6666bde4861c6 WHIRLPOOL aca6f57162ca7445cb5bc829580e51ceb4e02b17e62ad0379fb7e0afa3cf4a3001649ce1106a8bea4cc5c0b9e168a1c01ce81ce18bcd45fb17ae3c8a50af4847

dev-vcs/gitg/gitg-3.20.0.ebuild

@@ -0,0 +1,82 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python{3_3,3_4,3_5} )
+VALA_MIN_API_VERSION="0.32" # Needed when gtk+-3.20 is found
+
+inherit gnome2 pax-utils python-r1 vala
+
+DESCRIPTION="git repository viewer for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Gitg"
+
+LICENSE="|| ( GPL-2 GPL-3 )"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+
+IUSE="debug glade +python"
+REQUIRED_USE="python? ( ^^ ( $(python_gen_useflags '*') ) )"
+
+# test if unbundling of libgd is possible
+# Currently it seems not to be (unstable API/ABI)
+RDEPEND="
+	app-crypt/libsecret
+	dev-libs/libgee:0.8[introspection]
+	>=app-text/gtkspell-3.0.3:3
+	>=dev-libs/glib-2.38:2[dbus]
+	>=dev-libs/gobject-introspection-0.10.1:=
+	dev-libs/libgit2:=[threads]
+
+	>=dev-libs/libgit2-glib-0.24.0[ssh]
+	<dev-libs/libgit2-glib-0.25.0
+
+	>=dev-libs/libpeas-1.5.0[gtk]
+	>=dev-libs/libxml2-2.9.0:2
+	>=gnome-base/gsettings-desktop-schemas-0.1.1
+	>=x11-libs/gtk+-3.19.0:3
+	>=x11-libs/gtksourceview-3.10:3.0
+	x11-themes/adwaita-icon-theme
+	glade? ( >=dev-util/glade-3.2:3.10 )
+	python? (
+		${PYTHON_DEPS}
+		dev-libs/libpeas[python,${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+	)
+"
+DEPEND="${RDEPEND}
+	$(vala_depend)
+	>=dev-libs/libgit2-glib-0.22.0[vala]
+	gnome-base/gnome-common
+	>=sys-devel/gettext-0.17
+	virtual/pkgconfig
+	>=dev-util/intltool-0.40
+"
+
+pkg_setup() {
+	use python && [[ ${MERGE_TYPE} != binary ]] && python_setup
+}
+
+src_prepare() {
+	sed \
+		-e '/CFLAGS/s:-g::g' \
+		-e '/CFLAGS/s:-O0::g' \
+		-i configure.ac || die
+
+	gnome2_src_prepare
+	vala_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--disable-static \
+		--disable-deprecations \
+		$(use_enable debug) \
+		$(use_enable glade glade-catalog) \
+		$(use_enable python)
+}
+
+src_install() {
+	gnome2_src_install -j1
+}