media-libs/gegl: 0.4.12

Sync 9999 as well.
Signed-off-by: Sebastian Pipping <sping@gentoo.org>
Package-Manager: Portage-2.3.50, Repoman-2.3.11

media-libs/gegl/Manifest

@@ -3,5 +3,6 @@ DIST gegl-0.3.0.tar.bz2 5463571 BLAKE2B 7ac52fb22bab3b84068e10610d8681a5bcf56f6c
 DIST gegl-0.3.26.tar.bz2 6530788 BLAKE2B 1cd1a61737ec94cb30fdf16ca8dcb5667ebaa481d0e234f89b7e8bd9b05b3e515454bf768a66e64c88f61a57c83d51eecad9aab4450502dd3e02ce4f012df7a5 SHA512 1fafd6bb70b539bd31c052d2acfcb332fac92caf2a67e07a8c827db31b877aa373a184475952b6fc4dae455dcceccfd3943d782e9fe50f166323f698faf60957
 DIST gegl-0.3.34.tar.bz2 6707964 BLAKE2B 4424a2c218067bd0a77d79c2334528da393350db3062019f3889b8cdb8d222f6e436ccfc845b61fdf425a1634698a7a6963702a29bb1666f515b1395c50dc99f SHA512 a7a394dcce4137d5224163ca324f1585e64d1cc797e77d452ba444afe2bff39aa2e2d5d040d07b394697b75162bc310bc51490a5af80240b26aac14b6e7abe02
 DIST gegl-0.3.8.tar.bz2 5876259 BLAKE2B 24199148ffbef6454ea460d126c29f1cc8581e5430bc3e341a8ab48fff701a0d63c4cf8864d04219455feaeb7e03808e8de06cc8ae0a500eb4154f2ec9ba25fe SHA512 13207e7ab4723be1e31bdba5e30e5725e93c1adc61bad1413502128730391dbe7eb35419d243c8d0a1d8794341a58188790adacbb10d2a8e68db861c18d21bfb
+DIST gegl-0.4.12.tar.bz2 7065555 BLAKE2B f0801739e67e6d6ecc88abaed8638c900edd7229d240f63af7cc0bf503cd29b33b84d7e3018c757b0bdb6ee5245f6af595b96decc3916b57debfb46712213577 SHA512 cacf9f5c34357b3939162d0d4712ee2b47298a3e806b55e275cdf5e23f186d436ea1a840b91b1b72b76d450d94674cca217b7c253cd6b52a7d9505b4ad73fde2
 DIST gegl-0.4.6.tar.bz2 6931774 BLAKE2B c8fabc8efbcc21a3663c8a3a698e6bc072506a66a21b81e6696c37c81aec1458c695f773c554b6d98c2fd21a3d3ab7fcca4b2f6567ec9d4f94b1e925b9bc9ce5 SHA512 6df34b6e76318a375820bccac6efeb2792c737e47154902fcc08ef93cb45b978992ee263260c99f8e865964d80cd1fac6dc2d6c8e4453174df64a9044b57325e
 DIST gegl-0.4.8.tar.bz2 7017022 BLAKE2B ec934fe6faa0c9328ae8c6476e19e175a8e8082e3d1f59052fb83fad766030ede9dd3464a215d332238277492151d988b17c6d3ac87f3d9cec01797acd259fae SHA512 20d2700cc74bce02e3e1b477f5e4dbd6546bb74625de235baaaa31e24f506930927af53de3d0880c0b16f93a10cec993c58a12adba59dec7dda0e389261799aa

media-libs/gegl/gegl-0.4.12.ebuild

@@ -0,0 +1,173 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+
+# vala and introspection support is broken, bug #468208
+VALA_USE_DEPEND=vapigen
+
+inherit autotools gnome2-utils python-any-r1 vala
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.gnome.org/GNOME/gegl.git"
+	SRC_URI=""
+else
+	SRC_URI="http://download.gimp.org/pub/${PN}/${PV:0:3}/${P}.tar.bz2"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris ~x86-solaris"
+fi
+
+DESCRIPTION="A graph based image processing framework"
+HOMEPAGE="http://www.gegl.org/"
+
+LICENSE="|| ( GPL-3+ LGPL-3 )"
+SLOT="0.4"
+
+IUSE="cairo cpu_flags_x86_mmx cpu_flags_x86_sse debug ffmpeg +introspection jpeg2k lcms lensfun libav openexr raw sdl svg test tiff umfpack vala v4l webp"
+REQUIRED_USE="
+	svg? ( cairo )
+	vala? ( introspection )
+"
+
+# NOTE: Even current libav 11.4 does not have AV_CODEC_CAP_VARIABLE_FRAME_SIZE
+#       so there is no chance to support libav right now (Gentoo bug #567638)
+#       If it returns, please check prior GEGL ebuilds for how libav was integrated.  Thanks!
+RDEPEND="
+	>=dev-libs/glib-2.44:2
+	dev-libs/json-glib
+	>=media-libs/babl-0.1.58
+	>=media-libs/libpng-1.6.0:0=
+	sys-libs/zlib
+	virtual/jpeg:0=
+	>=x11-libs/gdk-pixbuf-2.32:2
+	x11-libs/pango
+	cairo? ( >=x11-libs/cairo-1.12.2 )
+	ffmpeg? (
+		libav? ( media-video/libav:0= )
+		!libav? ( media-video/ffmpeg:0= )
+	)
+	introspection? ( >=dev-libs/gobject-introspection-1.32:= )
+	jpeg2k? ( >=media-libs/jasper-1.900.1:= )
+	lcms? ( >=media-libs/lcms-2.8:2 )
+	lensfun? ( >=media-libs/lensfun-0.2.5 )
+	openexr? ( >=media-libs/openexr-2.2.0:= )
+	raw? ( >=media-libs/libraw-0.15.4:0= )
+	sdl? ( >=media-libs/libsdl-1.2.0 )
+	svg? ( >=gnome-base/librsvg-2.40.6:2 )
+	tiff? ( >=media-libs/tiff-4:0 )
+	umfpack? ( sci-libs/umfpack )
+	v4l? ( >=media-libs/libv4l-1.0.1 )
+	webp? ( >=media-libs/libwebp-0.5.0:= )
+"
+DEPEND="${RDEPEND}
+	dev-lang/perl
+	>=dev-util/gtk-doc-am-1
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	>=sys-devel/libtool-2.2
+	test? ( ffmpeg? ( media-libs/gexiv2 )
+		introspection? (
+			$(python_gen_any_dep '>=dev-python/pygobject-3.2[${PYTHON_USEDEP}]')
+		)
+	)
+	vala? ( $(vala_depend) )
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.3.12-failing-tests.patch"
+)
+
+pkg_setup() {
+	use test && use introspection && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	# FIXME: the following should be proper patch sent to upstream
+	# fix OSX loadable module filename extension
+	sed -i -e 's/\.dylib/.bundle/' configure.ac || die
+	# don't require Apple's OpenCL on versions of OSX that don't have it
+	if [[ ${CHOST} == *-darwin* && ${CHOST#*-darwin} -le 9 ]] ; then
+		sed -i -e 's/#ifdef __APPLE__/#if 0/' gegl/opencl/* || die
+	fi
+
+	# commit 7c78497b : tests that use gegl.png are broken on non-amd64
+	sed -e '/clones.xml/d' \
+		-e '/composite-transform.xml/d' \
+		-i tests/compositions/Makefile.am || die
+
+	eautoreconf
+
+	gnome2_environment_reset
+
+	use vala && vala_src_prepare
+}
+
+src_configure() {
+	local myeconfargs=(
+		# disable documentation as the generating is bit automagic
+		#    if anyone wants to work on it just create bug with patch
+		--disable-docs
+		# never enable altering of CFLAGS via profile option
+		--disable-profile
+		--disable-silent-rules
+		#  - Parameter --disable-workshop disables any use of Lua, effectivly
+		--disable-workshop
+		--program-suffix=-${SLOT}
+		--with-gdk-pixbuf
+		--with-pango
+		#  - Parameter --with-exiv2 compiles a noinst-app only, no use
+		#    but needed during testing
+		--without-exiv2
+		#  - There are two checks for dot, one controllable by --with(out)-graphviz
+		#    which toggles HAVE_GRAPHVIZ that is not used anywhere.  Yes.
+		--without-graphviz
+		# libspiro: not in portage main tree
+		--without-libspiro
+		--without-lua
+		--without-mrg
+		$(use_enable cpu_flags_x86_mmx mmx)
+		$(use_enable cpu_flags_x86_sse sse)
+		$(use_enable debug)
+		$(use_enable introspection)
+		$(use_with cairo)
+		$(use_with cairo pangocairo)
+		$(use_with ffmpeg libavformat)
+		$(use_with jpeg2k jasper)
+		$(use_with lcms)
+		$(use_with lensfun)
+		$(use_with openexr)
+		$(use_with raw libraw)
+		$(use_with sdl)
+		$(use_with svg librsvg)
+		$(use_with tiff libtiff)
+		$(use_with umfpack)
+		#  - v4l support does not work with our media-libs/libv4l-0.8.9,
+		#    upstream bug at https://bugzilla.gnome.org/show_bug.cgi?id=654675
+		$(use_with v4l libv4l)
+		$(use_with v4l libv4l2)
+		$(use_with vala)
+		$(use_with webp)
+	)
+
+	if use test; then
+		myeconfargs+=( $(use_with ffmpeg gexiv2) )
+	else
+		myeconfargs+=( --without-gexiv2 )
+	fi
+
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	default
+
+	[[ ${PV} == *9999* ]] && emake ./ChangeLog  # "./" prevents "Circular ChangeLog <- ChangeLog dependency dropped."
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -delete || die
+}

media-libs/gegl/gegl-9999.ebuild

@@ -36,7 +36,7 @@ REQUIRED_USE="
 RDEPEND="
 	>=dev-libs/glib-2.44:2
 	dev-libs/json-glib
-	>=media-libs/babl-0.1.54
+	>=media-libs/babl-0.1.56
 	>=media-libs/libpng-1.6.0:0=
 	sys-libs/zlib
 	virtual/jpeg:0=
@@ -151,7 +151,7 @@ src_configure() {
 	if use test; then
 		myeconfargs+=( $(use_with ffmpeg gexiv2) )
 	else
-		myeconfargs+=( "--without-gexiv2" )
+		myeconfargs+=( --without-gexiv2 )
 	fi
 
 	econf "${myeconfargs[@]}"