dev-scheme/guile-zstd: new package; add 0.1.1

Bug: https://github.com/trofi/nix-guix-gentoo/issues/24
Signed-off-by: Maciej Barć <xgqt@gentoo.org>

dev-scheme/guile-zstd/Manifest

@@ -0,0 +1 @@
+DIST guile-zstd-0.1.1.tar.gz 21402 BLAKE2B 995034f977649b31308690a5a53372cb80274b6457b6b0344bc31f4451d00e61cc33b6ef890e8b7a75cb6a656e8db506a2390bc2c5d29552af7c68788a6388ee SHA512 23bd4b201a427eb02ae32bcd81d05adefcac3b4446dcb8a91d8ad2bed389d4ea92ffd81dfb6b3e7427b891fd25b7466ca53a97b1a943e390f13de977986fcad0

dev-scheme/guile-zstd/guile-zstd-0.1.1.ebuild

@@ -0,0 +1,48 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="GNU Guile bindings to the zstd compression library"
+HOMEPAGE="https://notabug.org/guile-zstd/guile-zstd/"
+SRC_URI="https://notabug.org/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}"/${PN}
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+# In zstd-1.5.2-r2 library was moved from /usr/lib to /lib
+RDEPEND="
+	>=dev-scheme/guile-2.0.0:=
+	>=app-arch/zstd-1.5.2-r2
+"
+DEPEND="${RDEPEND}"
+
+DOCS=( AUTHORS ChangeLog NEWS README )
+
+# guile generates ELF files without use of C or machine code
+# It's a portage's false positive. bug #677600
+QA_PREBUILT='*[.]go'
+
+src_prepare() {
+	default
+
+	# Workaround gentoo-specific deviation where
+	# /usr/lib64/libzstd.so is a linker script that points to:
+	#   GROUP ( /lib64/libzstd.so.1 )
+	# This confuses guile-zstd and fails to open the library:
+	#   substitute: ice-9/boot-9.scm:1685:16: In procedure raise-exception:
+	#   substitute: In procedure load-foreign-library: file: "/usr/lib64/libzstd.so.1",
+	#     message: "file not found"
+	#   guix environment: error: `/usr/bin/guix substitute' died unexpectedly
+	sed "s|@ZSTD_LIBDIR@/libzstd.so.1|/$(get_libdir)/libzstd.so.1|" \
+		-i "${S}"/zstd/config.scm.in || die
+
+	# http://debbugs.gnu.org/cgi/bugreport.cgi?bug=38112
+	find "${S}" -name "*.scm" -exec touch {} + || die
+
+	eautoreconf
+}

dev-scheme/guile-zstd/metadata.xml

@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+
+<pkgmetadata>
+  <maintainer type="project">
+    <email>scheme@gentoo.org</email>
+    <name>Gentoo Scheme Project</name>
+  </maintainer>
+  <upstream>
+    <bugs-to>https://notabug.org/guile-zstd/guile-zstd/</bugs-to>
+  </upstream>
+</pkgmetadata>